calculate mean on even and odd lines independently in bash

Question

I have a file with 2 columns and many rows. I would like to calculate the mean for each column for odd and even lines independantly, so that in the end I would have a file with 4 values: 2 columns with odd and even mean. My file looks like this:

2 4 4 4 6 8 3 5 6 9 2 1

In the end I would like to obtain a file with the mean of 2,6,6 and 4,3,2 in the first column and the mean of 4,8,9 and 4,5,1 in the second column, that is:

4.66 7 3 3.33

If anyone could give me some advice I'd really appreaciate it, for the moment I'm only able to calculate the mean for all rows (not even and odd). Thank you very much in advance!

Try filtering even/odd lines first. See https://stackoverflow.com/questions/21309020/remove-odd-or-even-lines-from-a-text-file — Oleksii Filonenko, Jun 17 '19 at 17:00

Juan Diego Godoy Robles · Accepted Answer · 2019-06-17T17:31:36.783

2

This is an awk hardcoded example but you can get the point :

awk 'NR%2{e1+=$1;e2+=$2;c++;next}
     {o1+=$1;o2+=$2;d++}
     END{print e1/c"\t"e2/c"\n"o1/d"\t"o2/d}' your_file
4.66667 7
3       3.33333

edited Jun 17 '19 at 17:31

answered Jun 17 '19 at 17:20

Juan Diego Godoy Robles

14,447
2
38
52

score 1 · Answer 2 · answered Jun 17 '19 at 19:48

A more generalized version of Juan Diego Godoy's answer. Relies on GNU awk

gawk '
    {
        parity = NR % 2 == 1 ? "odd" : "even"
        for (i=1; i<=NF; i++) {
            sum[parity][i] += $i
            count[parity][i] += 1
        }
    }
    function result(parity) {
        for (i=1; i<=NF; i++)
            printf "%g\t", sum[parity][i] / count[parity][i]
        print ""
    }
    END { result("odd"); result("even") }
'

score 0 · Answer 3 · answered Jun 18 '19 at 00:31

This answer uses Bash and bc. It assumes that the input file consists of only integers and that there is an even number of lines.

#!/bin/bash
while read -r oddcol1 oddcol2; read -r evencol1 evencol2
do
    (( oddcol1sum += oddcol1 ))
    (( oddcol2sum += oddcol2 ))
    (( evencol1sum += evencol1 ))
    (( evencol2sum += evencol2 ))
    (( count++ ))
done < inputfile

cat <<EOF | bc -l
    scale=2
    print "Odd Column 1 Mean: "; $oddcol1sum / $count
    print "Odd Column 2 Mean: "; $oddcol2sum / $count
    print "Even Column 1 Mean: "; $evencol1sum / $count
    print "Even Column 2 Mean: "; $evencol2sum / $count
EOF

It could be modified to use arrays to make it more flexible.

calculate mean on even and odd lines independently in bash

3 Answers3