Create Perl function which accepts optional file handle like built-in print?

Question

How to declare the function prototype if I want to get similar parameter passing as built-in print, like accepts optional first parameter which is file handle? For example, the calling syntax would be myprint $filehandle @mylist.

Answer 1

The syntax of print can't be replicated by Perl subs.

$ perl -le'print defined(prototype("CORE::print")) ? "Can" : "Can'\''t", " be replicated"'
Can't be replicated

Specifically, the syntax NAME EXPR LIST can't be used to call a Perl sub because the syntax is for an indirect method call. NAME EXPR LIST already means EXPR->NAME(LIST)

Option 1

# myprint $fh, LIST
# myprint *FH, LIST
# myprint \*FH, LIST

sub myprint {
   my $fh = shift;
   ...
}

Option 2

# myprint $fh, LIST
# myprint *FH, LIST
# myprint \*FH, LIST
# myprint FH, LIST

sub myprint(*@) {
   my $fh = shift;
   if (!ref($fh)) {
      $fh = caller().'::'.$fh if $fh !~ /^(?:ARGV|STD(?:IN|OUT|ERR))\z/;
      no strict qw( refs );
      $fh = \*$fh;
   }

   ...
}

---

On the flip side, even print doesn't actually support print EXPR LIST. It supports the following syntaxes:

print LIST         # Short for: print { select() } LIST
print IDENT LIST   # Short for: print { \*IDENT  } LIST
print $VAR LIST    # Short for: print { $VAR     } LIST
print BLOCK LIST

You can actually support the final form of print (for which the others are merely shortcuts):

# myprint { select } LIST
# myprint { $fh } LIST
# myprint { *FH } LIST
# myprint { \*FH } LIST

sub myprint(&@) {
   my $fh = shift->();
   ...
}

I like this solution less than the first two.

Answer 2

print $fh @list as an example of an indirect method call, equivalent to

$fh->print(@list)

To use a different function that can be indirectly invoked with a filehandle, define it in the IO::Handle package.

sub IO::Handle::myprint {
    my ($self, @list) = @_;
    #$self->print(scalar localtime,": ",@list);
    print $self scalar localtime, ": ", @list;
}

open my $fh, '>', 'foo';
print $fh "hello\n";          # IO::Handle::print($fh, "hello\n")
myprint $fh "world\n";        # IO::Handle::myprint($fh, "world\n")
close $fh;

This works with Perl v5.16 and better, and doesn't work with Perl v5.12 and earlier, for reasons I haven't investigated (maybe it's because it's not until v5.14 or v5.16 that all filehandles are automatically blessed into IO::File)

This seems to work on all versions of Perl back to at least v5.8. It's the syntax $self->print(...) inside the myprint method that requires v5.16 (or maybe v5.14, whenever it was that all filehandles were automatically blessed into IO::File) -- print $self ... still works with older Perls.