batch script to rename all files less than current date

Question

I am trying to rename all the files in a folder which are less than current date. I am trying rename the image files in the format below.

1:
DRS01_773705373_20180329173532680_ALARM_INPUT.JPG.

After Renaming:
Cam 1_20180329173532680.jpg

There are several thousand images in folder with different timings, I need to rename the files which are older than current date.

Code:

@echo off
setlocal enableDelayedExpansion
for %%F in (DRS01_773705373_20180329173532680_ALARM_INPUT.jpg) do (
  set "name=%%F"
  ren "!name!" "!name:DRS01=Cam 1!" (stuck here)
)

I need to get rid of the ID 773705373 and_ALARM_INPUT from the filenames.

Use a `for /f` splitting the file name at the underscores and taking only the 3rd token. — , Apr 29 '18 at 10:44
Why are you checking the age of the images? If you run the script tomorrow then today's files will get renamed too, so why does one day make such a difference. It is extremely unlikely that you'll have images on your computer today named with tomorrows or next weeks date and time stamps. Just rename every image matching the file naming pattern. — Compo, Apr 29 '18 at 12:11

score 0 · Answer 1 · 2018-04-30T11:16:24.653

The first for iterates the files
The 2nd splits at _ leaving only 3rd token
the if compares the first 8 places of the date time strings

Untested:

@echo off & setlocal enableDelayedExpansion
:: Get Date
for /f "tokens=1-3 delims=.+-" %%A in (
  'wmic os get LocalDateTime^|findstr ^^[0-9]'
) do Set Today=%%A

for %%A in (DRS01_*_*_ALARM_INPUT.jpg) do (
  for /f "tokens=3 delims=_" %%B in ("%%A") do (
    set "FileDate=%%B"
    If "!FileDate:~0,8!" lss "%Today:~0,8%" (
      ren "%%A" "Cam 1_%%B%%~xA" 
    )
  )
)

Mofi · Accepted Answer · 2019-10-09T16:26:11.533

Here is my commented batch file solution which of course is very similar to solution posted by LotPings.

@echo off
setlocal EnableExtensions EnableDelayedExpansion
set "Folder=%CD%"
if "%Folder:~-1%" == "\" set "Folder=%Folder:~0,-1%"

rem Determine current local date using a region independent method in
rem basic international format yyyyMMdd according to ISO 8601:2004.
for /F "tokens=2 delims==." %%I in ('%SystemRoot%\System32\wbem\wmic.exe OS GET LocalDateTime /VALUE') do set "CurrentDate=%%I"
set "CurrentDate=%CurrentDate:~0,8%"

rem Process all non hidden files with three underscores in file name and of
rem which file name ends with ALARM_INPUT and having file extension JPG.

rem On each iteration of the loop first is determined the third underscore
rem delimited part from file name which contains the date in first 8 chars.
rem If the current file name has not the current date in file name, the
rem file name is modified to required format.

for /F "delims=" %%I in ('dir "%Folder%\*_*_*_ALARM_INPUT.JPG" /A-D /B /ON 2^>nul') do (
    for /F "tokens=3 delims=_" %%J in ("%%I") do set "FileDateNumber=%%J"
    if not "!FileDateNumber:~0,8!" == "%CurrentDate%" ren "%Folder%\%%I" "Cam 1_!FileDateNumber!.jpg"
)

endlocal

This batch file runs by default in current directory. The directory can be changed to directory of the batch file by modifying %CD% to %~dp0 in second line. And it is of course also possible to specify any other directory in second line.

This solution above works only with no file having an exclamation mark in file name.
Otherwise the batch code below using a subroutine is required for this file renaming task.

@echo off
setlocal EnableExtensions DisableDelayedExpansion
set "Folder=%CD%"
if "%Folder:~-1%" == "\" set "Folder=%Folder:~0,-1%"

rem Determine current local date using a region independent method in
rem basic international format yyyyMMdd according to ISO 8601:2004.
for /F "tokens=2 delims==." %%I in ('%SystemRoot%\System32\wbem\wmic.exe OS GET LocalDateTime /VALUE') do set "CurrentDate=%%I"
set "CurrentDate=%CurrentDate:~0,8%"

rem Process all non hidden files with three underscores in file name and of
rem which file name ends with ALARM_INPUT and having file extension JPG.
for /F "delims=" %%I in ('dir "%Folder%\*_*_*_ALARM_INPUT.JPG" /A-D-H /B /ON 2^>nul') do call :FileRename "%Folder%\%%I"

endlocal
goto :EOF

rem The subroutine FileRename first gets third underscore delimited part
rem from file name which contains the date in first 8 characters. If the
rem current file name has not the current date in file name, the subroutine
rem renames the file to required format.

:FileRename
for /F "tokens=3 delims=_" %%J in ("%~n1") do set "FileDateNumber=%%J"
if not "%FileDateNumber:~0,8%" == "%CurrentDate%" echo ren %1 "Cam 1_%FileDateNumber%.jpg"
goto :EOF

For details on first FOR loop used to get current date independent on country set in Windows Region and Language settings for currently used account see my answer on Why does %date% produce a different result in batch file executed as scheduled task?

Both batch files use a string comparison for comparing the dates as I do not expect that a file contains a date in future in file name. It is of course possible to replace == by LSS and remove not in IF command line to run an integer comparison on comparing date in file name with current date. The integer comparison is a bit slower although not noticeable slower in comparison to total execution time.

The solutions use command DIR to process by FOR a captured list of file names to avoid possible problems like skipping some file names on using directly FOR for searching for files matching the wildcard pattern in case of the files are stored on a FAT32 or exFAT partition.

For understanding the used commands and how they work, open a command prompt window, execute there the following commands, and read entirely all help pages displayed for each command very carefully.

echo /?
endlocal /?
for /?
goto /?
if /?
rem /?
ren /?
set /?
setlocal /?

See also answer on Where does GOTO :EOF return to?

batch script to rename all files less than current date

2 Answers2