Managing null values in variants using Delphi

Question

I'm working with a COM component which exposes a lot of Variant properties, but sometimes these values are null. When I try to convert these values to string (or another Delphi type) the application raises an exception like this:

Could not convert variant of type (Null) into type (String)

But if I use .net to call the same properties and the values are null, no exceptions are raised and the null values are treated as empty strings.

My question there is a way to handle these null values from Delphi avoiding these exceptions?

Thanks in advance.

score 30 · Accepted Answer · edited May 23 '17 at 12:25

30

Try setting NullStrictConvert to False.

As it's a global variable I use it like follows to minimize side effects:

var
  OldNullStrictConvert: Boolean;
begin
  OldNullStrictConvert := NullStrictConvert;
  NullStrictConvert := False;
  try
    // code containing conversions
  finally
    NullStrictConvert := OldNullStrictConvert;
  end;
end;

(In reality I have made a guardian interface out of this.)

NB: Where it's feasible I prefer code like Warren's.

edited May 23 '17 at 12:25

Community

1
1

answered May 09 '11 at 18:34

Uli Gerhardt

13,748
1
45
83

@user422039: I love `strict` but how is it connected to Salvador's problem? – Uli Gerhardt May 09 '11 at 19:30
i believe what Salvador's problem interconnects keyboard, chair and ignored documentation (see my answer, second link is very verbose on Null and NullStrictConvert). – user422039 May 10 '11 at 02:48
1

-1 Being a global variable, `NullStrictConvert` is not thread-safe, so setting it can have unwanted side effects in multi-threaded apps. – Remy Lebeau May 08 '12 at 01:45

Warren P · Answer 2 · 2011-05-10T13:34:41.583

The accepted answer changes a global setting, and could have unintended side effects on the operation of other code that was working before you changed it.

First you could just use VarToStrDef, secondly, if you must provide some functionality other than that, then I would have my code call my own function MyVarToStr, and do it like this:

resourcestring
    SNilValue = '[nil]';


function VarIsAssigned(v:Variant):Boolean; inline;
begin
          result := (v<>Variants.Null) and (not VarIsNull(V));
end;


function MyVarToStr( v:Variant):String;
begin
  if VarIsAssigned(v) then
    result := VarToStr(v)
else
    result := SNilValue;
end;

Since it seems that VarToStrDef should be enough, I only mean to demonstrate that it's better to write your code and call your own code, than to try to "globally change" the default behaviour of VCL/RTL library code.

Indeed. When possible I prefer solutions similar to your's. But sometimes the conversion is buried deep in library code you have no control over. — Uli Gerhardt, May 09 '11 at 23:11
Oh yea. That's a helper in one of my personal-standard-library functions. added a definition. — Warren P, May 10 '11 at 13:35

user422039 · Answer 3 · 2011-05-10T02:57:55.380

This is a documented behaviour of VarToStr function. There is no need to reinvent a wheel.

Null variant is distinct type (yes, it is a type, not merely a value), which denotes either missing or unknown data. So, strictly speaking, regular variant dynamic-typing should not happen with Null values (illustrated and reflected in RTL defaults).

given:

var
  V: Variant;
  S: string;

better code

S := VarToStr(V);             { stongly-typed explicit conversion }

relatively good code

if not VarIsNull(V) then      { program knows what it does, but reproduces RTL behaviour }
  S := V
else
  S := NullAsStringValue;

bad code

NullStrictConvert := False;   { smelly, from now on Null variant loses its specifics }
S := V;

even worse code

try
  S := V;
except on Eaten: Exception do { stinky PHP-style, hiding error instead of fixing it }
  S := NullAsStringValue;
end;

NOTE: Most late Delphi.NET exhibits exactly the same behaviour on Null variants, so OP's remark about .NET is questionable.

score 9 · Answer 4 · answered May 08 '12 at 01:48

9

VarToStr() and VarToStrDef() are the correct and proper way to convert a Null Variant to a String, as they explicitially check for Null values internally.

answered May 08 '12 at 01:48

Remy Lebeau

555,201
31
458
770

score 4 · Answer 5 · answered Feb 09 '12 at 07:55

4

..from user422039 code use VarToStr otherwise S:=V relays on an implicit conversion which may create different result on different environment:

S := VarToStr(V);
or
S := VarToStrDef(V, yourdefaultvalue);

answered Feb 09 '12 at 07:55

hola

71
2