E-mail Excel range with VBA

Question

This code in Excel (Office 365) would add an Excel range or table to a mail body.

The crucial part is for it to work in the background w/o the mail client (Outlook) being open.

I have working code (with Outlook in the background). It can only link specific or merged cells to mail body (which essentially means text and not even a simple table).

When linking a proper range (with let's say three columns and five rows), I get

"Run-time error '13': Type mismatch"

Sub Email()

    Dim xOutApp As Object
    Dim xOutMail As Object
    Dim xMailBody As String

    Set xOutApp = CreateObject("Outlook.Application")
    Set xOutMail = xOutApp.CreateItem(0)
    xMailBody = "E-MAIL BODY TEXT" & vbNewLine & _
    Range("ARRAY")
    
    On Error Resume Next
    
    With xOutMail
        .To = "test@mail.com"
        .CC = ""
        .BCC = ""
        .Subject = "Mail subject"
        .Body = xMailBody
        .Send
    End With
    On Error GoTo 0

    Set xOutMail = Nothing
    Set xOutApp = Nothing

End Sub

I have other code which is able to grab a range (sort of) from the sheet and send it as a table. It only runs when Outlook is open and running & producing an error message otherwise.

Sub Email2()

    Dim sh As Worksheet
    Set sh = ThisWorkbook.Sheets("Sheet1")

    Dim lr As Integer

    lr = sh.Range("D" & Application.Rows.Count).End(xlUp).Row

    sh.Range("D5:F" & lr).Select

    With Selection.Parent.MailEnvelope.Item
    .to = "test@mail.com"
    .bcc = ""
    .Subject = ""
    .send
    
    End With
End Sub

Note that row counting variables must be of type `Long` because Excel has more rows than `Integer` can handle: `Dim lr As Long`. I recommend [always to use Long instead of Integer](https://stackoverflow.com/a/26409520/3219613) in VBA since there is no benefit in `Integer` at all. • You might benefit from reading [How to avoid using Select in Excel VBA](https://stackoverflow.com/questions/10714251/how-to-avoid-using-select-in-excel-vba). — Pᴇʜ, Feb 14 '19 at 07:25

score 1 · Accepted Answer · answered Feb 14 '19 at 17:58

This code is a little more complex that what you showed, but it should do the job just fine. Obviously, modify it to suit your needs.

Sub Mail_Selection_Range_Outlook_Body()
'For Tips see: http://www.rondebruin.nl/win/winmail/Outlook/tips.htm
'Don't forget to copy the function RangetoHTML in the module.
'Working in Excel 2000-2016
    Dim rng As Range
    Dim OutApp As Object
    Dim OutMail As Object

    Set rng = Nothing
    On Error Resume Next
    'Only the visible cells in the selection
    Set rng = Selection.SpecialCells(xlCellTypeVisible)
    'You can also use a fixed range if you want
    'Set rng = Sheets("YourSheet").Range("D4:D12").SpecialCells(xlCellTypeVisible)
    On Error GoTo 0

    If rng Is Nothing Then
        MsgBox "The selection is not a range or the sheet is protected" & _
               vbNewLine & "please correct and try again.", vbOKOnly
        Exit Sub
    End If

    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    On Error Resume Next
    With OutMail
        .To = "ron@debruin.nl"
        .CC = ""
        .BCC = ""
        .Subject = "This is the Subject line"
        .HTMLBody = RangetoHTML(rng)
        .Send   'or use .Display
    End With
    On Error GoTo 0

    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With

    Set OutMail = Nothing
    Set OutApp = Nothing
End Sub


Function RangetoHTML(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2016
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With

    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With

    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.readall
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")

    'Close TempWB
    TempWB.Close savechanges:=False

    'Delete the htm file we used in this function
    Kill TempFile

    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function

Thanks a lot! At the first glance worked fine, however need to go deeper with the adjustments and see how it works. Have been on Ron De Bruin's site before, but couldn't locate this one. Plenty of good stuff there though. As for the code, not entirely sure what is the Tempfile for? Could someone briefly clarify? — sql scholar, Feb 18 '19 at 14:26

E-mail Excel range with VBA

1 Answers1