Inno Setup: Change value in JSON array

Question

I would like to create an installer with the help of Inno Setup. In order to make the program work on every computer, I need to change the tool directory in a .json-file. Here is an excerpt from this file:

{
  "commandScriptLinux" : "",
  "copyToolBehavior" : "once",
  "deleteWorkingDirectoriesAfterWorkflowExecution" : true,
  "deleteWorkingDirectoriesKeepOnErrorOnce" : true,
  "deleteWorkingDirectoriesNever" : true,
  "documentationFilePath" : "",
  "enableCommandScriptWindows" : true,
  "imitationScript" : "",
  "imitationToolOutputFilename" : "",
  "launchSettings" :
  [
    {
      "limitInstallationInstancesNumber" : "1",
      "limitInstallationInstances" : "false",
      "toolDirectory" : "%Selected Setup Folder%",
      "version" : "1.0"
    }
  ],
}

I hoped to solve this by using the inno-json-config library. Unfortunately, after executing the code, the lines are reversed (last line comes first now) and the changes weren't made.

[Setup]
AppName=Change_Config
AppVersion=1.0
DefaultDirName={userdocs}\Change_Config

[Files]
Source: "JSONConfig.dll"; Flags: dontcopy

[Code]
function JSONQueryString(FileName, Section, Key, Default: WideString;
  var Value: WideString; var ValueLength: Integer): Boolean;
  external 'JSONQueryString@files:jsonconfig.dll stdcall';
function JSONWriteString(FileName, Section, Key, 
  Value: WideString): Boolean;
  external 'JSONWriteString@files:jsonconfig.dll stdcall';

procedure InitializeWizard;
var
  FileName: WideString;
  IntValue: Int64;
  StrValue: WideString;
  StrLength: Integer;
  BoolValue: Boolean;
begin
  FileName := 'c:\configuration.json';
  SetLength(StrValue, 16);
  StrLength := Length(StrValue);

  if JSONQueryString(
       FileName, 'launchSettings', 'toolDirectory', 'Default', StrValue, StrLength) then
    MsgBox('Section_1:Key_1=' + StrValue, mbInformation, MB_OK);

  if not JSONWriteString(FileName, 'launchSettings', 'toolDirectory', 'Test') then
    MsgBox('JSONWriteString Section_1:Key_1 failed!', mbError, MB_OK);
end;

Thank you very much for your support!

Regards, Alex

Martin Prikryl · Accepted Answer · 2017-12-14T14:08:20.753

The launchSettings is an array. I believe that the inno-json-config library does not support arrays.

You can use JsonParser library instead.

[Code]

#include "JsonParser.pas"

function FindJsonValue(
  Output: TJsonParserOutput; Parent: TJsonObject; Key: TJsonString;
  var Value: TJsonValue): Boolean;
var
  I: Integer;
begin
  for I := 0 to Length(Parent) - 1 do
  begin
    if Parent[I].Key = Key then
    begin
      Value := Parent[I].Value;
      Result := True;
      Exit;
    end;
  end;

  Result := False;
end;

function FindJsonArray(
  Output: TJsonParserOutput; Parent: TJsonObject; Key: TJsonString;
  var Arr: TJsonArray): Boolean;
var
  JsonValue: TJsonValue;
begin
  Result :=
    FindJsonValue(Output, Parent, Key, JsonValue) and
    (JsonValue.Kind = JVKArray);

  if Result then
  begin
    Arr := Output.Arrays[JsonValue.Index];
  end;
end;

{ ... }

var
  JsonLines: TStringList;
  JsonParser: TJsonParser;
  LaunchSettingsArray: TJsonArray;
  ToolDirectoryValue: TJsonValue;
  I: Integer;
begin
  { ... }

  JsonLines := TStringList.Create;
  JsonLines.LoadFromFile(FileName);

  ParseJson(JsonParser, JsonLines.Text);

  if Length(JsonParser.Output.Errors) > 0 then
  begin
    Log('Error parsing JSON');
    for I := 0 to Length(JsonParser.Output.Errors) - 1 do
    begin
      Log(JsonParser.Output.Errors[I]);
    end;
  end
    else
  begin
    if FindJsonArray(
         JsonParser.Output, JsonParser.Output.Objects[0],
         'launchSettings', LaunchSettingsArray) and
       (GetArrayLength(LaunchSettingsArray) >= 0) and
       (LaunchSettingsArray[0].Kind = JVKObject) and 
       FindJsonValue(
         JsonParser.Output,
         JsonParser.Output.Objects[LaunchSettingsArray[0].Index], 'toolDirectory',
         ToolDirectoryValue) and
       (ToolDirectoryValue.Kind = JVKString) then
    begin
      Log(Format(
        'launchSettings[0]:toolDirectory:%s', [
        JsonParser.Output.Strings[ToolDirectoryValue.Index]]));
      JsonParser.Output.Strings[ToolDirectoryValue.Index] := 'Test';
      JsonLines.Clear;
      PrintJsonParserOutput(JsonParser.Output, JsonLines);
      JsonLines.SaveToFile(FileName);
    end;
  end;

  ClearJsonParser(JsonParser);
  JsonLines.Free;
end;

It still won't preserve the order (but that should not matter).

Though in your case, you do not need to parse the JSON. You can simply replace the %Selected Setup Folder% with the desired value.

See Replace placeholder in an installed text file with input entered by user.

Inno Setup: Change value in JSON array

1 Answers1