Using SetDelayedExpansion in batch files: handling dirs/filenames containing !

Question

I have two batch files (XP):

test.bat:

setlocal EnableDelayedExpansion

rem check for argument
if [%1]==[] goto :noarg

:arg
rem check for trailing backslash and remove it if it's there
set dirname=%1
IF !dirname:~-1!==\ SET "dirname=!dirname:~0,-1!"

rem find all log files in passed directory and call test2.bat for each one
for /f "tokens=* delims= " %%a in ('dir !dirname!\*.log /s /b') do call test2.bat "%%a"

goto :finish

:noarg
rem prompt for directory to scan
set /p dirname=Type the drive or directory, then hit enter: 

rem loop if nothing entered
if [!dirname!]==[] goto :noarg

rem check for trailing backslash and remove it if it's there
IF !dirname:~-1!==\ SET "dirname=!dirname:~0,-1!"

rem find all log files in passed directory and call test2.bat for each one
for /f "tokens=* delims= " %%a in ('dir "!dirname!"\*.log /s /b') do call test2.bat "%%a"

goto :finish

:finish

test2.bat:

echo %1

Demonstrating the problem:

-Create a directory called c:\test and another called c:\test! and put an empty test.log file in each directory.

Then run:

test c:\test

This works as expected (test2.bat echoes "c:\test\test.log")

Now run:

test c:\test!

The problem is that test2.bat echoes "c:\test\test.log" instead of the desired "c:\test!\test.log")

I realize this is because ! is reserved for EnableDelayedExpansion use. But if the solution is "use % expansion", then I'm hung because I need to use DelayedExpansion (per Handling trailing backslash & directory names with spaces in batch files )

I've poked around with:

setlocal DisableDelayedExpansion

and

endlocal

and How can I escape an exclamation mark ! in cmd scripts?

with no luck (could be PEBCAK).

Any thoughts?

jeb · Accepted Answer · 2011-03-09T11:39:11.317

2

The problems are the expansions of %1 and %%a, with delayed expansion the ! is removed.
So you should first disable the delayed expansion.
Btw. Removing the trailing slash is not neccessary (EDIT: only true, if it is not a root path)

setlocal DisableDelayedExpansion

rem check for argument
if "%~1"=="" goto :noarg

:arg
set "dirname=%~1"

rem find all log files in passed directory and call test2.bat for each one
for /f "tokens=* delims=" %%a in ('dir "%dirname%\*.log" /s /b') do (
  set "file=%%~a"
  setlocal EnableDelayedExpansion
  echo found #!file!#
  call test2.bat "!file!"
  endlocal
)

edited Mar 09 '11 at 11:39

answered Mar 08 '11 at 04:58

jeb

78,592
17
171
225

Thanks again @jeb! Just when I think I'm getting my head around something... Would you mind explaining why I don't need to remove trailing backslashes? I'm doing it to handle, for example, a user passing c:\ - which makes the for /F line error out because of: `"c:\\*.log"` – Craig H Mar 08 '11 at 17:38
@Craig H: You are right, it doesn't work with the root dir, but in any other like c:\temp\\*.log (I only test the second case) – jeb Mar 08 '11 at 19:50
thanks for the clarification - just wanted to see if I was overlooking something. Thanks once again for your help! – Craig H Mar 09 '11 at 05:52

Using SetDelayedExpansion in batch files: handling dirs/filenames containing !

1 Answers1