How to print line 6 through 10 after last match?

Question

After matching the last "Constrained" I want to print the 6th to 10th line:

This is what I've tried:

awk '/Constrained/ { print ; for(n=6; n<10; n++) { getline ; print } }' filename

But doesn't work. I was thinking of using tail -5 to get only the last 5 lines. (LInes 6 to 10 of only the last match)

You can test it with this:

************************** Constrained Symmetrised Forces **************************
 *                                                                                  *
 *                           Cartesian components (eV/A)                            *
 * -------------------------------------------------------------------------------- *
 *                         x                    y                    z              *
 *                                                                                  *
 * O               1     -0.03440             -0.03440              0.00000         *
 * O               2      0.03440              0.03440             -0.00000         *
 * O               3     -0.03440              0.03440             -0.00000         *
 * O               4      0.03440             -0.03440              0.00000         *
 * Ti              1      0.00000              0.00000              0.00000         *

I should get the lines that start with O and end with Ti. But throughout the file there are several "constrained"

Answer 1

All you need is:

grep -A10 Constrained file | tail -n 5

Answer 2

One option: reverse the file, find the first match plus 10 lines, re-reverse, take the last 5 lines:

tac filename | grep -B10 Constrained -m 1 | tac | tail -n 5

Answer 3

tac file | grep "Constrained" -m1 -B10 | tac | tail -n5

tac reverses the file, so you can find the last match easily using grep -m1. Second, you want to process the 10 lines (5 to skip and 5 to print) before ('before', because output is reversed). The second tac reverses the output again so you get the original line order and tail -n5 hides the lines between Constrained and the 6. line to print after the match.

Of course, you can do that with a simple grep, but this will read and process the whole file and can be significantly slower. tac starts reading from the end of file.

grep -A10 "Constrained" file | tail -n5

With awk (also reading the whole file):

awk '/Constrained/{f=NR;b=""};NR>=f+6 && NR<=f+10{b=b ORS $0}END{print b}' file

Searches for Constrained, sets the initial line number (f to current line) and deletes the buffer (for previous results). Then collects lines into b as long as the lines numbers match the region.

Answer 4

The easiest way I can think of to do that is to read the file twice. The first pass finds the last line number of the match, the second pass prints 6-10 after it.

awk 'FNR==NR && /Constrained/ { line=NR }
     FNR!=NR && FNR >= line+6 && FNR <= line+10' filename filename

Answer 5

Reading the file a single time, but keeping track of a buffer:

awk '(c-->0){b[10-c]=$0}
     /Constrained/{c=10}
     END{for(i=6;i<=10;++i) print b[i] }' file

How does this work?

The array b is buffer which always will contain the 10 lines following after a match of the pattern /Constrained/. A counter c will be used to count down to zero. Every time a match of the pattern is found, it is reset to the maximum value of 10. The program works like this:

1. Read a line (default awk action)
2. Check if the counter c is bigger than zero and decrease it by 1 (See What is the "-->" operator in C++?). If this condition is met, store the line in the buffer b. Since we start counting from 9 (10-1), store it at position 10 − i. This way the lines after the match are indexed as 1,2,3,...,10.
3. If the pattern /Constrained/ is matched, reset the counter c to 10.
4. Go back to 1 unless you are at the end of the file.
5. If you processed the file, the buffer b now contains the last 10 lines after the match. Just print line 6 till 10.

A couple of cleanups:

It is not necessarily said that after matching the pattern, you have 10 lines, so you have to make sure the previous buffer is fully erased.

$ awk '(c-->0){b[10-c]=$0}
       /Constrained/{c=10; delete b}
       END{for(i=6;i<=10;++i) if (i in b) print b[i] }' file

Parametrised version:

A parameterised version would allow for large ranges. But imagine you want the 10000 till 10001th line after the match. So the buffer would be really big, for just two lines. So we can correct this as:

$ awk '(c-->min) && (c<=max-min){b[max-c]=$0}
       ($0~ere){c=max; delete b}
       END{for(i=min;i<=max;++i) if (i in b) print b[i] }' \
       min=6 max=10 ere="Constrained" file

Be advised that min has to be bigger than 0.

Proof of principle:

$ awk '(c-->0) && (c<=max-min){b[max-c]=$0}
       ($0~ere){ c=max; delete b}
       END{for(i=min;i<=max;i++) if(i in b) print b[i] }' \
       min=6 max=10 ere="20" <( seq 1 50 && seq 101 150 )
126
127
128
129
130

Answer 6

I would suggest to try this one. -A refers to 10 lines after the match of the word. -m refers on when to stop reading the file. we dont want to read the whole file. do you?

grep -A10 Constrained file | tail -5