I have to replace a string present between two strings using 'sed' command in unix

Question

I have to replace a string present between two strings using sed command in Unix.

My Input is :

Apple'Mangoabcd'Orange'Mangoxyz'Lemon'

The command I used is

sed 's/Mango.*'"'"'/+XXXX'"'"'/'

My desired Output is

Apple'XXXX'Orange'XXXX'Lemon'

The output I get is

Apple'XXXX'

I want to replace 'Mango+freetext' with 'XXXX' in all the places.

Try `sed "s/Mango[^']*/XXXX/"`, or probably `sed "s/'Mango[^']*/'XXXX/"` will be more precise if `Mango` should be preceded with `'` — Wiktor Stribiżew, Jun 20 '18 at 12:13
Sorry. I missed few things. I have to replace free texts present between 'Mango' and first instance of ' . So, My input will be some thing like this "Input = Apple'Mangoabcd'Orange' — Sathya, Jun 20 '18 at 12:21
So, `sed "s/\(Mango\)[^']*/\1'XXXX/"`? Or just `sed "s/Mango[^']*/XXXX/"`? — Wiktor Stribiżew, Jun 20 '18 at 12:24
Possible duplicate of [Non greedy (reluctant) regex matching in sed?](https://stackoverflow.com/questions/1103149/non-greedy-reluctant-regex-matching-in-sed) — Wiktor Stribiżew, Jun 20 '18 at 12:30
I think all you need is [here](https://stackoverflow.com/a/1103159/3832970). There are other helpful answers there, too. — Wiktor Stribiżew, Jun 20 '18 at 12:30

kvantour · Accepted Answer · 2018-06-20T12:40:58.637

0

If you just want to replace Mango and you know it is Mango, then you just do
```
sed 's/Mango/XXXX/g'
```
If you want to replace Mango<freetext> where the freetext does not contain a single quote ', then you do :
```
sed "s/'Mango[^']*/'XXXX/g"
```
we added the extra quote before Mango to make sure we exclude strings such as 'SquashedMangoJuice'
If you want to replace the string between the words Apple and Orange, then you have to do it a bit different :
```
sed "s/Apple'[^']*'Orange/Apple'XXXX'Orange/g" 
```
or using back-references
```
sed "s/\(Apple'\)[^']*\('Orange\)/\1XXXX\2/g"
```

The reason why your original command is failing is that sed is greedy. What I mean is that the combination .*' will pick everything until the last quote. That is, it will represent Mango'Orange'. The culprit is the last quote after Orange. Above, we fixed this by replacing your . with [^']. This means all characters except the quote '.

edited Jun 20 '18 at 12:40

answered Jun 20 '18 at 12:17

kvantour

25,269
4
47
72

Sorry. I missed few things. I have to replace free texts present between 'Mango' and first instance of ' . So, My input will be some thing like this "Input = Apple'Mangoabcd'Orange' – Sathya Jun 20 '18 at 12:23
@Sathya, could you please update your original question to represent this. Especially the given input and expected output. Also clearly state if the Apples and Oranges have anything to do with the replacement (if it is a condition or not) or if `Pear'Mango_foobar'Banana'` should also be replaced. Also could the string that need to be replaced contain a quote. – kvantour Jun 20 '18 at 12:28
I have edited my question. I have multiple occurrence of the string which I am replacing in my Input. – Sathya Jun 20 '18 at 12:33
Hi, I tried the 2nd option. but it is replacing only the first instance. so my output is coming as " Apple'XXXX'Orange'Mangoabcd'Lemon' " instead of " Apple'XXXX'Orange'XXXX'Lemon' " – Sathya Jun 20 '18 at 12:47
Thank you so much for your help. 2nd Command perfectly suits my requirement :-) – Sathya Jun 21 '18 at 09:37
@Sathya you are welcome. Don't forget [someone answers](https://stackoverflow.com/help/someone-answers) – kvantour Jun 21 '18 at 09:40

I have to replace a string present between two strings using 'sed' command in unix

1 Answers1