Unable to click a JavaScript based link which is also the part of a table on a webpage using web elements through VBA

Question

I am attempting to automate a certain process for my business by clicking on certain links on a webpage, inputting business data into a search box and compare it with existing data. I am however, unsuccessful at clicking a javascript based link which also the part of the table using VBA. The website's relevant HTML is as below,

<tr class="odd"> <td> <a onclick="viewCompanyDetails('B214273', '1529481460070');" href="javascript:;">Alinda Infrastructure Fund III (Euro) GP SARL</a></td> <td><a onclick="viewCompanyDetails('B214273', '1529481460070');" href="javascript:;">B214273</a></td> </tr>

Here is my poor attempt at doing the project,

        Private Sub CommandButton1_Click()
        Set IE = CreateObject("InternetExplorer.Application")
        my_url = "https://www.lbr.lu/mjrcs/jsp/DisplayConsultDocumentsActionNotSecured.action?FROM_MENU=true&time=1528967707649&currentMenuLabel=menu.item.companyconsultation"

    consoletext = consoletext & "Connection established to Luxembourg Business Registers on www.rcsl.lu via Internet Explorer..." & vbNewLine & vbNewLine
    txtConsole.Value = consoletext
    consoletext = consoletext & "Looking up Registre De Commerce et des Societes." & vbNewLine & vbNewLine
    txtConsole.Value = consoletext

        With IE
            .Visible = True
            .navigate my_url

        Do Until Not IE.Busy And IE.readyState = 4
            DoEvents
        Loop

        End With

    For Each objlink In IE.document.getElementsByTagName("href")
    If objlink.href = "/mjrcs/jsp/DisplayConsultDocumentsActionNotSecured.action?FROM_MENU=true&time=1528969484260&currentMenuLabel=menu.item.companyconsultation" Then
    objlink.Click
    Exit For
    End If
    Next objlink

    Do Until Not IE.Busy And IE.readyState = 4
            DoEvents
        Loop

    consoletext = consoletext & "Looking up " & Sheets("Results").Range("N1").Value & " in the registry." & vbNewLine & vbNewLine
    txtConsole.Value = consoletext

    Dim TradeName As String
    TradeName = ThisWorkbook.Sheets("Results").Range("Y1").Value

     IE.document.getElementById("companyName").Value = TradeName

    Set objSubmit = IE.document.getElementsByTagName("input")

    For Each btn In objSubmit
        If btn.Value Like "Search" Then
            btn.Click
        End If
    Next

        Do Until Not IE.Busy And IE.readyState = 4
            DoEvents
        Loop

    For Each entitylink In IE.document.getElementsByClassName("tr")
    If entitylink.getElementsByTagName = "a" And entitylink.textcontent = Sheets("Results").Range("N1").Value And entitylink.href = "javascript:;" Then
    entitylink.Click
    Exit For
    End If
    Next entitylink


    txtXMLpath.Value = ""

End Sub

This is what the webpage content looks like,

enter image description here

I have hidden the name of the entity to protect the identity of the client. I need to click the result on the first row per the image.

I will be much obliged if you could provide any help. Again, I'm a beginner in VBA and have no idea how to proceed here. Please let me know should you require further clarification

Answer 1

You can use .querySelector to get the element you want which is the first with

.document.querySelector("a[onclick='viewCompanyDetails('B214273', '1529481460070');']")

Then you may need to do either:

.document.querySelector("a[onclick='viewCompanyDetails('B214273', '1529481460070');']").Click

or

.document.querySelector("a[onclick='viewCompanyDetails('B214273', '1529481460070');']").fireEvent 'onclick'

---

CSS selector:

The selector returns 2 items from your HTML but .querySelector will only return the first of these when applying the selector to the HTML. The first is the required "SARL".

---

More info on .fireEvent method:

fireEvent method: Fires a specified event on the object.

Syntax: object.fireEvent(bstrEventName, pvarEventObject,
pfCancelled)

It has a boolean return value which if TRUE tells you the event was successfully fired.

---

.querySelector method:

The Document method querySelector() returns the first Element within the document that matches the specified selector, or group of selectors. If no matches are found, null is returned.

Syntax: element = document.querySelector(selectors); <== note the ";" is not used in VBA

---

Edit:

If .querySelector method is not supported you could try looping the a tags and clicking when a particular string is found e.g.

Dim c As Object, n As Object
Set c = ie.document.getElementsByTagName("a")
For Each n In c
    If InStr(1, n.innerText, "Alinda Infrastructure Fund III (Euro) GP SARL") > 0 Then
        n.Click
        Exit For
    End If
Next n

Without more HTML to target the specific a tags of interest you can do a general write out of all a tags with:

Dim c As Object, n As Object, counter As Long
Set c = ie.document.getElementsByTagName("a")
With ActiveSheet
    For Each n In c
        counter = counter + 1
        .Cells(counter, 1) = n.innerText
    Next n
End With

More HTML is needed to target this better; perhaps there is a className or Id to identify the element housing these a tags?

For your link to write table to sheet:

Option Explicit
Public Sub GetInfo()
    Dim ie As Object
    Application.ScreenUpdating = False
    Set ie = CreateObject("InternetExplorer.Application")
    With ie
        .Visible = True
        .navigate "https://www.lbr.lu/mjrcs"

        While .Busy Or .readyState < 4: DoEvents: Wend '<== Loop until loaded

        Dim links As Object, link As Object
        Set links = .document.getElementsByTagName("a")

        For Each link In links
            If link.innerText = "View the person's file" Then
                link.Click
                Exit For
            End If
        Next link

        While .Busy Or .readyState < 4: DoEvents: Wend

        .document.getElementById("companyName").innerText = "Alinda"
        .document.getElementsByClassName("button")(0).Click

        While .Busy Or .readyState < 4: DoEvents: Wend

        Dim hTable As HTMLTable
        Set hTable = .document.getElementsByClassName("commonTable")(0)

        Dim n As Object, tRow As Object, tCell As Object, tr As Object, td As Object, r As Long, c As Long, hBody As Object

        r = 1
        With ActiveSheet
            Set hBody = hTable.getElementsByTagName("tbody")
            For Each n In hBody                 'HTMLTableSection
                Set tRow = n.getElementsByTagName("tr") 'HTMLTableRow
                For Each tr In tRow
                    Set tCell = tr.getElementsByTagName("td")
                    c = 1
                    For Each td In tCell         'DispHTMLElementCollection
                        .Cells(r, c).Value = td.innerText 'HTMLTableCell
                        c = c + 1
                    Next td
                    r = r + 1
                Next tr
            Next n
        End With
        .Quit '<== Remember to quit application
    End With
    Application.ScreenUpdating = True
End Sub