Windows batch file to insert a blank line / remove single lines - nmap output

Question

I'm trying to clean up nmap results and get a cleaner/easier to work with file, that has just the data I need - basically, IP and open ports.

(no need to integrate it into a solution, I can get them to work together)

This line cleans up the initial output:

findstr "Nmap open"|findstr /v "no-response"

It keeps lines with the txt Nmap, and the ports that are open. It then removes the lines that include "no-response" (that also have "Nmap" in them)

Here is resultant output:

Nmap scan report for 1.1.1.1
21/tcp   open  
22/tcp   open  
80/tcp   open   
Nmap scan report for 1.1.1.2
Nmap scan report for 1.1.1.3
22/tcp  open     
Nmap scan report for 1.1.1.4
80/tcp  open     
443/tcp open     
Nmap scan report for 1.1.1.5
80/tcp    open     
554/tcp   open     

I'd like that output to include blank lines, and omit lines with no subsequent open ports, i.e.:

Nmap scan report for 1.1.1.1
21/tcp   open  
22/tcp   open  
80/tcp   open   

Nmap scan report for 1.1.1.3
22/tcp  open     

Nmap scan report for 1.1.1.4
80/tcp  open     
443/tcp open 

Nmap scan report for 1.1.1.5 
80/tcp    open     
554/tcp   open  

Not sure if that's doable -- seems like it should be...

Answer 1

Although this question is too broad as it contains no attempt to solve the issue, I decided to provide a script that makes use of an undocumented findstr feature, namely to search beyond lines (see all the rem remarks in the code):

@echo off
setlocal EnableExtensions DisableDelayedExpansion

rem // Define constants here:
set "_FILE=%~1"         & rem // (path and name of input file; `%~1` is first argument)
set "_BEGIN=Nmap"       & rem // (expected beginning of lines; must not contain `=`, `"`)
set "_INCL=open"        & rem // (expected part of subsequent lines; must not contain `"`)
set "_EXCL=no-response" & rem // (part of subsequent lines to exclude; must not contain `"`)

rem // Gather carriage-return character:
for /F %%C in ('copy /Z "%~f0" nul') do set "$CR=%%C"
rem // Gather line-feed character:
(set ^"$LF=^
%= blank line =%
^")

rem // Reset flag variable that is used to not insert line-break before first match:
set "FLAG="
rem /* Loop through matching lines; the first `findstr` command excludes all lines that contain
rem    the predefined part; the second one uses the feature of `findstr` to match beyond lines
rem    when the search string contains line-breaks, although only the portion up to the (first)
rem    line-break is returned; hence the first search string ensures that there is at least one
rem    line with the prefedined part in between the lines with the predefined beginning; and
rem    the second search string matches the lines with the predefined parts in between: */
for /F "delims=" %%L in ('
    cmd /V /C findstr /V /R /C:" !_EXCL!\>" "!_FILE!" ^| ^
        cmd /V /C findstr /R /C:"^^!_BEGIN!  *..*!$CR!!$LF!..* * !_INCL!\>" /C:" !_INCL!\>"
') do (
    rem // Store current line string:
    set "LINE=%%L"
    rem // Toggle delayed expansion to avoid trouble with `!`:
    setlocal EnableDelayedExpansion
    rem // Check whether current line starts with predefined beginning:
    if "!_BEGIN!!LINE:*%_BEGIN%=!"=="!LINE!" (
        rem // Line starts with predefined beginning, hence conditionally return line-break:
        if defined FLAG echo/
        rem // Output current line string:
        echo(!LINE!
        endlocal
        rem // Set flag to insert line-breaks before further matches:
        set "FLAG=#"
    ) else (
        rem // Line does not start with predefined beginning, so just output current line string:
        echo(!LINE!
        endlocal
    )
)

endlocal
exit /B

Given that the script is stored as prettify-nmap-log-file.bat use the following command line to process a certain input file (like log.nmap):

prettify-nmap-log-file.bat "log.nmap"

To write the result to another file (liek log.nmap.txt) use redirection:

prettify-nmap-log-file.bat "log.nmap" > "log.nmap.txt"

Answer 2

Give this batch-file a try, after modifying only the doublequoted path to your text file, on line 5:

@(Set LF=^
% 0x0A %
)
@For /F %%# In ('Copy /Z "%~f0" NUL')Do @Set "CR=%%#"
@Call :Sub "%UserProfile%\Desktop\dummy.txt"
@GoTo :EOF
:Sub
@Set "#=#"
@(For /F Delims^=^ EOL^= %%# In ('^""%__AppDir__%cmd.exe"/V/U/D/C""%%__AppDir__%%findstr.exe"/I "^^^^Nmap ^^^^[0-9]*/.*open\^^^>" "%~1"|"%%__AppDir__%%findstr.exe"/IV "^^^^Nmap.*!CR!!LF!Nmap.*"|"%%__AppDir__%%findstr.exe"/IV "^^^^[0-9N].*!CR!!LF![^^^^\ ]""^"')Do @Echo("%%#"|"%__AppDir__%findstr.exe"/I "^.N">NUL&&(If Not Defined # (Echo(&Echo(%%#)Else Echo(%%#&Set "#=")||Echo(%%#)>"%~dpn1_filtered%~x1"

The last line looks extremely long because I have included the full paths to files which should normally be available using the %PATH% and %PATHEXT% variables. This simply prevents it failing should something have happened to those important variables.