How do I color a cxgrid based on table value?

Question

I would like all rows where in particular field name 'hello' is present to get colored green. I tried this on customdrawcell:

if abstable1.fieldbyname('somename').asstring = 'Hello' then
  cxgrid.canvas.brush.color:=clGreen

But it wont work... what am I missing here ?

Post your actual code for the entire event handler, not something you just made up for your question. Also, format it by either indenting it by four spaces or selecting it all and clicking the {} button or pressing Ctrl+K. Actual code allows us to see what's wrong, or at least copy and paste to help figure it out. — Ken White, May 21 '11 at 01:02

score 9 · Answer 1 · answered May 22 '11 at 02:41

9

Use the OnGetContentStyle event for either individual columns or the grid object. Styles are much easier to work with than messing with the canvas.

answered May 22 '11 at 02:41

Sam M

4,136
4
29
42

2

Yes, 100%. Styles are much easier to work and safer too. By separating the logic that chooses the style from how each style should be presented, you are free to change one of them without compromising the other (like HTML and CSS). Besides that, you also promotes reusability and standardization, since the styles can be shared among different grids. – Rafael Piccolo Apr 19 '12 at 12:03

score 6 · Answer 2 · answered May 24 '11 at 12:14

6

You need to look at the internal data for each view row rather that the data of the current position in the table. Also make use of the canvas provided in the OnCustomDrawCell() event.

procedure TForm1.YourViewCustomDrawCell(
  Sender: TcxCustomGridTableView; ACanvas: TcxCanvas;
  AViewInfo: TcxGridTableDataCellViewInfo; var ADone: Boolean);
begin
  if(AViewInfo.GridRecord.Values[YourColumn.Index] = 'Hello') then
    ACanvas.Brush.Color := clGreen;
end;

answered May 24 '11 at 12:14

avenmore

2,809
3
33
34

@user763539: will work, as long as you have view columns for every field in the table and they are in the same order. – avenmore May 27 '11 at 17:35

score 5 · Accepted Answer · answered May 21 '11 at 13:09

Don't try to change canvas colors in the Grid. Rather--and I find this to always be true--change colors in the View's OnDrawCell handler, as in this example:

procedure T_fmTabSnapList.View1CustomDrawCell(Sender: TcxCustomGridTableView;
  ACanvas: TcxCanvas; AViewInfo: TcxGridTableDataCellViewInfo; var ADone: Boolean);
begin
  if abstable1.fieldbyname('somename').asstring = 'Hello' then 
    ACanvas.Brush.Color := clGreen
end;

The cxGrid is just a container for Views. Views are where all the painting occurs. s

Got it to work ....if(AViewInfo.GridRecord.Values[DataModule2.ABSTable7.Index]...Thank you all... — user763539, May 26 '11 at 21:55

score 1 · Answer 4 · answered May 29 '13 at 09:47

procedure Tfm1.Grid1StylesGetContentStyle(Sender: TcxCustomGridTableView;
  ARecord: TcxCustomGridRecord; AItem: TcxCustomGridTableItem;
  out AStyle: TcxStyle);
Var
 Style1: TcxStyle;
begin
 if AItem = nil then exit;

 if ARecord.Values[Grid1Med.Index] = true then
   AStyle := cxStyleMed;

 if ARecord.Values[Grid1CP.Index] = true then
   AStyle := cxStyleHost;

 if (ARecord.Values[Grid1Med.Index] = true) and
    (ARecord.Values[Grid1CP.Index] = true) then
   AStyle := cxStyleHostAndCP;

  if not VarIsNull(ARecord.Values[colColor.Index]) then
  begin
    if not Assigned(AStyle) then
      AStyle := TcxStyle.Create(Sender);
    AStyle.Color := ARecord.Values[colColor.Index];
  end;
end;

score 0 · Answer 5 · answered May 21 '11 at 03:44

Here's some working code from a program of mine which does something similar.

procedure TDoDockets.grDocketsDrawColumnCell(Sender: TObject;
            const Rect: TRect; DataCol: Integer; Column: TColumn;
            State: TGridDrawState);
begin
 with grDockets do
  begin
   if (qDocketsOpenCost.asinteger > 1) and (datacol = 5)
    then canvas.font.color:= clRed;

   if datacol = 9 then // status
    if qDocketsColour.Value <> 0
     then Canvas.font.color:= tcolor (qDocketsColour.Value);

   if datacol = 10 then // attention
    if qDocketsAttention.asinteger = 1
     then canvas.brush.color:= clRed;

   if qDocketsUrgent.asinteger = 1 then canvas.brush.color:= 10092543;
   // light yellow
   DefaultDrawColumnCell (Rect, DataCol, Column, State);
  end
end;

grDockets is the grid, and qDockets is the query being displayed within the grid. Certain columns may be drawn in a different colour depending on the value being displayed, and in one case (qDocketsUrgent = 1), the entire line's background colour is changed.

How do I color a cxgrid based on table value?

5 Answers5

Linked