0 based array length. How is that right?

Question

I wrote a function in a Delphi Android app to determine if either Mobile or Wifi (or both) are enabled. I used Checking internet connection in android using getActiveNetworkInfo for reference.

I must have made a mistake, because the function isn't detecting Wifi, even when it is enabled on the phone!

function WhichNetwork: Integer; // 0 = none, 1 = wifi only, 2 = mobile only, 3 = both
var
  obj: JObject;
  cm: JConnectivityManager;
  networks: TJavaObjectArray<JNetwork>;
  i: Integer;
  network: JNetworkInfo;
  networktype: Integer;
  networkname: String;
begin
  Result := 0;
  obj := TAndroidHelper.Context.getSystemService(TJContext.JavaClass.CONNECTIVITY_SERVICE);
  if Assigned(obj) then
  begin
    cm := TJConnectivityManager.Wrap((obj as ILocalObject).GetObjectID);
    if Assigned(cm) then
    begin
      networks := cm.getAllNetworks;
      if Assigned(networks) then
      begin
        for i := 0 to networks.Length - 1 do // this looks right!
        begin
          network := cm.getNetworkInfo(i);
          networkname := JStringtoString(network.getTypeName); // for debug
          networktype := network.gettype;
          if networkType = TJConnectivityManager.JavaClass.TYPE_MOBILE then
          begin
            if network.isConnectedOrConnecting then
              Result := Result + 2;
          end
          else if networkType = TJConnectivityManager.JavaClass.TYPE_WIFI then
          begin
            if network.isConnectedOrConnecting then
              Result := Result + 1;
          end;
        end;
      end;
    end;
  end;
end;

After experimenting, I made the following change and it worked!

for i := 0 to networks.Length do // now this works

But, this is so not how Delphi usually works. Can someone explain why the Length of a TJavaObjectArray is zero-based?

It's an academic question, and I really want to understand this.

Answer 1

There is nothing wrong with this 0-based array.

You are calling the (deprecated) overload of getNetworkInfo that takes an integer argument. This integer specifies "which networkType in which you're interested", such as TYPE_MOBILE (0), TYPE_WIFI (1), and not an index position related to the array returned by getAllNetworks.

You need to call the getNetworkInfo overload that gets a Network as argument, as @nil said you in the comments.

for i := 0 to networks.Length - 1 do begin
    network := cm.getNetworkInfo(networks[i]);
    ...
end;

Answer 2

By convention Delphi uses zero based indexes. Dynamic arrays are zero based. Strings are historically one based but on the mobile platforms the default strings is now zero based. Other types such as container classes, fixed length arrays, are zero or one based as determined by the author, but by convention, zero based is preferred.

for i := 0 to networks.Length do

You say that this loop is correct, but by all known conventions it looks like a mistake since the loop covers one element too many. It should be:

for i := 0 to networks.Length-1 do

However, your loop doesn't refer to networks in the loop body. Which makes one wonder why you use networks.Length at all if you ignore the elements of networks. If you are going to obtain the array networks then surely you should be using it. I expect that once you resolve this conundrum things will become clear.

---

You seem to be struggling to find the documentation. Perhaps you are looking for Delphi documentation. You won't find that. These are Android libraries, and you will need to look in the Android documentation. Start here: https://developer.android.com/reference/android/net/ConnectivityManager.html

You are calling getNetworkInfo. Let's read its documentation. There are two overloads, declared like this:

NetworkInfo getNetworkInfo(int networkType);

NetworkInfo getNetworkInfo(Network network);

The first overload takes a type parameter, but you are passing an integer index. That is a mistake. Further, the first overload is deprecated.

It looks very much like you intend to use the second overload and so the code should be:

var
  networks: TJavaObjectArray<JNetwork>;
  networkInfo: JNetworkInfo;
....
networks := cm.getAllNetworks;
for i := 0 to networks.Length-1 do
begin
  networkInfo := cm.getNetworkInfo(networks[i]);
  ....
end;

Anyway, the big lesson here for you is to stop using trial and error. Instead, read the documentation.