How to get captions of actual windows currently running?

Question

I have a question: I simply need to get captions of all windows in a list, by captions I mean the "Notepad", "Total Commander" - simply the text shown in the top-edge of a window.

So far I've gotten here

function EnumWindowProc(hHwnd: HWND; lParam : integer): boolean; stdcall;
var
  pPid : DWORD;
  title, ClassName : string;
begin
  if (hHwnd=NULL) then
  begin
    result := false;
  end
  else
  begin
    GetWindowThreadProcessId(hHwnd,pPid);
    SetLength(ClassName, 255);
    SetLength(ClassName,
              GetClassName(hHwnd,
                           PChar(className),
                           Length(className)));
    SetLength(title, 255);
    SetLength(title, GetWindowText(hHwnd, PChar(title), Length(title)));
    OptionsForm.ListBox1.Items.Add(title);
    OptionsForm.Memo1.Lines.Add
      ('Class Name = ' + className +
       '; Title = ' + title +
       '; HWND = ' + IntToStr(hHwnd) +
       '; Pid = ' + IntToStr(pPid));
    Result := true;
  end;
end;

But well, it returns all kinds of "windows", different focuses of forms etc. How can I get only the "main" ones?

Here is a sample of the results:

Class Name = Shell_TrayWnd; Title = ; HWND = 65898; Pid = 3776
Class Name = CiceroUIWndFrame; Title = CiceroUIWndFrame; HWND = 65976; Pid = 3776
Class Name = THelpInsightWindowImpl; Title = HelpInsightWindow; HWND = 1577734; Pid = 4852
Class Name = THelpInsightWindowImpl; Title = HelpInsightWindow; HWND = 591660; Pid = 4852
Class Name = TTokenWindow; Title = CodeParamWindow; HWND = 985436; Pid = 4852
Class Name = TaskSwitcherWnd; Title = Přepínání úloh; HWND = 66824; Pid = 3776
Class Name = tooltips_class32; Title = ; HWND = 198982; Pid = 1768
Class Name = tooltips_class32; Title = ; HWND = 66046; Pid = 3776
Class Name = _SearchEditBoxFakeWindow; Title = ; HWND = 66024; Pid = 3776
Class Name = tooltips_class32; Title = ; HWND = 66008; Pid = 3776
Class Name = tooltips_class32; Title = ; HWND = 131538; Pid = 3776
Class Name = Desktop User Picture; Title = Magicmaster; HWND = 65982; Pid = 3776
Class Name = DV2ControlHost; Title = Nabídka Start; HWND = 65978; Pid = 3776
Class Name = tooltips_class32; Title = ; HWND = 327840; Pid = 1768
Class Name = tooltips_class32; Title = ; HWND = 460808; Pid = 1768
Class Name = CTSCTooltip; Title = ; HWND = 266710; Pid = 2792
Class Name = Auto-Suggest Dropdown; Title = ; HWND = 69884; Pid = 4732
Class Name = Auto-Suggest Dropdown; Title = ; HWND = 69802; Pid = 4732
Class Name = TaskbarNotifierClass; Title = DAP Message Center; HWND = 68924; Pid = 4732
Class Name = tooltips_class32; Title = ; HWND = 134356; Pid = 1992
Class Name = ATKOSD; Title = ATKOSD; HWND = 65884; Pid = 3636

Thank you in advance!

Rob's right. What are you looking for. As a wild guess, I suspect you want just the windows that have buttons in the taskbar. — David Heffernan, May 10 '11 at 15:13
From [MSDN](http://msdn.microsoft.com/en-us/library/cc144179(VS.85).aspx#Managing_Taskbar_But): The Shell creates a button on the taskbar whenever an application creates a window that isn't owned. To ensure that the window button is placed on the taskbar, create an unowned window with the WS_EX_APPWINDOW extended style. — David Heffernan, May 10 '11 at 15:19
Yeah, by "main" I mean those that can be focused through alt+tab or have icons in taskbar. — Martin Melka, May 10 '11 at 16:07

David Heffernan · Accepted Answer · 2023-02-28T21:59:32.953

10

The important information is contained in the MSDN topic describing the taskbar. Essentially you need to enumerate the top-level windows and pick out those that are visible, unowned and have the WS_EX_APPWINDOW window style.

This program shows you how it is done:

program EnumTaskbarWindows;

{$APPTYPE CONSOLE}

uses
  SysUtils, Windows;

function EnumWindowsProc(hwnd: HWND; lParam: LPARAM): BOOL; stdcall;
var
  s: string;
  len: Integer;
  IsVisible, IsOwned, IsAppWindow: Boolean;
begin
  Result := True;//carry on enumerating

  IsVisible := IsWindowVisible(hwnd);
  if not IsVisible then
    exit;

  IsOwned := GetWindow(hwnd, GW_OWNER)<>0;
  if IsOwned then
    exit;

  IsAppWindow := GetWindowLongPtr(hwnd, GWL_STYLE) and WS_EX_APPWINDOW<>0;
  if not IsAppWindow then
    exit;
  
  len := GetWindowTextLength(hwnd);
  if len = 0 then
    exit;
  SetLength(s, len);
  GetWindowText(hwnd, PChar(s), len+1);
  Writeln(s);
end;

begin
  EnumWindows(@EnumWindowsProc, 0);
end.

edited Feb 28 '23 at 21:59

answered May 10 '11 at 19:58

David Heffernan

601,492
42
1,072
1,490

This is it. Thank you for the MSDN link too. I didn't know the criteria for the windows. – Martin Melka May 11 '11 at 12:10
1

@David Heffernan - After a quick look I realized that unfortunately your code does not show some windows such as BSPlayer and Kaspersky KIS and Delphi. – Gabriel Aug 10 '13 at 16:54
Why not? What does the debugger tell you? – David Heffernan Aug 10 '13 at 16:54
It missed Windows calculator. – user30478 Nov 17 '18 at 19:44
I get an AV on GetWindowText. – Gabriel Feb 28 '23 at 21:06
You need a "if s = '' then EXIT" check before GetWindowText – Gabriel Feb 28 '23 at 21:09

score 1 · Answer 2 · answered May 10 '11 at 14:40

You want to check the properties of these windows. For instance, exclude any window that's not visible. You do this with GetWindowInfo. The properties to look for: no caption (missing WS_CAPTION in dwStyle), or not visible (WS_VISIBLE flag). You might also want to check for windows that are moved off screen, but that's slightly tricky (there could be multiple monitors, even at negative offsets)

How to get captions of actual windows currently running?

2 Answers2

Linked