Append zeros to list

Question

I have the following input file:

a,10,12,13
b,20,22
c,30
d,33

and would like to append zeros until each line has three numbers, so this should be the output:

a,10,12,13
b,20,22,0
c,30,0,0
d,33,0,0

In sed I could do use these two commands:

sed 's/\([a-z],[0-9]\+$\)/\1,0,0/g'
sed 's/\([a-z],[0-9]\+,[0-9]\+$\)/\1,0/g'

My regex knowledge is limited to sed and I would like to know how to achieve this with awk or perl.

Answer 1

As a Perl one-liner

perl -pe 's/$/,0/ until tr/,// >= 3' myfile

output

a,10,12,13
b,20,22,0
c,30,0,0
d,33,0,0

Answer 2

Super simple in awk.

$ awk -F, '{for(;NF<4;$(NF+1)=0);} 1' OFS=, i.csv

This uses a for loop whose condition is your field count goal and whose action adds another field. This works in BSD awk and GNU awk, I haven't tested in mawk or other awks.

In sed, however, the solution looks a little more complicated.

$ sed -e ':start' -e '/,.*,.*,/b end' -e 's/$/,0/' -e 'b start' -e ':end' i.csv

Or more compactly:

$ sed -e ':start
  /,.*,.*,/b end
  s/$/,0/
  b start
  :end' i.csv

The strategy here is to test for four fields by looking for three field separators, then step through a loop that adds a ,0 until we pass that test, at which point we b end (branch to the :end label) to quit. Then print the line, as it's the default action.

This was tested in BSD sed, but should be equally compatible (and perhaps more compactable) in GNU sed.

Answer 3

$ awk 'BEGIN{FS=OFS=","} {for (i=2;i<=4;i++) $i+=0} 1' file
a,10,12,13
b,20,22,0
c,30,0,0
d,33,0,0

Answer 4

With perl

$ perl -F, -lane 'print join ",", @F, (0)x(3-$#F)' ip.txt
a,10,12,13
b,20,22,0
c,30,0,0
d,33,0,0

$ perl -F, -lane 'print join ",", @F, ("NA")x(3-$#F)' ip.txt
a,10,12,13
b,20,22,NA
c,30,NA,NA
d,33,NA,NA

• -F, input field delimiter is , and results are accessible from @F array
  • See https://perldoc.perl.org/perlrun.html#Command-Switches for command line option details
• (0)x(3-$#F) add missing zeroes. $#F gives index of last element, for example it is 2 for the second line - so 3-2 zeroes added
  • ("NA")x(3-$#F) to use NA instead of 0 as filler element
• join "," use , as delimiter to join array elements

Inspired from Borodin's answer

$ perl -pe 's|$|",0" x (3 - tr/,//)|e' ip.txt 
a,10,12,13
b,20,22,0
c,30,0,0
d,33,0,0

• e modifier allows to use Perl code in replacement section
• tr/,// will give number of , in input line
• x will repeat the given string by (3 - tr/,//)

Answer 5

Following awk may help here too.

awk -F, 'NF<4{i="";while(i<(4-NF)){val=val?val OFS "0":",0";i++}}{print $0 val;val=""}' OFS=,  Input_file

Adding a non-one liner form of solution too now.

awk -F, '
NF<4{
  i="";
  while(i<(4-NF)){
    val=val?val OFS "0":",0";
    i++}
}
{
  print $0 val;
  val=""
}' OFS=,  Input_file

Answer 6

In awk:

$ awk 'BEGIN{FS=OFS=",";nf=4}{for(i=(NF+1);i<=nf;i++)$i=0}1' file
a,10,12,13
b,20,22,0
c,30,0,0
d,33,0,0

Explained:

$ awk '
BEGIN {
    FS=OFS=","               # separators
    nf=4                     # desired field count
}
{
    for(i=(NF+1);i<=nf;i++)  # da loop to create new fields
        $i=0                 # set new fields to 0 
}1' file                     # output

Answer 7

awk 'BEGIN{FS=OFS=","}$3==""{$3="0"}$4==""{$4="0"}1' file

a,10,12,13
b,20,22,0
c,30,0,0
d,33,0,0

First it says to keep the field separator in the output as well and then fill empty fields in $3,$4 with zeros.