2

I got 1.txt and 2.txt in my working directory. I use the following batch to list all the files.

The batch is this:

@echo off
for /f "tokens=*" %%a in ('dir *.txt /b') do (
    echo ---------------
    set file_variable=%%a
    echo file_variable=%file_variable%
    echo filename=%%a
    )

The result is below:

---------------
file_variable=2.txt   <---------------why it is not 1.txt here??
filename=1.txt
---------------
file_variable=2.txt
filename=2.txt

Thanks.

smwikipedia
  • 61,609
  • 92
  • 309
  • 482

2 Answers2

6

You need to put:

@setlocal enableextensions enabledelayedexpansion

at the top of your file and

endlocal

at the end.

Then you need to use the delayed expansion substitution characters.

@setlocal enableextensions enabledelayedexpansion
@echo off
for /f "tokens=*" %%a in ('dir *.txt /b') do (
    echo ---------------
    set file_variable=%%a
    echo file_variable=!file_variable!
    echo filename=%%a
)
endlocal

C:\Documents and Settings\Pax\My Documents> qq.cmd
---------------
file_variable=1.txt
filename=1.txt
---------------
file_variable=2.txt
filename=2.txt

What you're seeing without delayed expansion is that the entire for loop is being evaluated before running. That includes the substitution, so that %file_variable% will be replaced with the value it held before the loop started. Using delayed expansion defers the evaluation until the actual line is executed.

There are all sorts of wonderful Windows scripting tricks over at Rob van der Woude's site, containing quite a lot of different ways of doing things under Windows with various tools.

paxdiablo
  • 854,327
  • 234
  • 1,573
  • 1,953
  • @smwikipedia: The same applies to other cases where you have to use blocks of commands, enclosed in parentheses, like `if ... (...) else (...)`. – Andriy M Mar 18 '11 at 07:42
  • Is there any official documents abut the difference between !variable! and %variable% notations? – smwikipedia Mar 18 '11 at 09:01
  • @smwikipedia, check out http://www.robvanderwoude.com/ as well, it's got a lot of useful stuff. – paxdiablo Mar 18 '11 at 10:20
1

In this particular case you could get the correct output if you ECHOed file_variable like this:

CALL ECHO file_variable=%%file_variable%%

This approach is less flexible and probably less performant than the one described in @paxdiablo's answer. It's probably just a quick-and-dirty method of delaying the expansion of a variable without the need to enable the special syntax for that.

Community
  • 1
  • 1
Andriy M
  • 76,112
  • 17
  • 94
  • 154