How to implement around in Raku

Question

In Perl, using Moo, you can implement around subs, which will wrap around other methods in a class.

around INSERT => sub {
    my $orig = shift;
    my $self = shift;

    print "Before the original sub\n";
    my $rv  = $orig->($self, @_);
    print "After the original sub\n";
};

How can this behaviour be implemented in Raku, preferably using a role?

score 8 · Answer 1 · answered Nov 06 '19 at 15:42

8

You can shadow the method with the role and then use callwith:

class Foo {
    method meth { say 2 }
}

my $foo = Foo.new but role :: {
    method meth(|c) { say 1; callwith(|c); say 3 }
};

$foo.meth

answered Nov 06 '19 at 15:42

ugexe

5,297
1
28
49

Holli · Answer 2 · 2019-11-06T19:42:15.590

8

Method::Modifiers

Implements before(), after() and around() functions that can be used to modify class methods similarly to Perl 5's Moose. It uses wrap() internally, and returns the wrapper handler, so it is easy to .restore() the original.

This is how the module implements around:

sub around ($class, $method-name, &closure) is export
{
  $class.^find_method($method-name).wrap(method { closure(); });
}

edited Nov 06 '19 at 19:42

answered Nov 06 '19 at 19:27

Holli

5,072
10
27

jjmerelo · Answer 3 · 2019-11-06T17:25:34.553

6

Use wrap

sub bar () { return "baþ" };

my $wrapped = &bar.wrap( { " → " ~ callsame() ~ " ← " } );

say bar(); # OUTPUT:  «→ baþ ← »

Since methods are routines, you'll need a slightly more convoluted way to get a handle on the method itself, but other than that, the method is exactly the same, since Methods are a subclass of Routines

class Baz {
    method bar () { return "baþ" };
}

my &method_bar = Baz.^find_method("bar");
my $wrapped = &method_bar.wrap( { " → " ~ callsame() ~ " ← " } );

say Baz.bar(); # OUTPUT:  «→ baþ ← »

The $wrapped is a handle that can be used, later on, to unwrap it if needed.

Edit: to add the code to get a handle on the class method, taken from here, for instance.

edited Nov 06 '19 at 17:25

answered Nov 06 '19 at 17:10

jjmerelo

22,578
8
40
86

Wrap doesn't wrap methods – ugexe Nov 06 '19 at 17:11
@ugexe the OP refers explicitly to subs. Also, you can just use that for methods, since it's a [`Method` is a `Routine`](https://docs.raku.org/type/Method) – jjmerelo Nov 06 '19 at 17:11
I think you're confused. The question itself states 'wrap around other methods in a class.'. `Moo`s around is nothing like wrapping a subroutine. – ugexe Nov 06 '19 at 17:13
@ugexe same difference. Methods are Routines, as I said after the edit. – jjmerelo Nov 06 '19 at 17:17

How to implement around in Raku

3 Answers3