Another bug in TDateTimePicker?

Question

I found that after I set the MaxDate of a TDateTimePicker to a non zero value it's impossible to bring it back to zero (disable it). I mean, the MaxDate reads zero but the max range is still active to the value set before. This can be noticed by dropping down the calendar and checking the last visible date.

Is this another bug, or I do not understand how to disable the MaxDate ?

procedure TForm1.Button1Click(Sender: TObject);
begin
 DateTimePicker1.MaxDate:= Date + 10;
 DateTimePicker1.MaxDate:= 0;
 Caption:= IntToStr(Trunc(Test.MaxDate));
end;

P.S: I take care of setting Time to zero first (this is another bug).

Answer 1

Victoria discovered accidentally that the Win32 Date and Time Picker control can have its range reset by employing an undocumented trick.

However, Victoria's answer doesn't work in Delphi 10.2 because the VCL wrapper's internal max and min fields aren't reset properly to 0. It doesn't do to change the MinDate and MaxDate properties to 0 -- that will not set the FMinDate and FMaxDate fields to 0 due to the implementation of the property setters.

This will make the control malfunction after that point.

A workaround is to set the fields directly (I also tweaked Victoria's logic a bit to make the code briefer):

type
  TCommonCalendarHelper = class helper for TCommonCalendar
    procedure ResetRangeFields;
  end;

  TDateTimePickerHelper = class helper for TDateTimePicker
  public
    procedure ResetRange;
  end;

{ TDateTimePickerHelper }

procedure TDateTimePickerHelper.ResetRange;
begin
  if DateTime_SetRange(Handle, 0, nil) then
    ResetRangeFields;
end;

{ TCommonCalendarHelper }

procedure TCommonCalendarHelper.ResetRangeFields;
begin
  with Self do
  begin
    FMinDate := 0;
    FMaxDate := 0;
  end;
end;

(The with construct is surprisingly necessary here, see https://stackoverflow.com/a/42936824/282848.)

To try this:

procedure TForm1.FormClick(Sender: TObject);
begin
  DateTimePicker1.MaxDate := IncDay(Now, 4);
  // DateTimePicker1.ResetRange; // uncomment to see resetting in action
end;

Of course, this code relies both on undocumented Win32 features and on VCL implementation details. The dangers are probably fairly small, though. See the comments on Victoria's post for a more thorough discussion on this topic. It might be reasonable to use this code (only) if you know the VCL version. (You could even make it not compile on future VCL versions.)

Answer 2

The following is not documented by MSDN (and was discovered by accident), but it seems to work (at least on Windows 7). You can try calling the following macro (or, send corresponding message) to remove the time range restriction of a date time picker control:

DateTime_SetRange(DateTimePicker1.Handle, 0, nil);

My lucky accidental trial started by not using either GDTR_MIN or GDTR_MAX flags when sending DTM_SETRANGE message pointing at no time range (hence I've passed 0 and nil to the macro).

If you take this as a possible workaround, what remains for VCL is resetting the internal field values, so e.g. making a small helper might become:

uses
  CommCtrl;

type
  TDateTimePickerHelper = class helper for TDateTimePicker
  public
    procedure ResetRange;
  end;

implementation

{ TDateTimePickerHelper }

procedure TDateTimePickerHelper.ResetRange;
var
  DateRange: array[0..1] of TDate;
begin
  DateRange[0] := MinDate; { ← store the current MinDate }
  DateRange[1] := MaxDate; { ← store the current MaxDate }

  MinDate := 0; { ← set the control's MinDate internal field to 0 }
  MaxDate := 0; { ← set the control's MaxDate internal field to 0 }

  if not DateTime_SetRange(Handle, 0, nil) then { ← if the macro fails, then... }
  begin
    MinDate := DateRange[0]; { ← restore the previous MinDate internal field value }
    MaxDate := DateRange[1]; { ← restore the previous MaxDate internal field value }
  end;
end;

Using it to reset the range then:

procedure TForm1.Button1Click(Sender: TObject);
begin
  DateTimePicker1.ResetRange;
end;