Using %date% in batch script

Question

I want to have some code like this:

if %date% equ "Mon" echo do this do that

but the cmd window closes after encountering this code, even if I put

pause

after it. How do I fix this?

Answer 1

You probably want to use:

IF /I "%DATE:~,3%"=="Mon" (Echo Do this
    Echo Do that)

Or possibly:

IF NOT "%DATE:Mon=%"=="%DATE%" (Echo Do this
    Echo Do that)

However neither of those are safe or robust methods in anything other than your specific current user environment.

This is how I'd get the day of the week into a variable using a batch file with WMIC:

For /F %%A In ('WMIC Path Win32_LocalTime Get DayOfWeek') Do For %%B In (
    Monday.1 Tuesday.2 Wednesday.3 Thursday.4 Friday.5 Saturday.6 Sunday.0
) Do If "%%~xB"==".%%A" Set "WDName=%%~nB"

Line 2 can be optionally adjusted to start with Sunday.0 Monday.1 etc. if necessary or Lunes.1 Martes.2 etc. depending upon your language.

You could then use:

If "%WDName%"=="Monday" (Echo Do this
    Echo Do that)

Although (Get-Date).DayOfWeek in PowerShell seems so much simpler.

Answer 2

Here's a complete cmd file that will give you what you need. The important bit is all in the getDow function and, hopefully, it's commented well enough to understand. First, the test harness:

@echo off
rem Test harness bit - just get current date and compare with getDow.

date /t
call :getDow num long short
echo Day of week is %num%, %long%, %short%
goto :eof

The function itself is:

rem Usage: call :getDow <num> <long> <short>
rem        <num> will receive the numeric form (0-6).
rem        <long> will receive the long form (e.g., Monday).
rem        <short> will receive the short form (e.g., Mon).

:getDow
    rem Create local scope to prevent information leakage.

    setlocal enableextensions enabledelayedexpansion

    rem Create array for translation.

    set idx=0
    for %%a in (Sunday Monday Tuesday Wednesday Thursday Friday Saturday) do (
        set dow[!idx!]=%%a
        set /a "idx += 1"
    )

    rem Get the numeric day of week, mmi command will
    rem output 'DayOfWeek=N' and we just extract N.

    for /f "tokens=2 delims==" %%a in ('WMIC Path Win32_LocalTime Get DayOfWeek /value ^| findstr "DayOfWeek="') do (
        set localNum=%%a
    )
    set localStr=!dow[%localNum%]!

    rem Properly end scope but let selected information leak.

    endlocal&&set %1=%localNum%&&set %2=%localStr%&&set %3=%localStr:~0,3%
    goto :eof

A sample run of that script gives:

Tue Jun 05
Day of week is 2, Tuesday, Tue