VB.NET DLL does not trigger methods in VB6

Question

I have created a DLL in VB.NET and loaded in VB6.
All variables and methods are working very well.

In the DLL, I have a RaiseEvent.
The RaiseEvent from .NET DLL cannot trigger the methods in VB6.

Option Explicit On
Option Strict On

Imports System.Windows.Forms
Imports System.Net.Sockets
Imports System.IO
Imports System.Text
Imports System.Net
Imports System.ComponentModel
Imports System.Threading
Imports System.Runtime.InteropServices

<ComClass(TestDLL.ClassId, TestDLL.InterfaceId, TestDLL.EventsId)>
Public Class TestDLL
    Public Const ClassId As String = "6E9AB173-14BD-4DE4-9AE0-A9638FCE40B3"
    Public Const InterfaceId As String = "E659D166-F952-489F-899F-0104553B44E4"
    Public Const EventsId As String = "1C38AB4A-84B9-4CC2-A090-0C272177ECED"

    Public Event Disconnected()
    Public Event FirstConnect()
    Public Event Waagerecht()

    Private Sub Received(ByVal msg As String) Handles Me.Receive

     RaiseEvent Waagerecht()

   End Sub

This DLL is working in C#, VB.NET and in Labview amazing. Only not in VB6

RaiseEvent Part in VB.NET DLL

And the code in VB6:

Option Explicit

Private WithEvents MyNetClass As TestDll

Private Sub Form_Load()
    Set MyNetClass = New TestDll
End Sub

Private Sub Form_Terminate()
    Set MyNetClass = Nothing
End Sub

And the methods for triggering:

Private Sub MyNetClass_Waagerecht()
    MsgBox "Ich werde angezeigt, sobald dll mir was sagt"
End Sub

Answer 1

Disclaimer: The following is based on issues I have experienced with Office VBA and events being raised on a secondary thread. Due to their similar underlying architecture, I am assuming that VB6 will have similar issues. I do not have VB6 so I can not verify the this.

With that stated, it appears that your code is using NetworkStream.BeginRead and the callback events will arrive on a secondary thread, you may be experiencing problems due to the event being raised on the secondary thread.

To provide thread synchronization to the COM class, I utilize a System.Windows.Forms.Control. The control is created in the class constructor to capture the thread it is created on. Events are defined as Custom Event so that the RaiseEvent method can be defined to use the InvokeRequired property of the synchronizing control. I have only shown the pattern for your Waagerecht event; if this works, you will need to implement the same pattern for your other Public events.

Private synch As ISynchronizeInvoke

Public Sub New()
    Dim marshalingControl As New System.Windows.Forms.Control
    marshalingControl.CreateControl() ' the handle must be created

    synch = marshalingControl
End Sub

Private _Waagerecht As Action
Public Custom Event Waagerecht As Action
    AddHandler(value As Action)
        _Waagerecht = CType([Delegate].Combine(_Waagerecht, value), Action)
    End AddHandler

    RemoveHandler(value As Action)
        _Waagerecht = CType([Delegate].Remove(_Waagerecht, value), Action)
    End RemoveHandler

    RaiseEvent()
        If _Waagerecht IsNot Nothing Then
            If synch.InvokeRequired Then
                synch.Invoke(_Waagerecht, {})
            Else
                _Waagerecht.Invoke()
            End If
        End If
    End RaiseEvent
End Event

---

Edit: Recommendations For Debugging

A first step add the following to the VB.Net TestDLL class.

Public Sub TestWaagerecht()
    RaiseEvent Waagerecht()
End Sub

Then in your VB6 code, add a button to your form and in its Click handler, call MyNetClass.TestWaagerecht. This will verify whether or not the VB6 code is receiving the event.

Hopefully this will work with VB6. Try setting up VB.Net project for debugging. If the project does not have an app.config, add one (Project Menu->Add New Item->"Application Configuration File"). I don't know why, but without the app.Config file, break-points are not hit.

Next go to Project Properties->Debug Tab and set the "Start External Program" to point to the VB6 program. Add a break-point in the Sub TestWaagerecht that I asked you to add above.

When you click on the "Start" button in VS to start debugging, it should launch VB6. Now load your VB6 project and start debugging it. Click on the button that calls TestWaagerecht. Hopefully, the VS break-point will be hit. If it is hit, then all is well and you can start debugging your code to hopefully find the issue.