Changing AppName and AppDir depending on language in Inno Setup

Question

It's been a while since I was reading some questions/answers concerning InnoSetup, but none of them seems to help me... I want to change the AppName value depending on the language selected, being available English and Spanish. So, if the language chosen when prompted the dialog were Spanish, the AppName value should be "La Bola"; otherwise, if chosen English, the AppName value should be "The Ball".

The same thing applied to the AppDir. The only thing I've found so far was this Inno setup and DefaultDirName, but I cannot make it work with the Languages. Also tried using ISPP conditionals following an example:

#ifdef AppEnterprise
  #define AppName "My Program Enterprise Edition"
#else
  #define AppName "My Program"
#endif

but yet I cannot make it work with the Language, since I don't know how.

Is it possible to change it? =/

Greetings!

score 3 · Answer 1 · answered Jul 30 '13 at 12:46

I had the same question, so I'm posting an answer that would allow others to get it faster.

Actually, there is an example in Examples\Languages.iss file in Inno Setup installation folder.

To be short:

[Setup]
AppName={cm:MyAppName}

then

[Languages]
Name: en; MessagesFile: "compiler:Default.isl"
Name: es; MessagesFile: "compiler:Languages\Spanish.isl"

then

[CustomMessages]
en.MyAppName=The Ball
es.MyAppName=La Bola

That's it. For more details, see the example. By the way, note that there is a LicenseFile language attribute available (this is not mentioned in the example):

[Languages]
Name: en; MessagesFile: "compiler:Default.isl"; LicenseFile: "eula_en.rtf"
Name: es; MessagesFile: "compiler:Languages\Spanish.isl"; LicenseFile: "eula_es.rtf"

Deanna · Answer 2 · 2016-03-08T09:24:27.767

1

Look at CustomMessages which can be translated into different languages, These can then be used in AppName and DefaultDirName with the {cm:..} constant.

edited Mar 08 '16 at 09:24

answered Jun 20 '11 at 09:07

Deanna

23,876
7
71
156

Since I don't do multiple languages, I missed that feature of the `[CustomMessages]` I wonder how it handles the resource in setup.exe – Robert Love Jun 20 '11 at 13:20
I'm not sure either, I left that as an excercise for the reader :) – Deanna Jun 21 '11 at 08:54
@RobertLove For resource in "setup.exe" [the `VersionInfoDescription`](http://www.jrsoftware.org/ishelp/index.php?topic=setup_versioninfodescription) is used. It defaults to the `AppName`, only when the `AppName` does not include any constants. If there are constants in the `AppName` and the `VersionInfoDescription` is not defined, a compile-time warning is issued and the resource stays empty. – Martin Prikryl Mar 08 '16 at 08:27

score 0 · Answer 3 · answered Jun 19 '11 at 10:40

ISPP is a Pre-Processor, so this means this code run's prior to compiling the SETUP.EXE

The AppName is used for a variety of purposes but one is the SETUP.EXE Resource. Which is why it can't be set at runtime using {code: }

So you could a compile time and have a different SETUP.EXE for each language.

You can do this in a number of ways, using the ISPP, here is one.

#define lang = "english"
[Setup]
#if lang == "english"
AppName=The Ball
#elif lang == "spanish"
AppName=La Bola
#else
# error Unsupported Language
#endif

AppVersion=1.5
;AppVerName=My Program 1.5
DefaultDirName={pf}\My Program

[Languages]
#if lang == "english"
Name: "en"; MessagesFile: "compiler:Default.isl"
#elif lang == "spanish"
Name: "spanish"; MessagesFile: "compiler:Languages\Spanish.isl"
#else
# error Unsupported Language
#endif


[Files]
Source: "C:\Program Files (x86)\Inno Setup 5\Examples\MyProg.exe"; DestDir: "{app}"; Flags: ignoreversion

Changing AppName and AppDir depending on language in Inno Setup

3 Answers3

Linked