Xpath: filter out childs

Question

I'm looking for a xpath expression that filters out certain childs. A child must contain a CCC node with B in it.

Source:

<AAA>
    <BBB1>
        <CCC>A</CCC>
    </BBB1>       
    <BBB2>
        <CCC>A</CCC>
    </BBB2>
    <BBB3>
        <CCC>B</CCC>
    </BBB3>
    <BBB4>
        <CCC>B</CCC>
    </BBB4>
</AAA>

This should be the result:


<AAA>
    <BBB3>
        <CCC>B</CCC>
    </BBB3>
    <BBB4>
        <CCC>B</CCC>
    </BBB4>
</AAA>

Hopefully someone can help me.

Jos

score 4 · Answer 1 · answered Mar 05 '11 at 01:16

XPath is a query language for XML documents. As such it can only select nodes from existing XML document(s) -- it cannot modify an XML document or create a new XML document.

Use XSLT in order to transform an XML document and create a new XML document from it.

In this particular case:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="/*/*[not(CCC = 'B')]"/>
</xsl:stylesheet>

when this transformation is applied on the provided XML document:

<AAA>
    <BBB1>
        <CCC>A</CCC>
    </BBB1>
    <BBB2>
        <CCC>A</CCC>
    </BBB2>
    <BBB3>
        <CCC>B</CCC>
    </BBB3>
    <BBB4>
        <CCC>B</CCC>
    </BBB4>
</AAA>

the wanted, correct result is produced:

<AAA>
   <BBB3>
      <CCC>B</CCC>
   </BBB3>
   <BBB4>
      <CCC>B</CCC>
   </BBB4>
</AAA>

Mads Hansen · Answer 2 · 2011-03-03T12:47:48.960

In order to select all of the desired element and text nodes, use this XPATH:

//node()[.//CCC[.='B']
      or self::CCC[.='B']
      or self::text()[parent::CCC[.='B']]]

This could be achieved with a more simply/easily using XPATH with a modified identity transform XSLT:

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes" />

    <!--Empty template for the content we want to redact -->
    <xsl:template match="*[CCC[not(.='B')]]" />

    <!--By default, copy all content forward -->
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>

</xsl:stylesheet>

+1 For XSLT solution. I would use `/*/*[not(CCC = 'B')]` as pattern. Meaning: _any element child of root element and not having a `CCC` element with `'B'` as string value_. — , Mar 03 '11 at 16:53

score 0 · Answer 3 · answered Mar 03 '11 at 11:24

0

try this ,

         "//CCC[text() = 'B']"

It shall give all CCC nodes where the innertext is B.

answered Mar 03 '11 at 11:24

Furqan Hameedi

4,372
3
27
34

Thanks for your fast response! Your expression doesn't include the BBB and AAA nodes. – Jos Mar 03 '11 at 11:29
My bad, the expression got wrong then, sorry. let me try to correct and post it again later. – Furqan Hameedi Mar 03 '11 at 11:36

score 0 · Answer 4 · answered Mar 03 '11 at 12:22

0

If you want to get AAA, BBB3 and BBB4 you can use the following

//*[descendant::CCC[text()='B']]

If BBB3 and BBB4 only then

//*[CCC[text()='B']]

answered Mar 03 '11 at 12:22

alpha-mouse

4,953
24
36

Xpath: filter out childs

4 Answers4

Linked