Count for ALL instances of a field (even in other segments)

Question

The TOTAL field needs to count ALL ITEM fields for ALL segments. Not just the ITEM fields inside the same segment

I've already tried changing the context by adding another ./ in the beginning of the xpath.

<xsl:template match="nm:EPCISDocument">
  <MESSAGE>
      <PALLET>
        <xsl:for-each select="//*[local-name()='ObjectEvent'][substring(epcList/epc,1,16) = 'urn:epc:id:sgtin']">
          <MATERIAL>
            <BOX>
              <TOTAL>
                <xsl:value-of select="count(./epcList/epc[substring(.,1,16) = 'urn:epc:id:sgtin'])"/>
              </TOTAL>
              <xsl:for-each select="./epcList/epc[substring(.,1,16) = 'urn:epc:id:sgtin']">
                <SERIES>
                  <ITEM>
                    <xsl:value-of select="substring-after(substring-after(.,'.'),'.')"/>
                  </ITEM>
                </SERIES>
            </BOX>
          </MATERIAL>
      </PALLET>
  </MESSAGE>

This is a sample input file:

<?xml version="1.0" encoding="UTF-8"?>
<n0:EPCISDocument xmlns:n0="urn:epcglobal:epcis:xsd:1" xmlns:soap-env="http://schemas.xmlsoap.org/soap/envelope/" schemaVersion="1.1">
  <ObjectEvent>
    <epcList>
      <epc>urn:epc:id:sgtin:999999999.0000.0000000001</epc>
      <epc>urn:epc:id:sgtin:999999999.0000.0000000002</epc>
    </epcList>
  </ObjectEvent>
  <ObjectEvent>
    <epcList>
      <epc>urn:epc:id:sgtin:999999999.0000.0000000003</epc>
      <epc>urn:epc:id:sgtin:999999999.0000.0000000004</epc>
      <epc>urn:epc:id:sgtin:999999999.0000.0000000005</epc>
    </epcList>
  </ObjectEvent>
</n0:EPCISDocument>

The expected should be:

<?xml version="1.0" encoding="UTF-8"?>
<MESSAGE>
  <PALLET>
    <MATERIAL>
      <BOX>
        <TOTAL>5</TOTAL>
        <SERIES>
          <ITEM>0000000001</ITEM>
        </SERIES>
        <SERIES>
          <ITEM>0000000002</ITEM>
        </SERIES>
      </BOX>
    </MATERIAL>
    <MATERIAL>
      <BOX>
        <TOTAL>5</TOTAL>
        <SERIES>
          <ITEM>0000000003</ITEM>
        </SERIES>
        <SERIES>
          <ITEM>0000000004</ITEM>
        </SERIES>
                <SERIES>
          <ITEM>0000000005</ITEM>
        </SERIES>
      </BOX>
    </MATERIAL>
  </PALLET>
</MESSAGE>

But right now based on the code, I'm getting this:

<?xml version="1.0" encoding="UTF-8"?>
<MESSAGE>
  <PALLET>
    <MATERIAL>
      <BOX>
        <TOTAL>2</TOTAL>
        <SERIES>
          <ITEM>0000000001</ITEM>
        </SERIES>
        <SERIES>
          <ITEM>0000000002</ITEM>
        </SERIES>
      </BOX>
    </MATERIAL>
    <MATERIAL>
      <BOX>
        <TOTAL>3</TOTAL>
        <SERIES>
          <ITEM>0000000003</ITEM>
        </SERIES>
        <SERIES>
          <ITEM>0000000004</ITEM>
        </SERIES>
                <SERIES>
          <ITEM>0000000005</ITEM>
        </SERIES>
      </BOX>
    </MATERIAL>
  </PALLET>
</MESSAGE>

`//*[local-name()='ObjectEvent']` You should never have to use such hack. If the source element is in a namespace, use a prefix - see: https://stackoverflow.com/questions/34758492/xslt-transform-doesnt-work-until-i-remove-root-node/34762628#34762628 — michael.hor257k, Aug 06 '19 at 05:16

score 1 · Accepted Answer · answered Aug 06 '19 at 05:14

1

How about:

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="/*">
    <MESSAGE>
        <PALLET>
            <xsl:variable name="total" select="count(ObjectEvent/epcList/epc)" />
            <xsl:for-each select="ObjectEvent">
                <MATERIAL>
                    <BOX>
                        <TOTAL>
                            <xsl:value-of select="$total"/>
                        </TOTAL>
                        <xsl:for-each select="epcList/epc">
                            <SERIES>
                                <ITEM>
                                    <xsl:value-of select="substring-after(substring-after(., '.'), '.')"/>
                                </ITEM>
                            </SERIES>
                        </xsl:for-each> 
                    </BOX>
                </MATERIAL>
            </xsl:for-each> 
        </PALLET>
    </MESSAGE>
</xsl:template>

</xsl:stylesheet>

answered Aug 06 '19 at 05:14

michael.hor257k

113,275
6
33
51

Sorry Sir michael, I'm getting a 0 for the TOTAL – XSLT newbie Aug 06 '19 at 05:35
1

It works as expected for me - see: https://xsltfiddle.liberty-development.net/bnnZX9 – michael.hor257k Aug 06 '19 at 06:24
okay sir let me fiddle around with my code. it's weird that mine says 0 zero. – XSLT newbie Aug 06 '19 at 07:19
1

Perhaps `ObjectEvent` is also in a namespace? Are there any occurrences of a default namespace declaration of `xmlns="...."` in your actual XML? – Tim C Aug 06 '19 at 07:54
ah you are right Sir Tim! I missed something in my source payload and xslt sorry. I cannot use template match /* – XSLT newbie Aug 06 '19 at 09:50
1

@XSLTnewbie If your input XML is different from the one you posted, then please edit your question and show what your actual input looks like. – michael.hor257k Aug 06 '19 at 10:03
@michael.hor257k, i have edited the xslt. i have added at the start. that's the only difference – XSLT newbie Aug 06 '19 at 10:07
tried this also: , count is showing an incorrect sum – XSLT newbie Aug 06 '19 at 10:13
1

@XSLTnewbie We are not making progress here. You say that **my** XSLT does not work with your XML, so **your** XSLT is irrelevant. If your **XML** is similar to what you posted, then my XSLT will produce the expected result. – michael.hor257k Aug 06 '19 at 10:17
Thanks sir @michael.hor257k. I forgot the 2 parent segments above ObjectEvent. It's working now. – XSLT newbie Aug 06 '19 at 11:15

Count for ALL instances of a field (even in other segments)

1 Answers1