Clojure - How to check loop condition AFTER making calculation?

Question

I need to create a loop, that in a first step something should be calculated and result of that calculation should be passed to test condition. It's something like:

do (something) while (condition)

It's mandatory, that first pass should make calculation just before test condition should occur.

Is it possible to do in Clojure?

I've found similar problem here on StackOverflow, but it was unclear for me. Those solutions presented here are much more precise.

score 2 · Answer 1 · answered May 09 '18 at 06:20

Something like this, maybe:

(ns playground.core)

(defn do-while-loop [init-state do-something condition]
  (loop [state init-state]
    (let [next-state (do-something state)]
      (if (condition next-state)
        (recur next-state)
        next-state))))


playground.core> (do-while-loop 0 inc #(< % 6))
6
playground.core> (do-while-loop 0 inc #(< % 0))
1

init-state is the state you are looping on, do-something is a function to compute the next state, and condition is a function that returns a boolean value based on the state.

This is a purely functional do-while-loop with the condition being tested after the next state has been computed. And you can always add extra syntactic sugar on top of it using macros if you prefer that.

Carcigenicate · Answer 2 · 2018-05-08T22:18:22.613

1

I'd just use loop here. Whenever you can't decide how you want to loop, loop is a good starting point to feel things out since it's so general. A bare bones example would look like:

(loop []
  (let [result (some-calc)]
    (if (verify-result result) ; The condition
      (recur) ; Loop again
      result))) ; Or return the result of the calculation

Where some-calc is the producer, and verify-result checks if you should loop again.

You could even do away with the loop and use a recursive function:

(defn func []
  (let [result (some-calc)]
    (if (verify-result result)
      (recur)
      result)))

edited May 08 '18 at 22:18

answered May 08 '18 at 21:16

Carcigenicate

43,494
9
68
117

OK, that seems to be the solution for my idea, but what if I need to use calculations that have some "variables"? For instance: (/ (* 2 temp_val) some_number). Where I should put definitions of temp_val and some_number? – Boba_Fett May 09 '18 at 09:35
@Boba_Fett In the `let` inside the `loop`. – Carcigenicate May 09 '18 at 12:23
So it should look like this? `let [temp_val (blablabla)]` `let [some_number (blablabla)]` `let [result (/ (* 2 temp_val) some_number)` – Boba_Fett May 09 '18 at 13:03
@Boba_Fett You only need 1 `let`: `(let [temp-val (stuff) some-num (stuff) result (/ (* 2 temp-val) some-num)] result)`. – Carcigenicate May 09 '18 at 13:05
No, I'm just getting used to it :) – Boba_Fett May 09 '18 at 13:07
@Boba_Fett Oh, I see you've been using `def` instead of `let` when defining locally. Ya, definitely use `let` instead. – Carcigenicate May 09 '18 at 13:11
Yes, I will :) One more thing to clarify: `recur (something)` is operating inside of `let`? – Boba_Fett May 09 '18 at 13:44
@Boba_Fett Yes, because `result` is only available inside the let. All the vals defined by the let go out of scope when you leave it. If you want to recur with the result, it needs to be in the let. – Carcigenicate May 09 '18 at 13:46
OK, and what is the role of `loop` bindings? How do I affect them? – Boba_Fett May 09 '18 at 13:50
@Boba_Fett Using recur. This is getting a little broad, and hard to go over in comments. The Clojure docs on loop are very informative. If you look them over, it should make more sense. – Carcigenicate May 09 '18 at 14:01
@Boba_Fett https://clojuredocs.org/clojure.core/loop – Carcigenicate May 09 '18 at 14:01
@Boba_Fett Look at the third example, underneath the panda avatar. – Carcigenicate May 09 '18 at 14:02
OK, thanks for explanation. I'll follow Your guide. – Boba_Fett May 09 '18 at 18:20

Clojure - How to check loop condition AFTER making calculation?

2 Answers2