Passing a parameter to CreateThread

Question

I am having a problem passing a class reference as the parameter to the ThreadProc in a call to CreateThread. Here is a sample program that demonstrates the problem I am having:

program test;

{$APPTYPE CONSOLE}

uses
  SysUtils, Windows, Dialogs;

type
    TBlah = class
        public
        fe: Integer;
    end;

function ThreadProc(param: Pointer) : DWORD;
begin
    ShowMessage(IntToStr(TBlah(param).fe));

    Result := 0;
end;

var
    tID: DWORD;
    handle: THandle;
    b: TBlah;
begin
    b := TBlah.Create;
    b.fe := 54;

    handle := CreateThread(nil, 0, @ThreadProc, Pointer(b), 0, tID);

    WaitForSingleObject(handle, INFINITE); 
end.

The call to ShowMessage pops up a message box that has something like 245729105 in it, not 54 like I expect.

This is probably just a basic misunderstanding of how Delphi works, so could someone please tell me how to get this working properly?

David Heffernan · Accepted Answer · 2011-02-24T21:07:14.247

10

The problem here is that your thread function has the wrong calling convention. You need to declare it with the stdcall convention:

function ThreadProc(param: Pointer) : DWORD; stdcall;

enter image description here

Having said that, it would be more idiomatic to just use a TThread descendant which handles the OOP to C function back to OOP transitioning for you. That would look like this:

type
  TBlah = class(TThread)
  protected
    procedure Execute; override;
  public
    fe: Integer;
  end;

procedure TBlah.Execute;
begin
  ShowMessage(IntToStr(fe));
end;

var
  b: TBlah;

begin
  b := TBlah.Create(True);
  b.fe := 42;
  b.Start;
  b.WaitFor;
end.

Incidentally, does anyone know why Windows.pas declares TFNThreadStartRoutine as TFarProc rather than a proper typed function pointer?

edited Feb 24 '11 at 21:07

answered Feb 24 '11 at 21:01

David Heffernan

601,492
42
1,072
1,490

3

`b.fe := 42;`, don't forget the `:` :) – Kokonotsu Feb 24 '11 at 21:04
2

@Kokonotsu Any particular reason for not using `TThread`? As for the `=` vs `:=`, guess I've been doing too much P/Invoke today! – David Heffernan Feb 24 '11 at 21:06
A lot of typing, and a *screenshot*... Fast you are! – Sertac Akyuz Feb 24 '11 at 21:09
@Sertac Thx! Thing is, I need a couple more accepts, I'm desperate. Slipping down the rankings this week!! ;-) – David Heffernan Feb 24 '11 at 21:12
@Sertac Just my obsessive personality!! ;-) – David Heffernan Feb 24 '11 at 21:17
@David: FYI, I have never seen anyone at 332 points before: http://stackoverflow.com/tags/delphi/topusers – Andreas Rejbrand Feb 24 '11 at 21:21
@Andreas I was more thinking of this one: http://stackexchange.com/leagues/1/week/stackoverflow – David Heffernan Feb 24 '11 at 21:23

score 9 · Answer 2 · answered Feb 24 '11 at 21:00

9

You're forgetting the stdcall directive.

function ThreadProc(param: Pointer) : DWORD; stdcall;

answered Feb 24 '11 at 21:00

Sertac Akyuz

54,131
4
102
169

score 1 · Answer 3 · edited Jan 31 '12 at 20:57

1

And don't use Pointer cast in:

handle := CreateThread(nil, 0, @ThreadProc, **Pointer**(b), 0, tID);

b is already a Pointer (a Class, which is an Object Pointer)

edited Jan 31 '12 at 20:57

stealthyninja

10,343
11
51
59

answered Jul 10 '11 at 02:45

Gustavo

11
1

Passing a parameter to CreateThread

3 Answers3