Unified xslt for multiple SSRS reports (xml export)

Question

I have SSRS 2016 and some reports (similar structure but different names and data) to be transformed during xml export.

Report xml example:

<?xml version="1.0" encoding="utf-8"?>
<Report xsi:schemaLocation="My_Report_1 http://..." Name="My_Report_1"
    xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
    xmlns="My_Report_1">
    <Table>
        <tbl_MainGroup_Collection>
            <Data TxDev="abc" DateTime="20200906001057" DBVersion="1.0" ProductVersion="1.0" Version="1.0">
                <tbl_SiteGroup_Collection>
                    <Site SiteName="All sites">
                        <tbl_ColumnGroup_Collection>
                            <Column Column1="Week 33" Column2="Week 34">
                                <Lines>
                                    <Line LineName="abc" Column1="0.00" Column2="0.00" LineNumber="1" EntityType="0" EntityNo="1" />
                                    <Line LineName="dfg" LineNumber="-1" EntityType="0" EntityNo="2" />
                                </Lines>
                            </Column>
                        </tbl_ColumnGroup_Collection>
                    </Site>
                </tbl_SiteGroup_Collection>
            </Data>
        </tbl_MainGroup_Collection>
    </Table>
</Report>

XSLT transformation example:

<?xml version="1.0" encoding="utf-8" standalone="yes"?>
<xsl:stylesheet version="1.0"     
    xmlns:x="My_Report_1"
    exclude-result-prefixes="x"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:output omit-xml-declaration="no" indent="yes" method="xml" />
    
  <xsl:template match="x:Report|x:Table|x:tbl_MainGroup_Collection">
      <xsl:apply-templates />
  </xsl:template>

  <xsl:template match="x:Report/x:Table//x:Data">
    <Data TxDev="{@TxDev}" DateTime="{@DateTime}" DBVersion="{@DBVersion}" ProductVersion="{@ProductVersion}" Version="{@Version}">
      <xsl:apply-templates select="x:tbl_SiteGroup_Collection"/>
    </Data>
  </xsl:template>

  <xsl:template match="x:tbl_SiteGroup_Collection">
    <Sites>
      <xsl:apply-templates select="x:Site"/>
    </Sites>
  </xsl:template>

  <xsl:template match="x:Site">
    <Site SiteNumber="{@SiteNumber}" SiteID="{@SiteID}" SiteName="{@SiteName}">
      <xsl:apply-templates select="x:tbl_ColumnGroup_Collection"/>
    </Site>
  </xsl:template>

  <xsl:template match="x:tbl_ColumnGroup_Collection">
    <Columns>
      <xsl:apply-templates select="x:Column"/>
    </Columns>
  </xsl:template>

  <xsl:template match="x:Column">
    <xsl:for-each select="@*[starts-with(local-name(), 'Column')]">
      <Column ColumnNumber="{translate(local-name(),'Column','')}" ColumnName="{.}">
        <xsl:variable name="attrName" select="local-name()"/>
        <xsl:for-each select="../x:Lines">
          <xsl:call-template name="Lines">
            <xsl:with-param name="ColumnName" select="$attrName"/>
          </xsl:call-template>
        </xsl:for-each>
      </Column>
    </xsl:for-each>
  </xsl:template>

  <xsl:template name="Lines" match="x:Lines">
    <xsl:param name="ColumnName"/>
    <Lines>
      <xsl:for-each select="x:Line[@LineNumber&gt;0 and @EntityType=0]">
        <xsl:sort select="@LineNumber" data-type="number" />
        <xsl:call-template name="Line">
          <xsl:with-param name="ColumnName" select="$ColumnName"/>
        </xsl:call-template>
      </xsl:for-each>
    </Lines>
  </xsl:template>

  <xsl:template name="Line" match="x:Line">
    <xsl:param name="ColumnName"/>
    <Line LineNumber="{@LineNumber}" LineName="{@LineName}" >
      <xsl:variable name="LineNo" select="@LineNumber"/>
      <xsl:choose>
        <xsl:when test="count(../x:Line[@LineNumber=$LineNo and @EntityType=1])>0">
          <xsl:attribute name="Value">
            <xsl:value-of select="@*[local-name()=$ColumnName]"/>
          </xsl:attribute>
          <Departments>
            <xsl:for-each select="../x:Line[@LineNumber=$LineNo and @EntityType=1]">
              <xsl:sort select="@EntityNo" data-type="number"/>
              <Department DepNumber="{@EntityNo}" DepName="{@LineName}" Value="{@*[local-name()=$ColumnName]}">
              </Department>
            </xsl:for-each>
          </Departments>
        </xsl:when>
        <xsl:when test="count(../x:Line[@LineNumber=$LineNo and @EntityType=2])>0">
          <xsl:if test="@*[local-name()=$ColumnName]">
            <xsl:attribute name="Value">
              <xsl:value-of select="@*[local-name()=$ColumnName]"/>
            </xsl:attribute>
          </xsl:if>
          <MOPs>
            <xsl:for-each select="../x:Line[@LineNumber=$LineNo and @EntityType=2]">
              <xsl:sort select="@EntityNo" data-type="number"/>
              <MOP MOPNumber="{@EntityNo}" MOPName="{@LineName}" Value="{@*[local-name()=$ColumnName]}">
              </MOP>
            </xsl:for-each>
          </MOPs>
        </xsl:when>
        <xsl:otherwise>
          <xsl:attribute name="Value">
            <xsl:value-of select="@*[local-name()=$ColumnName]"/>
          </xsl:attribute>
        </xsl:otherwise>
      </xsl:choose>
    </Line>
  </xsl:template>

  <xsl:template match="/">
    <xsl:apply-templates />
  </xsl:template>

</xsl:stylesheet>

Due to namespace binding xmlns:x="My_Report_1" I can use this xslt transformation only for this report. Is there any way to produce a more generic xslt transformation that would work with all such reports, regardless of the value of the namespace-uri? Provide a parameter for the namespace value?

Thanks in advance.

If all your reports are in the same namespace, use the same namespace URI for all your reports. — Tomalak, Sep 06 '20 at 11:20
What determines the namespace used for the source report? Is there a known list of possible namespaces? -- P.S. It looks like you are trying to create a huge generic XSLT that will cover all possible inputs. In most cases, it is much simpler to create (and maintain) an individual XSLT for each type. — michael.hor257k, Sep 06 '20 at 11:57
SSRS export to xml produces tag with namespace xmlns="My_Report_1" - in XSLT has to be exact namespace. This was already described in https://stackoverflow.com/a/26424142/7706781. What I want is to pass some kind of variable or function in XSLT, for example . — Serhii Proskurnin, Sep 06 '20 at 12:27

Dimitre Novatchev · Accepted Answer · 2020-09-07T18:30:51.837

From a comment of the OP:

What I want is to pass some kind of variable or function in XSLT, for example <xsl:stylesheet version="1.0" xmlns:x="{namespace-uri()}">. – Сергей Проскурнин yesterday

One general solution, that even doesn't require to pass the namespace-uri as parameter is this:

Replace in every XPath expression (in the XSLT code)

x:someElementName

with

*[local-name() = 'someElementName']

Doing this on your provided code results in this transformation

Do note that the now unnecessary namespace declaration with prefix x: is removed!

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:output omit-xml-declaration="no" indent="yes" method="xml" />

  <xsl:template match="*[local-name()= 'Report']| *[local-name()= 'Table']| *[local-name()= 'tbl_MainGroup_Collection']">
      <xsl:apply-templates />
  </xsl:template>

  <xsl:template match="*[local-name()= 'Report']/*[local-name()= 'Table']//*[local-name()= 'Data']">
    <Data TxDev="{@TxDev}" DateTime="{@DateTime}" DBVersion="{@DBVersion}" ProductVersion="{@ProductVersion}" Version="{@Version}">
      <xsl:apply-templates select="*[local-name()= 'tbl_SiteGroup_Collection']"/>
    </Data>
  </xsl:template>

  <xsl:template match="*[local-name()= 'tbl_SiteGroup_Collection']">
    <Sites>
      <xsl:apply-templates select="*[local-name()= 'Site']"/>
    </Sites>
  </xsl:template>

  <xsl:template match="*[local-name()= 'Site']">
    <Site SiteNumber="{@SiteNumber}" SiteID="{@SiteID}" SiteName="{@SiteName}">
      <xsl:apply-templates select="*[local-name()= 'tbl_ColumnGroup_Collection']"/>
    </Site>
  </xsl:template>

  <xsl:template match="*[local-name()= 'tbl_ColumnGroup_Collection']">
    <Columns>
      <xsl:apply-templates select="*[local-name()= 'Column']"/>
    </Columns>
  </xsl:template>

  <xsl:template match="*[local-name()='Column']">
    <xsl:for-each select="@*[starts-with(local-name(), 'Column')]">
      <Column ColumnNumber="{translate(local-name(),'Column','')}" ColumnName="{.}">
        <xsl:variable name="attrName" select="local-name()"/>
        <xsl:for-each select="../*[local-name()='Lines']">
          <xsl:call-template name="Lines">
            <xsl:with-param name="ColumnName" select="$attrName"/>
          </xsl:call-template>
        </xsl:for-each>
      </Column>
    </xsl:for-each>
  </xsl:template>

  <xsl:template name="Lines" match="*[local-name()='Lines']">
    <xsl:param name="ColumnName"/>
    <Lines>
      <xsl:for-each select="*[local-name()='Line'][@LineNumber&gt;0 and @EntityType=0]">
        <xsl:sort select="@LineNumber" data-type="number" />
        <xsl:call-template name="Line">
          <xsl:with-param name="ColumnName" select="$ColumnName"/>
        </xsl:call-template>
      </xsl:for-each>
    </Lines>
  </xsl:template>

  <xsl:template name="Line" match="*[local-name()='Line']">
    <xsl:param name="ColumnName"/>
    <Line LineNumber="{@LineNumber}" LineName="{@LineName}" >
      <xsl:variable name="LineNo" select="@LineNumber"/>
      <xsl:choose>
        <xsl:when test="count(../*[local-name()='Line'][@LineNumber=$LineNo and @EntityType=1])>0">
          <xsl:attribute name="Value">
            <xsl:value-of select="@*[local-name()=$ColumnName]"/>
          </xsl:attribute>
          <Departments>
            <xsl:for-each select="../*[local-name()='Line'][@LineNumber=$LineNo and @EntityType=1]">
              <xsl:sort select="@EntityNo" data-type="number"/>
              <Department DepNumber="{@EntityNo}" DepName="{@LineName}" Value="{@*[local-name()=$ColumnName]}">
              </Department>
            </xsl:for-each>
          </Departments>
        </xsl:when>
        <xsl:when test="count(../*[local-name()='Line'][@LineNumber=$LineNo and @EntityType=2])>0">
          <xsl:if test="@*[local-name()=$ColumnName]">
            <xsl:attribute name="Value">
              <xsl:value-of select="@*[local-name()=$ColumnName]"/>
            </xsl:attribute>
          </xsl:if>
          <MOPs>
            <xsl:for-each select="../*[local-name()='Line'][@LineNumber=$LineNo and @EntityType=2]">
              <xsl:sort select="@EntityNo" data-type="number"/>
              <MOP MOPNumber="{@EntityNo}" MOPName="{@LineName}" Value="{@*[local-name()=$ColumnName]}">
              </MOP>
            </xsl:for-each>
          </MOPs>
        </xsl:when>
        <xsl:otherwise>
          <xsl:attribute name="Value">
            <xsl:value-of select="@*[local-name()=$ColumnName]"/>
          </xsl:attribute>
        </xsl:otherwise>
      </xsl:choose>
    </Line>
  </xsl:template>

  <xsl:template match="/">
    <xsl:apply-templates />
  </xsl:template>

</xsl:stylesheet>

and applying this transformation on the provided source XML document produces exactly the same output as the original transformation.

Warning: This solution is correct only if it is guaranteed that the local element names that are referenced are not used with more that one (different) namespace.

Just what I wanted) Thank you, @Dimitre! – Serhii Proskurnin Sep 08 '20 at 08:45 — Serhii Proskurnin, Sep 08 '20 at 08:45

Unified xslt for multiple SSRS reports (xml export)

1 Answers1