having trouble using spaces in folder names

Question

When the user enters a space in the folder name, I can create and remove the folder with the following code, but the line to start or open the folder will not work.

I have tried several different things. If I use the "%input%" in the start line the quotes are used as part of the folder name so it is not recognized. If I eliminate the ""'s only the first word in the name is recognized so the folder is not found. the Md and Rd lines work perfectly with the quotes.

@echo off
echo Type in the name of your folder and hit enter.
set /P x=Please type the folder name here:
md %userprofile%\desktop\"%x%"
start %userprofile%\desktop\"%x%"
pause
rd %userprofile%\desktop\"%x%"

I expected the folder to open on the desktop and just get an error that the name is not recognized.

Move your quotes. No: %userprofile%\desktop\"%x%" Yes: "%userprofile%\desktop\%x%" — Señor CMasMas, Jun 06 '19 at 18:08
Also start uses the 1st argument in double quotes as the windows title, so insert a dummy pair `start "" "%userprofile%\desktop\%x%"` — , Jun 06 '19 at 18:30
While we are on this subject. Does anyone know if the window opened for the folder can be sized and located on the desktop? — jlmscad, Jun 06 '19 at 19:36

score 0 · Answer 1 · answered Jun 07 '19 at 05:20

Please read answer on How to stop Windows command interpreter from quitting batch file execution on an incorrect user input? and the commends in batch code below for understanding why this code is much better for your task.

It is usually necessary to enclose the entire argument string in double quotes and not just parts of it as it can be seen below.

@echo off
setlocal EnableExtensions DisableDelayedExpansion
echo Type in the name of your folder and hit ENTER.
:UserPrompt
set "Folder="
set /P "Folder=Please type the folder name here: "
rem Has the user entered a string at all?
if not defined Folder goto UserPrompt
rem Remove all double quotes of user input string.
set "Folder=%Folder:"=%"
rem Was not only one or more double quotes entered by the user?
if not defined Folder goto UserPrompt
rem Create the folder with suppressing the error message.
md "%UserProfile%\Desktop\%Folder%" 2>nul
rem Could the folder name be created at all which means the user
rem input string was valid and the folder did not exist already?
if errorlevel 1 goto UserPrompt
rem Open the just created folder on user's desktop.
start "" "%UserProfile%\Desktop\%Folder%"
pause
rd "%UserProfile%\Desktop\%Folder%"
endlocal

Instead of the command line

start "" "%UserProfile%\Desktop\%Folder%"

it is also possible to use

%SystemRoot%\explorer.exe "%UserProfile%\Desktop\%Folder%"

or use

%SystemRoot%\explorer.exe /e,"%UserProfile%\Desktop\%Folder%"

explorer.exe is an exception of general rule to enclose an entire argument string in double quotes. "/e,%UserProfile%\Desktop\%Folder%" would not work because in this case the argument string would be interpreted as folder with an invalid relative path to root directory of current drive instead of option /e with folder to open.

But Windows Explorer does not offer options to define window position and size. Whatever the user used the last time and is therefore most likely preferred by the user is used again by Windows Explorer on opening an Explorer window for a folder.

It would be of course possible with additional code to send to the just opened Explorer window being top-level foreground window a message for changing window position and size. See for example:

How can a batch file run a program and set the position and size of the window?

For understanding the used commands and how they work, open a command prompt window, execute there the following commands, and read entirely all help pages displayed for each command very carefully.

echo /?
endlocal /?
if /?
md /?
pause /?
rd /?
rem /?
set /?
setlocal /?
start /?

having trouble using spaces in folder names

1 Answers1