save income messages from not default mailbox in outlook 2016 with vba

Question

I have two mailboxes in my microsoft outlook 2016, so I want to save on local storage every income message from not predefined in settings mailbox. For this purpose I use this vba script:

Option Explicit
Private WithEvents Items As Outlook.Items

Private Sub Application_Startup()
  Dim Ns As Outlook.NameSpace
  Set Ns = Application.GetNamespace("MAPI")
  Set Items = Ns.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub Items_ItemAdd(ByVal Item As Object)
  If TypeOf Item Is Outlook.MailItem Then

  Dim sPath As String
  Dim dtDate As Date
  Dim sName As String
  Dim enviro As String

  enviro = CStr(Environ(USERPROFILE))

  sName = Item.Subject
  ReplaceCharsForFileName sName, "_"

  dtDate = Item.ReceivedTime
  sName = Format(dtDate, "yyyymmdd", vbUseSystemDayOfWeek, _
    vbUseSystem) & Format(dtDate, "-hhnnss", _
    vbUseSystemDayOfWeek, vbUseSystem) & "-" & sName & ".msg"

' use My Documents for older Windows.
    sPath = enviro & "\Documents\"
  Debug.Print sPath & sName
  Item.SaveAs sPath & sName, olMSG

  End If

End Sub

Private Sub ReplaceCharsForFileName(sName As String, _
  sChr As String _
)
  sName = Replace(sName, "/", sChr)
  sName = Replace(sName, "\", sChr)
  sName = Replace(sName, ":", sChr)
  sName = Replace(sName, "?", sChr)
  sName = Replace(sName, Chr(34), sChr)
  sName = Replace(sName, "<", sChr)
  sName = Replace(sName, ">", sChr)
  sName = Replace(sName, "|", sChr)
End Sub

It works fine for predefined mailbox. How could I switch to other mailbox?

https://stackoverflow.com/questions/31008941/how-to-get-the-mailitems-of-a-specific-folder-in-outlook — Marcucciboy2, Sep 17 '18 at 11:53

score 0 · Answer 1 · answered Sep 18 '18 at 12:17

Thank you everybody for the help! Debug mode helps a lot understad data. Code is here : C:\Program Files\Microsoft Office\root\Office16

Option Explicit
Private WithEvents Items As Outlook.Items

Private Sub Application_Startup()
  Dim Ns As Outlook.NameSpace
  Set Ns = Application.GetNamespace("MAPI")
  Set Items = Application.Session.Folders.Item("test@test.test").Folders.Item("Inbox").Items
End Sub

Private Sub Items_ItemAdd(ByVal Item As Object)
  If TypeOf Item Is Outlook.MailItem Then

  Dim sPath As String
  Dim dtDate As Date
  Dim sName As String
  Dim enviro As String

  enviro = CStr(Environ("USERPROFILE"))

  sName = Item.Subject
  ReplaceCharsForFileName sName, "_"

  dtDate = Item.ReceivedTime
  sName = Format(dtDate, "yyyymmdd", vbUseSystemDayOfWeek, _
    vbUseSystem) & Format(dtDate, "-hhnnss", _
    vbUseSystemDayOfWeek, vbUseSystem) & "-" & sName & ".msg"

' use My Documents for older Windows.
    sPath = enviro & "\Documents\"
  Debug.Print sPath & sName
  Item.SaveAs sPath & sName, olMSG

  End If

End Sub

Private Sub ReplaceCharsForFileName(sName As String, _
  sChr As String _
)
  sName = Replace(sName, "/", sChr)
  sName = Replace(sName, "\", sChr)
  sName = Replace(sName, ":", sChr)
  sName = Replace(sName, "?", sChr)
  sName = Replace(sName, Chr(34), sChr)
  sName = Replace(sName, "<", sChr)
  sName = Replace(sName, ">", sChr)
  sName = Replace(sName, "|", sChr)
End Sub

Your question starts "I have two mailboxes in my Microsoft outlook 2016". I read this to mean you want to use events to save messages from two mailboxes not just from a non-default mailbox. Was my interpretation wrong? If not, I do not understand how your answer solves your problem. BTW, `sName` cannot contain any invalid characters so there is no need to clean it. — Tony Dallimore, Sep 19 '18 at 21:48
Hi, yes actually I was struggling with choosing the one mailbox which is not set in default. Thanks for the sName tip, i've corrected it. — Sergey Vladimirovich, Sep 22 '18 at 19:17
OK. However, if you ever wanted to catch messages as they arrive in two separate mailboxes, I have code that does that. — Tony Dallimore, Sep 22 '18 at 23:03

save income messages from not default mailbox in outlook 2016 with vba

1 Answers1