Delphi: How to get the *real* ASCII code from a string

Question

This is driving me crazy. I have been two days converting my string from one type to another with no success.

I'm using Delphi Rio and I need to convert a string to HEX or DEC, but the string contains special characters, like á é í ó ú ñ or €.

For example, the 'á' character is 160 (dec) or A0 (hex). However, I'm getting 225, 145, 241 depending on the string type (ansichar, utf8, widechar...) but I don't know how can I get the real 160 value.

I need this because I want to send special characters to a bluetooth printer. If I send this:

edit1.text := 'áéíóú€$';
FSocket.SendData(TEncoding.ASCII.GetBytes(edit1.Text));

Printer receives this (HEX):

3F 3F 3F 3F 3F 3F 24

However, it should receive this (HEX):

A0 82 A1 A2 A3 D5 24

That's because I'm getting the wrong ASCII value for each character (63 is the ascii code for '?' character).

So... how can I send the real ASCII text to the printer? How can I get the real ascii code for 'á' (160)?

Please help!

Answer 1

First, there is no such thing as a real ASCII code for characters beyond 0x7F. ASCII defines 7-bit characters only. When considering text encoding using characters in the upper half (0x80->0xFF) of the 8-bit character range the encodings are no longer ASCII, but ANSI, and there are hundreds of different encoding schemes, all of which support different varieties of special characters. The complete mutual incompatibility of ANSI encoding schemes is one of the main drivers for the development and migration to Unicode.

We can deduce from your expected outputs that the ANSI codepage you are trying to map to is Code Page 858. Your printer manual probably tells you this somewhere, but for now we will assume that this is the only input the printer accepts. It's always a good idea to read your manuals - they will save you endless headaches in the future. As David noted, if you can use Unicode, this should always be your first, best option.

You can extract the desired bytes using the TEncoding class like :

program Project1;

{$APPTYPE CONSOLE}

uses
  SysUtils;

var      
  LEncoding : TEncoding;
  tb : TBytes;
  b : Byte;
begin
  LEncoding := TEncoding.GetEncoding(858);
  try
    tb := LEncoding.GetBytes('áéíóú€$');
  finally
    LEncoding.Free;
  end;
  for b in tb do Write(IntToHex(b,2) + ' ');    
  ReadLn;    
end.

This produces output :

 A0 82 A1 A2 A3 D5 24