How to concatenate child elements under one parent node by | separator in XSLT?

Question

I have an issue while concatenating all the the child elements under parent element.

Here is the source data

<?xml version="1.0" encoding="UTF-8" standalone="no"?>
<PurchaseOrder id="abc">
    <attr attr-name="A">
        <new-value>123</new-value>
    </attr>
    <attr attr-name="B">
        <new-value>99</new-value>
    </attr>
    <attr attr-name="B">
        <new-value>77</new-value>
    </attr>
    <attr attr-name="C">
        <new-value>1</new-value>
        <new-value>2</new-value>
        <new-value>3</new-value>
        <new-value>4</new-value>
        <new-value>5</new-value>
        <new-value>6</new-value>
        <new-value>7</new-value>
        <new-value>8</new-value>
    </attr>
    <attr attr-name="D">
        <new-value>
            <child1>567</child1>
            <child2>2</child2>
        </new-value>
    </attr>
    <attr attr-name="E">
        <new-value>
            <child3>890</child3>
            <child4>3</child4>
        </new-value>
    </attr>
</PurchaseOrder>

XSLT Transformation used

<?xml version="1.0" encoding="UTF-8"?>
    <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:ns0="urn:demo:PurchaseOrder">
        <xsl:output method="xml" indent="yes" />
        <xsl:strip-space elements="*" />
        <xsl:key name="keyAttrName" match="attr" use="@attr-name" />
        <xsl:template match="PurchaseOrder">
            <ns0:PurchaseOrderMSG>>
                <Orders>
                    <Order id="{@id}">
                        <xsl:for-each select="attr[generate-id() = generate-id(key('keyAttrName', @attr-name)[1])]">
                            <xsl:variable name="nodeName" select="@attr-name" />
                            <xsl:choose>
                                <xsl:when test="key('keyAttrName', @attr-name)/new-value/*/node()">
                                    <xsl:for-each select="new-value">
                                        <xsl:element name="{$nodeName}">
                                            <xsl:copy-of select="*" />
                                        </xsl:element>
                                    </xsl:for-each>
                                </xsl:when>
                                <xsl:when test="key('keyAttrName', @attr-name)/new-value/materials/material">
                                    <xsl:for-each select="key('keyAttrName', @attr-name)">
                                        <xsl:element name="{$nodeName}">
                                            <xsl:copy-of select="attr" />
                                        </xsl:element>
                                    </xsl:for-each>
                                </xsl:when>
                                <xsl:otherwise>
                            <xsl:for-each select="key('keyAttrName', @attr-name)">
                               <xsl:element name="{$nodeName}">
                                  <xsl:if test="position()!=1">
                                     <ns0:text>|</ns0:text>
                                  </xsl:if>
                                  <xsl:value-of select="."/>
                               </xsl:element>
                            </xsl:for-each>
                                </xsl:otherwise>
                            </xsl:choose>
                        </xsl:for-each>
                    </Order>
                </Orders>
            </ns0:PurchaseOrderMSG>
        </xsl:template>
    </xsl:stylesheet>

The expected Result should be

<?xml version="1.0" encoding="UTF-8"?>
<ns0:PurchaseOrderMSG xmlns:ns0="urn:demo:PurchaseOrder">
    <Orders>
        <Order>
            <A>123</A>
            <B>99</B>
            <B>77</B>
            <C>1|2|3|4|5|6|7|8</C>
            <D>
                <child1>567</child1>
                <child2>2</child2>
            </D>
            <E>
                <child3>890</child3>
                <child4>3</child4>
            </E>
        </Order>
    </Orders>
</ns0:PurchaseOrderMSG>

The output that is coming with the XSLT I have used is as below. Separator logic is not working.

<?xml version="1.0" encoding="UTF-8"?>
<ns0:PurchaseOrderMSG xmlns:ns0="urn:demo:PurchaseOrder">
    <Orders>
        <Order>
            <A>123</A>
            <B>99</B>
            <B>77</B>
            <C>12345678</C>
            <D>
                <child1>567</child1>
                <child2>2</child2>
            </D>
            <E>
                <child3>890</child3>
                <child4>3</child4>
            </E>
        </Order>
    </Orders>
</ns0:PurchaseOrderMSG>

I have tried logic mentioned in some blogs but no luck

XSLT merging/concatenating values of siblings nodes of same name into single node

Concatenate several child items into one child item using XSLT

score 1 · Accepted Answer · answered Dec 28 '17 at 05:00

You need to modify the <xsl:otherwise> condition to handle the values in <new-value> node as below. If the count of <new-value> child nodes is > 1, then perform the concatenation using the separator else just output the value as is.

<xsl:otherwise>
    <xsl:for-each select="key('keyAttrName', @attr-name)">
        <xsl:element name="{$nodeName}">
            <xsl:choose>
                <xsl:when test="count(new-value) &gt; 1">
                    <xsl:for-each select="new-value">
                        <xsl:value-of select="." />
                        <xsl:if test="position() != last()">
                            <xsl:value-of select="'|'" />
                        </xsl:if>
                    </xsl:for-each>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="." />
                </xsl:otherwise>
            </xsl:choose>
        </xsl:element>
    </xsl:for-each>
</xsl:otherwise>

The complete XSLT and the output is as below.

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:ns0="urn:demo:PurchaseOrder">
    <xsl:output method="xml" indent="yes" />
    <xsl:strip-space elements="*" />
    <xsl:key name="keyAttrName" match="attr" use="@attr-name" />
    <xsl:template match="PurchaseOrder">
        <ns0:PurchaseOrderMSG>
            <Orders>
                <Order id="{@id}">
                    <xsl:for-each select="attr[generate-id() = generate-id(key('keyAttrName', @attr-name)[1])]">
                        <xsl:variable name="nodeName" select="@attr-name" />
                        <xsl:choose>
                            <xsl:when test="key('keyAttrName', @attr-name)/new-value/*/node()">
                                <xsl:for-each select="new-value">
                                    <xsl:element name="{$nodeName}">
                                        <xsl:copy-of select="*" />
                                    </xsl:element>
                                </xsl:for-each>
                            </xsl:when>
                            <xsl:when test="key('keyAttrName', @attr-name)/new-value/materials/material">
                                <xsl:for-each select="key('keyAttrName', @attr-name)">
                                    <xsl:element name="{$nodeName}">
                                        <xsl:copy-of select="attr" />
                                    </xsl:element>
                                </xsl:for-each>
                            </xsl:when>
                            <xsl:otherwise>
                                <xsl:for-each select="key('keyAttrName', @attr-name)">
                                    <xsl:element name="{$nodeName}">
                                        <xsl:choose>
                                            <xsl:when test="count(new-value) &gt; 1">
                                                <xsl:for-each select="new-value">
                                                    <xsl:value-of select="." />
                                                    <xsl:if test="position() != last()">
                                                        <xsl:value-of select="'|'" />
                                                    </xsl:if>
                                                </xsl:for-each>
                                            </xsl:when>
                                            <xsl:otherwise>
                                                <xsl:value-of select="." />
                                            </xsl:otherwise>
                                        </xsl:choose>
                                    </xsl:element>
                                </xsl:for-each>
                            </xsl:otherwise>
                        </xsl:choose>
                    </xsl:for-each>
                </Order>
            </Orders>
        </ns0:PurchaseOrderMSG>
    </xsl:template>
</xsl:stylesheet>

Output

<ns0:PurchaseOrderMSG xmlns:ns0="urn:demo:PurchaseOrder">
    <Orders>
        <Order id="abc">
            <A>123</A>
            <B>99</B>
            <B>77</B>
            <C>1|2|3|4|5|6|7|8</C>
            <D>
                <child1>567</child1>
                <child2>2</child2>
            </D>
            <E>
                <child3>890</child3>
                <child4>3</child4>
            </E>
        </Order>
    </Orders>
</ns0:PurchaseOrderMSG>

Hello Aniket..Excellent ..Awesome..Thanks a ton for your solution...It is working as expected.I have accepted the answer :) — piuser, Dec 28 '17 at 06:03

How to concatenate child elements under one parent node by | separator in XSLT?

1 Answers1