19

I'm doing a bit of self study on functional languages (currently using Haskell). I came across a Haskell based assignment which requires defining map and filter in terms of foldr. For the life of me I'm not fully understanding how to go about this.

For example when I define a map function like:

map'            :: (a -> b) -> [a] -> [b]
map' f []       = []
map' f (x:xs)   = foldr (\x xs -> (f x):xs) [] xs

I don't know why the first element of the list is always ignored. Meaning that:

map' (*2) [1,2,3,4]

results in [4,6,8] instead of [2,4,6,8]

Similarly, my filter' function:

filter'             :: (a -> Bool) -> [a] -> [a]
filter' p []        = []
filter' p (x:xs)    = foldr (\x xs -> if p x then x:xs else xs ) [] xs

when run as:

filter' even [2,3,4,5,6]

results in [4,6] instead of [2,4,6]

Why would this be the case? And how SHOULD I have defined these functions to get the expected results? I'm assuming something is wrong with my lambda expressions...

klactose
  • 1,190
  • 2
  • 9
  • 26

9 Answers9

52

I wish I could just comment, but alas, I don't have enough karma.

The other answers are all good ones, but I think the biggest confusion seems to be stemming from your use of x and xs.

If you rewrote it as

map'            :: (a -> b) -> [a] -> [b]
map' f []       = []
map' f (x:xs)   = foldr (\y ys -> (f y):ys) [] xs

you would clearly see that x is not even mentioned on the right-hand side, so there's no way that it could be in the solution.

Cheers

tredontho
  • 1,273
  • 10
  • 14
  • 5
    Precicely. Thus it should become clear that `map' f xs` instead of `map' f (x:xs)` should solve the problem. – Dan Burton Apr 20 '11 at 13:12
  • 4
    Btw GHC can be an aid in seeing it when option `-Wall` is used: `Warning: Defined but not used: 'x'` (or, for the original code: `This binding for 'x' shadows the existing binding`) – Ed'ka Apr 20 '11 at 14:46
  • Now, you should have enough karma and a nice badge on top ;) – fuz Apr 20 '11 at 17:20
  • 2
    Thanks, you were right... my usage of x & xs was confusing me! This really made it much clearer. – klactose Apr 21 '11 at 02:57
  • 2
    please, replace `map' f (x:xs)` by `map' f xs` as suggested by Dan Burton – palik Oct 21 '19 at 04:01
  • no, there's no suggestion in Dan Burton's comment to make such an edit to this answer. – Will Ness Apr 22 '21 at 15:53
21

For your first question, foldr already has a case for the empty list, so you need not and should not provide a case for it in your own map.

map' f = foldr (\x xs -> f x : xs) []

The same holds for filter'

filter' p = foldr (\x xs -> if p x then x : xs else xs) []

Nothing is wrong with your lambda expressions, but there is something wrong with your definitions of filter' and map'. In the cons case (x:xs) you eat the head (x) away and then pass the tail to foldr. The foldr function can never see the first element you already ate. :)

Alse note that:

filter' p = foldr (\x xs -> if p x then x : xs else xs) []

is equivalent (η-equivalent) to:

filter' p xs = foldr (\x xs -> if p x then x : xs else xs) [] xs
Alessandro Vermeulen
  • 1,321
  • 1
  • 9
  • 28
6

I would define map using foldr and function composition as follows:

map :: (a -> b) -> [a] -> [b]
map f = foldr ((:).f) []

And for the case of filter: 

filter :: (a -> Bool) -> [a] -> [a]
filter p = foldr (\x xs -> if p x then x:xs else xs) []

Note that it is not necessary to pass the list itself when defining functions over lists using foldr or foldl. The problem with your solution is that you drop the head of the list and then apply the map over the list and this is why the head of the list is missing when the result is shown.

Vombat
  • 1,156
  • 1
  • 15
  • 27
  • This answers a question in the title, very neatly, but it would be even more helpful if you explained, and yet more helpful if you answered the other questions in the question. – AndrewC Sep 27 '12 at 07:50
  • Following @coffeMug suggestion, parameters can be reduced inside lambda too: `filter p = foldr (\x -> if p x then (x:) else id) []` – paluh Dec 12 '13 at 01:47
  • 1
    is there anyone who really finds `(:).f` easier to read than `\x xs -> f x : xs` ? – Justin L. Aug 23 '15 at 09:54
  • 2
    @paluh, while this is all rather silly, you can import `Data.Bool` and use `filter p = foldr (bool id . (:) <*> p) []`. Going to extremes, ``filter = (`foldr` []) . (bool id . (:) <*>)``. – dfeuer Jan 13 '16 at 20:09
  • @Justin L a mathematician. ;-) – Vombat May 30 '16 at 21:29
  • @coffeMug I'll dare you to find a mathematician who does :P – Justin L. May 31 '16 at 00:29
3

I am new to Haskell (in fact I've found this page asking the same question) but this is my understanding of lists and foldr so far:

  • lists are elements that are linked to the next element with the cons (:) operator. they terminate with the empty list []. (think of it as a binary operator just like addition (+) 1+2+3+4 = 10, 1:2:3:4:[] = [1,2,3,4]
  • foldr function takes a function that takes two parameters. this will replace the cons operator, which will define how each item is linked to the next.
  • it also takes the terminal value for the operation, which can be tought as the initial value that will be assigned to the empty list. for cons it is empty list []. if you link an empty list to any list the result is the list itself. so for a sumfunction it is 0. for a multiply function it is 1, etc.
  • and it takes the list itself

So my solution is as follows:

filter' p = foldr (\x n -> if p x then x : n else n) []

the lambda expression is our link function, which will be used instead of the cons (:) operator. Empty list is our default value for an empty list. If predicate is satisfied we link to the next item using (:) as normal, else we simply don't link at all.

map' f = foldr (\x n -> f x : n) []

here we link f x to the next item instead of just x, which would simply duplicate the list.

Also, note that you don't need to use pattern matching, since we already tell foldr what to do in case of an empty list.

I know this question is really old but I just wanted to answer it anyway. I hope it is not against the rules.

kureta
  • 478
  • 4
  • 15
3

A different way to think about it - foldr exists because the following recursive pattern is used often:

-- Example 1: Sum up numbers
summa :: Num a => [a] -> a
summa []     = 0
summa (x:xs) = x + suma xs

Taking the product of numbers or even reversing a list looks structurally very similar to the previous recursive function:

-- Example 2: Reverse numbers
reverso :: [a] -> [a]
reverso []      = []
reverso (x:xs)  = x `op` reverso xs
  where
    op = (\curr acc -> acc ++ [curr])

The structure in the above examples only differs in the initial value (0 for summa and [] for reverso) along with the operator between the first value and the recursive call (+ for summa and (\q qs -> qs ++ [q]) for reverso). So the function structure for the above examples can be generally seen as

-- Generic function structure
foo :: (a -> [a] -> [a]) -> [a] -> [a] -> [a]
foo op init_val []      = init_val
foo op init_val (x:xs)  = x `op` foo op init_val xs

To see that this "generic" foo works, we could now rewrite reverso by using foo and passing it the operator, initial value, and the list itself:

-- Test: reverso using foo
foo (\curr acc -> acc ++ [curr]) [] [1,2,3,4]

Let's give foo a more generic type signature so that it works for other problems as well:

foo :: (a -> b -> b) -> b -> [a] -> b

Now, getting back to your question - we could write filter like so:

-- Example 3: filter
filtero :: (a -> Bool) -> [a] -> [a]
filtero p []     = []
filtero p (x:xs) = x `filterLogic` (filtero p xs)
  where
     filterLogic = (\curr acc -> if (p curr) then curr:acc else acc)

This again has a very similar structure to summa and reverso. Hence, we should be able to use foo to rewrite it. Let's say we want to filter the even numbers from the list [1,2,3,4]. Then again we pass foo the operator (in this case filterLogic), initial value, and the list itself. filterLogic in this example takes a p function, called a predicate, which we'll have to define for the call:

let p = even in foo (\curr acc -> if (p curr) then curr:acc else acc) [] [1,2,3,4]

foo in Haskell is called foldr. So, we've rewritten filter using foldr.

let p = even in foldr (\curr acc -> if (p curr) then curr:acc else acc) [] [1,2,3,4]

So, filter can be written with foldr as we've seen:

-- Solution 1: filter using foldr
filtero' :: (a -> Bool) -> [a] -> [a]
filtero' p xs = foldr (\curr acc -> if (p curr) then curr:acc else acc) [] xs

As for map, we could also write it as

-- Example 4: map
mapo :: (a -> b) -> [a] -> [b]
mapo f []   = []
mapo f (x:xs) = x `op` (mapo f xs)
  where
    op = (\curr acc -> (f curr) : acc)

which therefore can be rewritten using foldr. For example, to multiply every number in a list by two:

let f = (* 2) in foldr (\curr acc -> (f curr) : acc) [] [1,2,3,4]

So, map can be written with foldr as we've seen:

-- Solution 2: map using foldr
mapo' :: (a -> b) -> [a] -> [b]
mapo' f xs = foldr (\curr acc -> (f curr) : acc) [] xs
Daniel
  • 3,758
  • 3
  • 22
  • 43
3

In your definitions, you are doing pattern matching for x:xs, which means, when your argument is [1,2,3,4], x is bound to 1 and xs is bound to the rest of the list: [2,3,4].

What you should not do is simply throw away x: part. Then your foldr will be working on whole list.

So your definitions should look as follows:

map'            :: (a -> b) -> [a] -> [b]
map' f []       = []
map' f xs       = foldr (\x xs -> (f x):xs) [] xs

and

filter'             :: (a -> Bool) -> [a] -> [a]
filter' p []        = []
filter' p xs        = foldr (\x xs -> if p x then x:xs else xs ) [] xs
dave4420
  • 46,404
  • 6
  • 118
  • 152
x13n
  • 4,103
  • 2
  • 21
  • 28
1

Your solution almost works .) The problem is that you've got two differend bindings for x in both your functions (Inside the patternmatching and inside your lambda expression), therefore you loose track of the first Element.

map'            :: (a -> b) -> [a] -> [b]
map' f []       = []
map' f (x:xs)   = foldr (\x xs -> (f x):xs) [] (x:xs)

filter'             :: (a -> Bool) -> [a] -> [a]
filter' p []        = []
filter' p (x:xs)    = foldr (\x xs -> if p x then x:xs else xs ) [] (x:xs)

This should to the trick :). Also: you can write your functions pointfree style easily.

Jakob Runge
  • 2,287
  • 7
  • 36
  • 47
0
*Main> :{
*Main| map' :: (a -> b) -> [a] -> [b]
*Main| map' = \f -> \ys -> (foldr (\x -> \acc -> f x:acc) [] ys)
*Main| :}
*Main> map' (^2) [1..10]
[1,4,9,16,25,36,49,64,81,100]

*Main> :{
*Main| filter' :: (a -> Bool) -> [a] -> [a]
*Main| filter' = \p -> \ys -> (foldr (\x -> \acc -> if p x then x:acc else acc) [] ys)
*Main| :}
*Main> filter' (>10) [1..100]

In the above snippets acc refers to accumulator and x refers to the last element.

Abhijit Gupta
  • 21
  • 3
0

Everything is correct in your lambda expressions. The problem is you are missing the first element in the list. If you try,

map' f (x:xs) = foldr (\x xs -> f x:xs) [] (x:xs)

then you shouldn't miss the first element anymore. The same logic applies to filter.

filter' p (x:xs) = foldr(\ y xs -> if p y then y:xs else xs) [] (x:xs)

Srinath
  • 66
  • 4