Select date format

Question

I want to set a date format so that when I'm reading in my text file and converting it to XML there are no complications with the date format. I.e. if I'm reading in a text file that has USA date format or UK date format I don't want any errors occurring.

I have already written code that converts a text file into an XML file and it works fine. However, now I am trying to ensure the birthday format is correct.

If I'm honest I'm not really sure how to do this.

Also, is it possible to do this by using a combobox, so the user selects which format the date is in?

Do you create the text file? I'm a little unclear on the how or why you're using a date delimiter. After reading your text file you can `DateTime.TryParse` to evaluate whether you have a decent date or not. — Andrew Mortimer, Feb 19 '19 at 12:53
no Im reading in a text file and converting it to xml. I wanted to use date delimiter to identify if the text file being converted had for example DD/MM/YY format or MM/DD/YY — user11019667, Feb 19 '19 at 13:01
I have rephrased my question as it was a bit unclear as to what I was asking. — user11019667, Feb 19 '19 at 14:19
[What is the correct format to use for Date/Time in an XML file](https://stackoverflow.com/q/254753/1115360) - basically, use `yyyy-MM-dd`. — Andrew Morton, Feb 19 '19 at 14:29
Is there a way of using more than one. for eg. one file is dd/mm/yy another is mm/dd/yy ? — user11019667, Feb 19 '19 at 14:32
"I have already wrote code that convers a text file into an xml file" <- this is where you should be writing the dates in yyyy-MM-dd format into the XML file. — Andrew Morton, Feb 19 '19 at 15:09

score 0 · Accepted Answer · answered Feb 19 '19 at 15:17

So that you can experiment with how it can work, I suggest that you make a new Windows Forms project, just for now, and put on the form a ComboBox (name it cbDateFormat) and a Button (name it Button4) and use this code:

Public Class Form1

    Private Sub Button4_Click(sender As Object, e As EventArgs) Handles Button4.Click
        Dim str = "1/4/19" ' test data '

        If cbDateFormat.SelectedIndex = -1 Then
            MsgBox("Please select the date format.")
            Exit Sub
        End If

        Dim dateFormat = ""

        Select Case cbDateFormat.Text
            Case "DD/MM/YYYY"
                dateFormat = "d/M/yyyy"
            Case "MM/DD/YYYY"
                dateFormat = "M/d/yyyy"
            Case "DD/MM/YY"
                dateFormat = "d/M/yy"
            Case "MM/DD/YY"
                dateFormat = "M/d/yy"
            Case Else
                Throw New Exception("Date format not found.")
        End Select

        Dim d As DateTime
        If DateTime.TryParseExact(str, dateFormat, Globalization.CultureInfo.InvariantCulture, Nothing, d) Then
            ' d now holds the datetime '
            MsgBox(d.ToString("dd-MMM-yyyy"))
        End If

    End Sub

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        cbDateFormat.Items.AddRange({"DD/MM/YYYY", "MM/DD/YYYY", "DD/MM/YY", "MM/DD/YY"})

    End Sub

End Class

It uses DateTime.TryParseExact to be able to parse a string with a user-selected date format.

I used a test date of 1/4/19 deliberately as it could be the 1st of April or January 1st. A test date of 1/1/19 would not be helpful.

Then be sure to write the date in the XML in the format yyyy-MM-dd so that it is unambiguous.

Thank you so much for all your help! – user11019667 Feb 19 '19 at 16:13 — user11019667, Feb 19 '19 at 16:13

Select date format

1 Answers1