How to write a xpath to match all elements except a particular element

Question

I am writing an XSL transformation. I want to write a template which matches all the child elements of the document except one particular node. My xml looks like this -

<Document>
    <NodeA></NodeA>

    <NodeB></NodeB>

    <ServiceNode></ServiceNode>

    <NodeX></NodeX>
</Document>

I want to write a template that matches all nodes except ServiceNode i.e. NodeA to NodeX. How to write this Xpath to get -

<xsl:template match="ALL Nodex Except ServiceNode">

Good question, +1. See my answer for four alternative solutions for four different possible meanings of this question. — Dimitre Novatchev, Feb 01 '11 at 13:41

score 36 · Accepted Answer · edited Feb 01 '11 at 16:48

I want to write a template that matches all nodes except ServiceNode i.e. NodeA to NodeX.

If by "node" you mean element, then use:

<xsl:template match="*[not(self::ServiceNode)]">

If by "node" you mean any node (of type element, text, comment, processing-instruction): use

<xsl:template match="node()[not(self::ServiceNode)]">

If you want only children of Document to be matched use:

<xsl:template match="Document/node()[not(self::ServiceNode)]">

If you want only children of the top element to be matched use:

<xsl:template match="/*/node()[not(self::ServiceNode)]">

score 7 · Answer 2 · answered Feb 01 '11 at 08:13

You should better use this expression:

*[not(self::ServiceNode)]

As incorporated in an XSLT:

<xsl:stylesheet
    version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>

    <xsl:template match="/*">
        <xsl:apply-templates select="*[not(self::ServiceNode)]"/>
    </xsl:template>

    <xsl:template match="*">
        <xsl:value-of select="."/>
        <xsl:text>&#xA;</xsl:text>
    </xsl:template>

</xsl:stylesheet>

With this XML sample:

<Document>
    <NodeA>1</NodeA>
    <NodeB>2</NodeB>
    <ServiceNode>3</ServiceNode>
    <NodeX>4</NodeX>
</Document>

It will give a correct result:

1
2
4

Correct. This is better than testing on name() or local-name(). In XPath 2.0 an alternative is (* except ServiceNode) — Michael Kay, Feb 01 '11 at 09:41

score 5 · Answer 3 · edited Oct 02 '14 at 23:30

5

<xsl:template match="Document/*[name() != 'ServiceNode']">

(or local-name() if you have to deal with namespaces)

edited Oct 02 '14 at 23:30

slugster

49,403
14
95
145

answered Feb 01 '11 at 07:16

user568826

581
5
16

I recommend testing in a live evaluator like http://www.whitebeam.org/library/guide/TechNotes/xpathtestbed.rhtm where you can paste expressions like //*[name()!="pet"] – Chris Dolan Feb 01 '11 at 07:26

score 3 · Answer 4 · answered Feb 01 '11 at 10:32

3

You could use two templates:

<xsl:template match="Document/*">
   ...do something...
</xsl:template>


<xsl:template match="Document/ServiceNode" />

The later template will take priority, so the first template will match everything except ServiceNode.

answered Feb 01 '11 at 10:32

Nick Jones

6,413
2
18
18

This could be useful in some cases, besides it doesn't answer this question properly. – Feb 01 '11 at 16:53

score 0 · Answer 5 · answered Feb 01 '11 at 07:21

0

/Document/*[not(name()='ServiceNode')]

answered Feb 01 '11 at 07:21

Amit Patel

15,609
18
68
106

How to write a xpath to match all elements except a particular element

5 Answers5

Linked