How can I calculate lot size risking X% of account balance

Question

My question is in two closely related parts:

1. Given the entry price and stop loss, how can I calculate my lot size so that 2.5% of my current account balance would be risked on trades?

2. Also in cases where the 2.5% lot size is not a tradable lot size, say 0.013 and 0.018, how can I round the lot size already calculated in 1. to the closest tradable lot size 0.01 (for 0.013) and 0.02 (for 0.018)?

I know how to calculate the number of pips between my entry price and stop loss:

double DiffInPips = MathAbs(NormalizeDouble(stopLoss-openPrice,Digits)/Point);

I believe it is needed to solve this, but not sure how to arrive at the desired lot sizes in both of the above.

Answer 1

Calculating the risk-exposed part of your equity is a trivial but not on-topic here, so let me here focus on the programming, solving the item 2:

double NormalizeLotsToTRADE( const double aLotSizeREQUESTED )         // DEMO CODE
{  
   double  aMinSIZE = MarketInfo( _Symbol, MODE_MINLOT  ),
           aMaxSIZE = MarketInfo( _Symbol, MODE_MAXLOT  ),
           aFixSTEP = MarketInfo( _Symbol, MODE_LOTSTEP );
   
   return( MathMin(            aMaxSIZE,                              // never > MAXLOT
                    MathMax(   aMinSIZE,                              // never < MINLOT
                             ( aMinSIZE                               // ~ min + steps
                             + aFixSTEP * MathFloor( ( aLotSizeREQUESTED
                                                     - aMinSIZE
                                                       )
                                                     / aFixSTEP
                                                     )
                               )
                             )
                    )
           );
    }

For a case your Risk-Manager is not so strict on your risk-modeling caveats and permit you to go into "closest" rounding, may use MathRound() instead of risk-management strict using of MathFloor().

Answer 2

double GetLotSize()
{
    double balance = AccountBalance();
    double tradeAmount = balance * RiskPercentage / 100.0;
    
    double pipValue = MarketInfo(Symbol(), MODE_TICKVALUE) / 
    MarketInfo(Symbol(), MODE_TICKSIZE);
    double pipsToRisk = StopLossPips;
    
    double lotSize = tradeAmount / (pipsToRisk * pipValue);

    double minLot = MarketInfo(Symbol(), MODE_MINLOT);
    double maxLot = MarketInfo(Symbol(), MODE_MAXLOT);
    double lotStep = MarketInfo(Symbol(), MODE_LOTSTEP);

    lotSize = MathRound(lotSize / lotStep) * lotStep;
    lotSize = MathMax(minLot, MathMin(maxLot, lotSize));

    return lotSize;
}