How do you define variables for excluding multiple transitive dependencies in a build.gradle.kts

Question

I know in a groovy based build.gradle that you can define multiple excludes as described here:

dependencies {
    def withoutStuff = { 
        exclude group: 'com.android.support', module: 'support-v4' 
        exclude group: 'com.android.support', module: 'support-v13'
        exclude group: 'com.android.support', module: 'design-v13' 
    }

    // For Material Datepicker
    compile deps.datePicker, withoutStuff
}

But now how do we do this in a kotlin based build.gradle.kts file?

score 4 · Accepted Answer · answered Jan 26 '19 at 18:56

Ok I figured it out after much searching and trail and error. Above the dependencies you can define:

val withoutStuff = fun ExternalModuleDependency.() {
    exclude(group = "com.android.support", module = "support-v4")
    exclude(group = "com.android.support", module = "support-v13")
    exclude(group = "com.android.support", module = "design-v13")
}

and then inside of the dependencies block you can do:

dependencies {

    implementation(deps.datePicker, withoutStuff)
    ...
}

Hope that helps someone else and looking forward to other answers.

score 2 · Answer 2 · answered Apr 21 '20 at 19:58

Or if you want to globally set an exclusions, this might works:

// android {} 

configurations {
    implementation {
        exclude(group = "androidx.core", module = "app")
        exclude(group = "androidx.core", module = "core")
        exclude(group = "androidx.appcompat", module = "app")
        exclude(group = "com.google.firebase", module = "firebase-iid")
        exclude(group = "androidx.test", module = "monitor")
    }
}

// dependencies {}

Inspired by: https://stackoverflow.com/a/52165253/3763032

How do you define variables for excluding multiple transitive dependencies in a build.gradle.kts

2 Answers2