Finding and Installing Latest file in directory with specific extension

Question

I'm trying to search for the latest .msi file, and install it in the background.

I have tried following the help from this link but it did not help.

This is what I currently have:

  @echo off
setlocal

if _%1_==_payload_  goto :payload

:getadmin
    echo %~nx0: elevating self
    set vbs=%temp%\getadmin.vbs
    echo Set UAC = CreateObject^("Shell.Application"^)                >> "%vbs%"
    echo UAC.ShellExecute "%~s0", "payload %~sdp0 %*", "", "runas", 1 >> "%vbs%"
    "%temp%\getadmin.vbs"
    del "%temp%\getadmin.vbs"
goto :eof

:payload

::ENTER YOUR CODE BELOW::   

FOR /F "eol=| delims=" %%I IN ('DIR "directory" /A-D /B /S /O-D /TW 2^>nul') 
DO (
    ECHO %%~I
    SET "NewestFile=%%~I"
    GOTO FoundFile
)
ECHO No *.msi file found!
GOTO :EOF

:FoundFile
msiexec.exe /I "%NewestFile%" /Q

::END OF YOUR CODE::

echo.
echo...Script Complete....
echo.

I'm guessing the problem is with the :FoundFile and the execution part or finding the correct file based off of time.

I was thinking maybe I have to use:

forfiles /p "dir" /m *.msi /S /D +%Date%

but I'm not entirely sure.

Answer 1

A proposal for a solution using Powershell:

Get-ChildItem *msi | Sort-Object -Property LastWriteTime | Select -Last 1 | %{Start-Process $_.FullName -WindowStyle Hidden}

This will launch in the background the .msi file with the most recent write time in your current folder.

Answer 2

@echo off
setlocal

rem Search in this directory path.
set "searchdir=%~dp0directory\"

rem Escape the directory path.
set "searchdir=%searchdir:\=\\%"

rem Display the directory path.
echo %searchdir%

rem Get the latest msi file.
for /f "usebackq tokens=1,* delims= " %%A in (`
 wmic datafile where "extension='msi' and name like '%searchdir%%%'"
 get lastmodified^, name ^| sort /r ^| findstr "\\"
`) do (
    set "NewestFile=%%~B"
    echo FoundFile: %%~B
    goto :FoundFile
)

echo No *.msi file found!
exit /b

:FoundFile
rem Install the latest msi file.
msiexec.exe /i "%NewestFile%" /q
exit /b 0

The directory fullpath is setup as directory which is appended to the directory of the script. The backslashes need to be escaped for use with wmic, so variable substition to change \ to \\ is done. The directory path is then echoed for inspection.

The for loop uses wmic to get the lastmodified timestamp and name which will be the fullpath to the found msi file. sort /r will reverse the sorted order so the latest is the first. findstr "\\" will only output values with a path separator \. The variable named NewestFile stores the msi fullpath, echo outputs the msi path to stdout for inspection, and the goto :FoundFile event occurs.

msiexec.exe runs installation with the newest file.

Note:

NewestFile may contain a msi path with trailing spaces. This should do no harm to leave and I chose not to trim in case of causing harm in an unneeded trim operation.

Testing shows that wmic processes actual paths, not reparse points i.e. symlinked paths. Ensure running the script from an actual path else the name like ... query of wmic may not match anything.

You can replace the code between the ::ENTER YOUR CODE BELOW:: and ::END OF YOUR CODE:: in your posted code, without the @echo off and setlocal as you already have those lines.