Drawing Line using matrix OpenGL

Question

I'm working on this shaders that I modified but I wish to simply draw a line instead of this blur / bloom effect I understood that is the Float d that is used as a modifier but how to get this simple line instead

I based my research on this shader

Will appreciate any help

Zoltan

#ifdef GL_ES
precision mediump float;
#endif

mat4 mat  = mat4 (
        vec4 ( Scale * SizeTpDwn , 0.0 , 0.0 , 0.0 ),
        vec4 ( 0.0 , Scale * SizeLftRght , 0.0 , 0.0 ),
        vec4 ( 0.0 , 0.0 , Scale , 0.0 ),
        vec4 ( 0.0 , 0.0 , 0.0 , Scale ) );

vec2 pos;
vec4 linecol = vec4 (0.5 , 0.5 , 0.7 , 0.5);

vec4 col = vec4 ( 0.0, 0.0, 0.0, 1.0 );

void Line4 ( vec4 a, vec4 b );
void Line2 ( vec2 a, vec2 b );

void main( void ) {

    pos = gl_FragCoord.xy / RENDERSIZE.xy;
    pos -= .5;

    //Line
    Line4 ( vec4 ( LengthTX, MoveTX, .2 ,-.2), vec4 (LengthTX2, MoveTX2, .2, -.2 ) );
    //Line4 ( vec4 ( MoveRX, LengthRY, .2 ,-.2 ),vec4 ( MoveRX2,LengthRY2, .2, -.2 ) );
    //Line4 ( vec4 (MoveLX, LengthLY, .2 ,-.2 ),vec4 (MoveLX2,LengthLY2, .2, -.2 ) );
    //Line4 ( vec4 ( LengthDX,MoveDX, .2 ,-.2), vec4 (LengthDX2,MoveDX2, .2, -.2 ) );

    gl_FragColor = vec4( col.xyz, 1.0 );
}

void Line4 ( vec4 a, vec4 b )
{
    a = mat * a;
    //a.xyz /= 1.5 + a.w * 2.;
    b = mat * b;
    //b.xyz /= 1.5 + b.w * 2.;
    Line2 ( a.xy , b.xy );
}

void Line2 ( vec2 a, vec2 b )
{
    float dtc = (distance ( pos , a ) + distance ( pos , b ) - distance ( a , b )); //+ 1e-5);

    //linecol = vec4 (0.5 , 0.5 , 0.7 , 0.5);
    col += max ( 1. - pow ( dtc * 14. , 0.10 ) , -.10 );
}

Answer 1

What you have to do is to find the closest distance of the current fragment to the line. If this distance is smaller than the half line thickness, then the fragment is on the line.
To create a line with sharp edges, I recommend to use the step function, which returns 0.0, if a value is smaller than a reference value and 1.0 otherwise.
Th draw a line which is not endless, you have to check if the point on the endless line, which is closest to the current position, is in between the start and the end of the line:

void Line2 (vec2 L1, vec2 L2)
{
    vec2  P   = pos;
    vec2  O   = L1;         
    vec2  D   = normalize(L2-L1);
    float d   = dot(P-O, D);
    vec2  X   = L1 + D * d;

    float dtc;
    if (d < 0.0)
        dtc = distance(L1, P); // d < 0.0 -> X is "before" L1
    else if (d > distance(L1, L2))
        dtc = distance(L2, P); // d > distance(L1, L2) -> X is "after" L2
    else
        dtc = distance(pos, X);

    col += 1.0 - step(0.01, dtc);
}

Preview

---

Explanation:

Lets assume, that the line is defined by a Point O and a Unit vector D with gives the direction of the line. Note the length of a unit vector is 1.

Further you have the point P and you want to find the closest point X on the line (O, D) to P.

First calculate a vector V from O to P:

V = P - O;

The distance d from O to the intersection point X can be calculated by the Dot product.
Note, since D is a unit vector, the dot prduct of V and D is equal the cosine of the angle between the line (O, D) and the vector V, multiplied by the amount (length) of V:

d = dot(V, D);

The intersection point X, can be calculated by shifting the point O along the line (D) by the distance d:

X = O + D * d;    

So the formula for the intersection point is:

O ... any point on the line
D ... unit vector which points in the direction of the line
P ... the "Point"

X = O + D * dot(P-O, D); 

Note, if the line is defined by 2 points, L1 and L2 then the unit vector D can be calcualted as follows:

D = normalize(L2-L1);