Merge Different workbooks into one

Question

I got 97 different workbooks. I want to merge them together into one workbook.

After some search I found this code and made some changes.

When I press F5, no Error happen. But I don't see any result of code.

Here my code:

Sub MergeDifferentWorkbooksTogether()

Dim wbk As Workbook
Dim wbk1 As Workbook
Set wbk1 = ThisWorkbook
Dim Filename As String
Dim Path As String

Path = "C:\Users\xezer.suleymanov\Desktop\Combine Workbooks"
Filename = Dir(Path & "*.xlsx")

Do While Len(Filename) > 0

Set wbk = Workbooks.Open(Path & Filename)
wbk.Activate
Range("A2").Select
Range(ActiveCell, ActiveCell.End(xlDown).End(xlToRight)).Copy
Windows("Book1.xlsx").Activate
Application.DisplayAlerts = False
Dim i As Double
i = wbk1.Sheets("Sheet1").cell(Rows.Count, 1).End(xlUp).Row
Sheets("Sheet").Select
Cells(i + 1, 1).Select
ActiveCell.PasteSpecial xlPasteAll
wbk.Close True
Filename = Dir

Loop
End Sub

You'd be better using Power Query to aggregate data from your workbooks. — Olly, Dec 20 '17 at 11:49
You miss ``\`` at the end of `Path`. I recommend to loop using `FileSystemObject` — AntiDrondert, Dec 20 '17 at 11:52

score 1 · Accepted Answer · answered Dec 20 '17 at 11:59

Using your coding style, try something like this to get what you need:

Sub MergeDifferentWorkbooksTogether()

    Dim wbk As Workbook
    Dim wbk1 As Workbook
    Set wbk1 = ThisWorkbook
    Dim Filename As String
    Dim Path As String

    Path = "C:\Users\SomeFile\"
    Filename = Dir(Path & "*.xlsx")

    Do While Len(Filename) > 0
        Debug.Print Filename
        Set wbk = Workbooks.Open(Path & Filename)
        wbk.Activate
        Range("A2").Select
        Range(ActiveCell, ActiveCell.End(xlDown).End(xlToRight)).Copy
        wbk.Activate
        Application.DisplayAlerts = False
        Dim i As Long
        i = wbk1.Worksheets(1).Range("A:A").End(xlUp).Row
        Worksheets(2).Select
        Cells(i + 1, 1).Select
        ActiveCell.PasteSpecial xlPasteAll
        wbk.Close True
        Filename = Dir
    Loop

End Sub

In general, as mentioned in the comments, you need to end your path with a \ sign. Then make sure that your code uses the correct references - e.g. Cell should be written Cells and etc.

As a third step somewhere in the future, try to avoid Selection and ActiveCell in VBA, it slows you down and it can lead to some errors - How to avoid using Select in Excel VBA

score 0 · Answer 2 · answered Dec 21 '17 at 00:05

So, 97 workbooks merged into 1, right.

Merge a range from all workbooks in a folder (below each other)

Sub Basic_Example_1()
    Dim MyPath As String, FilesInPath As String
    Dim MyFiles() As String
    Dim SourceRcount As Long, Fnum As Long
    Dim mybook As Workbook, BaseWks As Worksheet
    Dim sourceRange As Range, destrange As Range
    Dim rnum As Long, CalcMode As Long

    'Fill in the path\folder where the files are
    MyPath = "C:\Users\Ron\test"

    'Add a slash at the end if the user forget it
    If Right(MyPath, 1) <> "\" Then
        MyPath = MyPath & "\"
    End If

    'If there are no Excel files in the folder exit the sub
    FilesInPath = Dir(MyPath & "*.xl*")
    If FilesInPath = "" Then
        MsgBox "No files found"
        Exit Sub
    End If

    'Fill the array(myFiles)with the list of Excel files in the folder
    Fnum = 0
    Do While FilesInPath <> ""
        Fnum = Fnum + 1
        ReDim Preserve MyFiles(1 To Fnum)
        MyFiles(Fnum) = FilesInPath
        FilesInPath = Dir()
    Loop

    'Change ScreenUpdating, Calculation and EnableEvents
    With Application
        CalcMode = .Calculation
        .Calculation = xlCalculationManual
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    'Add a new workbook with one sheet
    Set BaseWks = Workbooks.Add(xlWBATWorksheet).Worksheets(1)
    rnum = 1

    'Loop through all files in the array(myFiles)
    If Fnum > 0 Then
        For Fnum = LBound(MyFiles) To UBound(MyFiles)
            Set mybook = Nothing
            On Error Resume Next
            Set mybook = Workbooks.Open(MyPath & MyFiles(Fnum))
            On Error GoTo 0

            If Not mybook Is Nothing Then

                On Error Resume Next

                With mybook.Worksheets(1)
                    Set sourceRange = .Range("A1:C1")
                End With

                If Err.Number > 0 Then
                    Err.Clear
                    Set sourceRange = Nothing
                Else
                    'if SourceRange use all columns then skip this file
                    If sourceRange.Columns.Count >= BaseWks.Columns.Count Then
                        Set sourceRange = Nothing
                    End If
                End If
                On Error GoTo 0

                If Not sourceRange Is Nothing Then

                    SourceRcount = sourceRange.Rows.Count

                    If rnum + SourceRcount >= BaseWks.Rows.Count Then
                        MsgBox "Sorry there are not enough rows in the sheet"
                        BaseWks.Columns.AutoFit
                        mybook.Close savechanges:=False
                        GoTo ExitTheSub
                    Else

                        'Copy the file name in column A
                        With sourceRange
                            BaseWks.cells(rnum, "A"). _
                                    Resize(.Rows.Count).Value = MyFiles(Fnum)
                        End With

                        'Set the destrange
                        Set destrange = BaseWks.Range("B" & rnum)

                        'we copy the values from the sourceRange to the destrange
                        With sourceRange
                            Set destrange = destrange. _
                                            Resize(.Rows.Count, .Columns.Count)
                        End With
                        destrange.Value = sourceRange.Value

                        rnum = rnum + SourceRcount
                    End If
                End If
                mybook.Close savechanges:=False
            End If

        Next Fnum
        BaseWks.Columns.AutoFit
    End If

ExitTheSub:
    'Restore ScreenUpdating, Calculation and EnableEvents
    With Application
        .ScreenUpdating = True
        .EnableEvents = True
        .Calculation = CalcMode
    End With
End Sub

RDB_Last function to find the last cell or row

Function RDB_Last(choice As Integer, rng As Range)
'Ron de Bruin, 5 May 2008
' 1 = last row
' 2 = last column
' 3 = last cell
    Dim lrw As Long
    Dim lcol As Integer

    Select Case choice

    Case 1:
        On Error Resume Next
        RDB_Last = rng.Find(What:="*", _
                            after:=rng.cells(1), _
                            Lookat:=xlPart, _
                            LookIn:=xlFormulas, _
                            SearchOrder:=xlByRows, _
                            SearchDirection:=xlPrevious, _
                            MatchCase:=False).Row
        On Error GoTo 0

    Case 2:
        On Error Resume Next
        RDB_Last = rng.Find(What:="*", _
                            after:=rng.cells(1), _
                            Lookat:=xlPart, _
                            LookIn:=xlFormulas, _
                            SearchOrder:=xlByColumns, _
                            SearchDirection:=xlPrevious, _
                            MatchCase:=False).Column
        On Error GoTo 0

    Case 3:
        On Error Resume Next
        lrw = rng.Find(What:="*", _
                       after:=rng.cells(1), _
                       Lookat:=xlPart, _
                       LookIn:=xlFormulas, _
                       SearchOrder:=xlByRows, _
                       SearchDirection:=xlPrevious, _
                       MatchCase:=False).Row
        On Error GoTo 0

        On Error Resume Next
        lcol = rng.Find(What:="*", _
                        after:=rng.cells(1), _
                        Lookat:=xlPart, _
                        LookIn:=xlFormulas, _
                        SearchOrder:=xlByColumns, _
                        SearchDirection:=xlPrevious, _
                        MatchCase:=False).Column
        On Error GoTo 0

        On Error Resume Next
        RDB_Last = rng.Parent.cells(lrw, lcol).Address(False, False)
        If Err.Number > 0 Then
            RDB_Last = rng.cells(1).Address(False, False)
            Err.Clear
        End If
        On Error GoTo 0

    End Select
End Function

That if from here.

https://www.rondebruin.nl/win/s3/win008.htm

Also, consider using this Excel AddIn.

https://www.rondebruin.nl/win/addins/rdbmerge.htm

Merge Different workbooks into one

2 Answers2