Bootloader won't load the kernel

Question

I actually made a bootloader with two stages because I set the video mode to 1920px*1080px by using the VESA BIOS extensions (which requires more than 512 bytes.).

Right now I'm trying to call my own kernel to begin plotting pixels etc.. but it didn't work.

I based my bootloader on Michael Petch's code from the answer to this question

bootloader.asm:

%include "stage2info.inc"

STAGE2_LOAD_SEG     equ STAGE2_ABS_ADDR >> 4
STAGE2_LBA_START    equ 1
STAGE2_LBA_END      equ STAGE2_LBA_START + NUM_STAGE2_SECTORS

[BITS 16]
[ORG 0x7c00]

%include "BPB.inc"
%include "error.asm"

bootloader_main:
    xor ax, ax
    mov ds, ax
    mov ss, ax
    mov sp, 0x7c00
    cld

load_stage2:
    mov [bootDevice], dl
    mov di, STAGE2_LOAD_SEG
    mov si, STAGE2_LBA_START
    jmp check_for_last_lba

read_sector:
    call lba_to_chs
    mov es, di
    xor bx, bx

retry:
    mov ax, 0201h
    int 13h
    jc disk_error

success:
    add di, 512>>4
    inc si

check_for_last_lba:
    cmp si, STAGE2_LBA_END
    jl read_sector

stage2_loaded:
    mov ax, STAGE2_RUN_SEG
    mov ds, ax
    mov es, ax

    jmp STAGE2_RUN_SEG:STAGE2_RUN_OFS

lba_to_chs:
    push ax
    mov ax, si
    xor dx, dx
    div word[sectorsPerTrack]
    mov cl, dl
    inc cl
    xor dx, dx
    div word[numHeads]
    mov dh, dl
    mov dl, [bootDevice]
    mov ch, al
    shl ah, 6
    or cl, ah
    pop ax
    ret

bootDevice: db 0x00

times 510 - ($-$$) db 0
DW 0xAA55

NUM_STAGE2_SECTORS equ (stage2_end - stage2_start + 511) / 512

stage2_start:
    incbin "stage2.bin"

stage2_end:

stage2.asm:

%include "stage2info.inc"

[BITS 16]
[ORG STAGE2_RUN_OFS]

start:
    ;graphics stuff here...

    call load_kernel

    cli
    lgdt[gdt_descriptor]

    mov eax, cr0
    or eax, 1
    mov cr0, eax

    jmp 0x8:kernel_entry

[BITS 32]
kernel_entry:
   mov ax, 0x10
   mov ss, ax
   mov ds, ax
   mov es, ax
   mov fs, ax
   mov gs, ax

   mov ebp, 0x90000
   mov esp, ebp

   call KERNEL_OFFSET
   jmp $


[BITS 16]

load_kernel:
    mov bx, KERNEL_OFFSET
    mov dh, 15
    mov dl, 0

    mov ah, 0x02
    mov al, dh
    mov ch, 0x00
    mov dh, 0x00
    mov cl, 0x02
    int 0x13
    ret

GDT:
    dq 0

    dw 0xFFFFF
    dw 0x0
    db 0x0
    db 10011010b
    db 11001111b
    db 0x0

    dw 0xFFFFF   
    dw 0x0          
    db 0x0
    db 10010010b 
    db 11001111b 
    db 0x0

gdt_descriptor :
    dw $ - GDT - 1
    dd GDT

incbin "../kernel/kernel.bin"

VESAInfo        db 'VBE3'
                times 508 db 0

MODEInfo        times 256 db 0

ModeInfoBlock   times 256 db 0

KERNEL_OFFSET equ 0x1000

%include "error.asm"

stage2info.asm:

STAGE2_ABS_ADDR     equ 0x07e00
STAGE2_RUN_SEG      equ 0x0000
STAGE2_RUN_OFS      equ STAGE2_ABS_ADDR

kernel.asm:

[bits 32]

jmp $

And I build the image like the following:

#!/bin/bash

nasm -f bin stage2.asm -o stage2.bin
nasm -f bin ../kernel/kernel.asm -o ../kernel/kernel.bin
nasm -f bin bootloader.asm -o bootloader.bin

dd if=/dev/zero of=disk.img bs=512 count=2880
dd if=bootloader.bin of=disk.img conv=notrunc
qemu-system-i386 -fda disk.img -boot a

Any idea why it didn't work?

That's a lot of code. Reduce to [mcve]. If you have trouble with loading remove the graphics stuff and everything else. Make sure your chs conversion is correct, maybe hardcode the values first. Use a debugger (bochs recommended) to see what is happening. — Jester, May 23 '20 at 18:39
There isn't a need for `load_kernel`. THe first stage actually reads as many sectors into memory for stage2. Stage2 is technically part of your kernel. It looks like what you really want to do is create separate asm files and link them with stage2 rather than include `kernel.bin with `incbin`. You'd assemble stage2.asm to an elf object (with -f elf), same with kernel.asm. You'd link them together with LD to an elf executable and then output it to binary (I use objcopy to convert an elf executable to binary). If I get a chance I can try answering this a bit later more in depth. — Michael Petch, May 23 '20 at 19:20
@MichaelPetch `error.asm` contains just some text printing functions. — MARSHMALLOW, May 23 '20 at 19:33
@MichaelPetch Can you show me an example please? I really need this. — MARSHMALLOW, May 23 '20 at 19:44
@MichaelPetch Can I just jump to my kernel by entering protected mode, then switch back to the real mode to achieve the graphics stuff and then enter the protected mode again? — MARSHMALLOW, May 24 '20 at 00:51

score 1 · Accepted Answer · answered May 26 '20 at 14:07

The problem is solved by entering the protected mode and including the kernel.asm file instead of the binary file.

Here's how (stage2.asm):

%include "stage2info.inc"

[BITS 16]
[ORG STAGE2_RUN_OFS]

start:
    pusha
    mov ah, 0x00
    mov al, 0x03
    int 10h
    popa

    mov ax, 4F00h
    mov di, VESAInfo
    int 10h

    cmp al, 4Fh
    jne VBE_error

    mov si, [VESAInfo + 0Eh]

loop:
    mov ax, [VESAInfo + 10h]
    mov es, ax
    mov dx, word[es:si]

    cmp dx, 0FFFFh
    je got_mode

    add si, 2
    mov cx, dx
    mov ax, 4F01h
    mov di, MODEInfo
    int 10h

    cmp al, 4Fh
    jne loop

    mov ax, word[MODEInfo]
    bt ax, 0
    jnc loop
    bt ax, 4
    jnc loop
    bt ax, 7
    jnc loop

    mov ax, word[MODEInfo + 12h]
    cmp ax, 1920
    jne loop

    mov ax, word[MODEInfo + 14h]
    cmp ax, 1080
    jne loop

    xor ax, ax
    mov al, byte[MODEInfo + 19h]
    cmp ax, 24
    jne loop

got_mode:
    mov ax, 4F01h
    mov cx, dx
    mov di, ModeInfoBlock
    int 10h

    cmp ax, 4Fh
    jne VBE_error

    mov ax, 4F02h
    mov bx, dx
    int 10h

    cmp ax, 4Fh
    jne VBE_error

    cli
    lgdt [gdt_descriptor] ;Load the global descriptor table
    mov eax, cr0
    or al, 1
    mov cr0, eax

    jmp 0x8:prepare_segments ;prepare segments

prepare_segments:
    mov ax, 0x10
    mov ds, ax
    mov ss, ax
    mov es, ax
    mov fs, ax
    mov gs, ax

    jmp kernel ;jump to the kernel in kernel.asm!

GDT:
    dq 0

    dw 0xFFFFF
    dw 0x0
    db 0x0
    db 10011010b
    db 11001111b
    db 0x0

    dw 0xFFFFF   
    dw 0x0          
    db 0x0
    db 10010010b 
    db 11001111b 
    db 0x0

gdt_descriptor :
    dw $ - GDT - 1
    dd GDT

[BITS 32]
;We're already in the protected mode here!
%include "../kernel/kernel.asm" ;include the kernel

[BITS 16]

VESAInfo        db 'VBE3'
                times 508 db 0

MODEInfo        times 256 db 0

%include "ModeInfoBlock.asm"

KERNEL_OFFSET equ 0x1000

%include "error.asm"

Bootloader won't load the kernel

1 Answers1