Unable to get the distinct values for particular node of XML in XSLT

Question

I have some XML like this:

<?xml version="1.0" encoding="UTF-8"?>
<Results>
    <Build>
            <Test>
                <car value=""/>
                <car value="abc"/>
                <car value=""/>
                <car value="xyz"/>  
            </Test> 
    </Build>
    <Build>         
            <Test>
                <car value=""/>
                <car value="xyz"/>
                <car value="xyz"/>
                <car value="mno" />
            </Test>
    </Build>
    <Build>     
            <Test>
                <car  value=""/>
                <car value="xyz"/>
                <car value="xyz"/>
                <car value="mno" />
            </Test>     
    </Build>
</Results>

and I want the out for 2nd Build node element like this:

xyz
mno

I have tried many ways.kindly refer to below code. it was working perfectly for Build[1] but when i tried to run it for particularity Build[2] and Build[3], output is not as expected.

<xsl:template match="Results">
    <xsl:apply-templates select="Build[2]" />
</xsl:template>

<xsl:template match="Build">
    <html>
        <body>
            <xsl:for-each select="Test/car[not(@value = (preceding:: car/@value))]">
                <xsl:sort select="@value" />
                <xsl:if test="@value!=''">
                    <li>
                        <xsl:value-of select='@value' />
                    </li>
                </xsl:if>
            </xsl:for-each>
        </body>
    </html>
</xsl:template>

It gives me this output:

<html>  
<body>  
<li>mno</li>  
</body>  
</html>

Can someone help me to resolve this issue?

Please always say which version of XSLT you are using. Many tasks like this are much easier with XSLT 2.0 or 3.0. — Michael Kay, Jan 31 '18 at 14:44
What is your desired output? Is the HTML list just missing *abc* and *xyz*? — Parfait, Jan 31 '18 at 16:09
@Parfait yes thi sis HTML list which have the unique values i.e abc and xyz — Meenu Garg, Feb 01 '18 at 05:09

score 1 · Accepted Answer · answered Jan 31 '18 at 13:37

There is already a good answer here at SO. Applied to your special situation you have at least the following two solutions:

In XSLT-2.0 you have the distinct-values function which makes this a lot easier by simply the using this for-each loop.

<xsl:for-each select="distinct-values(Test/car/@value)">
    <xsl:sort select="." />
    <xsl:if test=".!=''">
        <li>
            <xsl:value-of select='.' />
        </li>
    </xsl:if>
</xsl:for-each>

In XSLT-1.0 the following solution will work. It's a bit more complicated, but quite similar to your approach:

<xsl:template match="Build">
    <html>
        <body>
            <xsl:for-each select="Test/car[@value!='' and not(@value=preceding-sibling::car/@value)]">
                <xsl:sort select='@value' />
                <li>
                    <xsl:value-of select='@value' />
                </li>
            </xsl:for-each>
        </body>
    </html>
</xsl:template>

Unable to get the distinct values for particular node of XML in XSLT

1 Answers1