Default inherited button text

Question

This is the code for my inherited Button control:

Public Class ButtonRefreshSmall
Inherits Button

Public Sub New()
    MyBase.New
    ' This call is required by the designer.
    InitializeComponent()

    ' Add any initialization after the InitializeComponent() call.
    Me.SuspendLayout()
    Me.Text = ""
    MyBase.Text = ""
    Me.ResumeLayout()
End Sub
End Class

However, when I rebuild and drag this button to a form the text is always ButtonRefreshSmall1. I've tried variants without the Inherits declaration (since it's already in the .Designer.vb file, I've tried setting Text in Designer view/class of the control, to no avail.
Sometimes it won't even show in the Toolbox after rebuild.

All I want is for text of the button to be empty (since it has an Image defined in the designer).

This is what I have in the Designer file:

 <System.Diagnostics.DebuggerStepThrough()> _
Private Sub InitializeComponent()
    Me.SuspendLayout()
    '
    'ButtonRefreshSmall
    '
    Me.BackColor = System.Drawing.Color.Transparent
    Me.FlatAppearance.BorderSize = 0
    Me.FlatStyle = System.Windows.Forms.FlatStyle.Flat
    Me.Image = Global.TraxCashFlow.My.Resources.Resources.Refresh_grey_16x
    Me.Size = New System.Drawing.Size(23, 23)
    Me.TextImageRelation = System.Windows.Forms.TextImageRelation.ImageBeforeText
    Me.UseVisualStyleBackColor = False
    'MyBase.Text = ""
    Me.ResumeLayout(False)

End Sub

And all other properties are set like I set them. I tried to trick it with TextImageRelation but the "B" is always visible anyway.

Update: Jimi gave me the idea in a comment below his answer, so I added a new Property MyText and this works just like I want (not sure why I need to call Refresh though, if I don't then it's updated after losing focus):

Imports System.ComponentModel

Public Class ButtonRefreshSmall

Public Property MyText As String
    Get
        Return Me.Text
    End Get
    Set(value As String)
        Me.Text = value
        Me.Refresh()
    End Set
End Property

Public Sub New()
    'MyBase.New
    ' This call is required by the designer.
    InitializeComponent()

    ' Add any initialization after the InitializeComponent() call.
    'Me.Text = ""
End Sub

<Browsable(False)>
<DesignerSerializationVisibility(DesignerSerializationVisibility.Hidden)>
Public Overrides Property Text As String
End Class

Update #2, see @TnTinMn's answer.

It might just be simpler to remove the text yourself after dragging the button. — the_lotus, Jun 17 '19 at 13:39
[How to prevent winforms designer from setting Text property to instance name](https://stackoverflow.com/a/35791638/3110834) — Reza Aghaei, Jun 19 '19 at 20:58

score 3 · Accepted Answer · answered Jun 17 '19 at 17:15

To accomplish the goal you stated in a comment to the accepted answer,

... I'd want Text property to remain but just to be empty ...

You can apply a ToolboxItemAttribute to your custom button class.

<System.ComponentModel.ToolboxItemAttribute(GetType(ToolBoxItemNoDefaultText))>
Public Class ButtonRefreshSmall

This will tell the design environment to use the class ToolBoxItemNoDefaultText to control the creation of ButtonRefreshSmall for placement on the design surface. ToolBoxItemNoDefaultText will derive from the ToolboxItem Class.

Imports System.Drawing.Design
Imports System.ComponentModel
Imports System.Runtime.Serialization
Imports System.Windows.Forms

<Serializable()> ' ToolBoxItems must be Serializable 
Public Class ToolBoxItemNoDefaultText : Inherits ToolboxItem
  Public Sub New(ByVal toolType As Type)
    ' this constructor is needed to allow the type decorated with 
    ' <System.ComponentModel.ToolboxItemAttribute(GetType(ToolBoxItemNoDefaultText))>
    ' to be added to the ToolBox
    MyBase.New(toolType)
  End Sub

  Sub New(ByVal info As SerializationInfo, ByVal context As StreamingContext)
    ' this constructor is needed to support the design-time deserialization of this
    ' class by the design environment.
    Deserialize(info, context)
  End Sub

  Protected Overrides Sub OnComponentsCreated(args As ToolboxComponentsCreatedEventArgs)
    ' this will run after all initialization code has run including that set
    ' by the component's designer, thus you can override designer set values.
    For Each comp As IComponent In args.Components
      Dim ctrl As Control = TryCast(comp, Control)
      If ctrl IsNot Nothing Then ctrl.Text = String.Empty
    Next
    MyBase.OnComponentsCreated(args)
  End Sub
End Class

This solution is somewhat after the fact as it allows the default designer code to run and then modifies the created instance. You may notice that the Text set by the designer is momentarily displayed before it is set to String.Empty.

The proper way to deal with this would be to create a custom designer and not set the Text property during initialization. However, proper implementation of a custom designer can become involved if the user experience is to be as close as possible that implemented by MS.

@okkko, you may find it simpler for your needs, but if you ever need this behavior again. instead of one line of additional code to add the ToolboxItemAttribute, you need to replicate the the whole code pattern that you devised. — TnTinMn, Jun 18 '19 at 12:48
You're right! Tbh, I haven't really look at your code before but now that I've tried it, it works perfectly, no momentary Tex noticed. Upvoted and accepted as answer, sorry Jimi! I guess they are many solutions to simple problems. — okkko, Jun 18 '19 at 13:10
Here is the designer approach: [How to prevent winforms designer from setting Text property to instance name](https://stackoverflow.com/a/35791638/3110834). — Reza Aghaei, Jun 19 '19 at 21:02

score 2 · Answer 2 · answered Jun 17 '19 at 13:38

That's just what the WinForms designer does. When you add a control to the form, it sets the Name and Text properties based on the type of the control and the number of them that are on the form with default names. It's done after the constructor is executed so your constructor code can't help. You'd have to put code in the property itself to ignore a set in the designer:

Public Overrides Property Text As String
    Get
        Return MyBase.Text
    End Get
    Set
        If Not DesignMode Then
            MyBase.Text = Value
        End If
    End Set
End Property

Note that that means that you won't be able to set it yourself either though, unless at run-time.

Jimi · Answer 3 · 2019-06-17T13:51:06.907

2

Simple way: override or shadow the Text property, adding a DesignerSerializationVisibility Attribute, setting it to DesignerSerializationVisibility.Hidden and the Browsable attribute to False.

The Designer won't generate any code for the Text property (so the Control won't show a text), the property is not visible in the PropertyGrid but it's still there and can be set in code.

<Browsable(False)>
<DesignerSerializationVisibility(DesignerSerializationVisibility.Hidden)>
Public Overrides Property Text As String
' or
' Public Shadows Property Text As String

Another way is to remove the property, using a custom designer.
See here how it can be implemented:
Is it possible to change the value of a property attribute at design time?

edited Jun 17 '19 at 13:51

answered Jun 17 '19 at 13:43

Jimi

29,621
8
43
61

Both answers are good and a compromise at the same time. I'd want Text property to remain but just to be empty. For this particular case I accept this is an answer. – okkko Jun 17 '19 at 13:47
1

As I said in my answer, you wouldn't be able to set the `Text` yourself in the designer anyway, so hiding it in the designer is a better option. You can still set it in code because, as this answer says, the property still exists. – jmcilhinney Jun 17 '19 at 14:01

Default inherited button text

3 Answers3