Way to find CMD window size from batch (*.bat) and maybe buffer size?

Question

I would like to make a *.bat file which can act differently according to the window size of the CMD.

I searched for a way to find the window size which is mostly the same but some times when people customize the settings its not the same. Normally the window size is 80 characters width and 25 lines height. But some apply their own custom settings so it could be any thing else.

Is there a way from inside of a *.bat to find the actual window size? I would like to keep it as much *.bat as possible ... with other words not PowerShell or vbs and so on and the best would also be without *.tmp files.

This would interest me the most. But also interesting would be a way to find the buffer size of a running *.bat in it self.

Is there any way or idea to get this information from inside of a *bat?

Alternative may would be to adjust the window size or buffer size from a *.bat file it self. So if I can't get the actual window or buffer size is it possible to set a window or buffer size in a running *.bat while it is processed?

Does any one have a trick or even idea on how to get or set this information from inside of a running *.bat?

Until now I have no idea if it is possible and how? so I could not try much that I could show now.

UPDATE:

REM Empty Variables
set "ROWS="
set "CHARACTERS="
REM Read CMD Window Size in Rows and Characters per Row.
for /F "tokens=3" %%A in ('reg query HKCU\Console /v WindowSize') do set /A ROWS=%%A/65535
for /F "tokens=3" %%A in ('reg query HKCU\Console /v WindowSize') do set /A "CHARACTERS=%%A&0xffff
REM Test it ...
echo %ROWS%
echo %CHARACTERS%

This will read the rows and characters per line from the registry. its a shortened form from https://superuser.com/questions/1330772/cmd-window-size

SomethingDark · Accepted Answer · 2020-09-29T23:49:49.847

1

Both lines and columns (height and width, respectively) are found in the output of the mode con command. Screen buffer size, unfortunately, is found in the registry and gets stored after being multiplied by 65535 for some reason.

@echo off
for /f "tokens=2" %%A in ('mode con ^| find "Lines"') do set "window_height=%%A"
for /f "tokens=2" %%A in ('mode con ^| find "Columns"') do set "window_width=%%A"
for /f "tokens=3" %%A in ('reg query HKCU\Console /v ScreenBufferSize') do set /a window_buffer=%%A/65535

echo Window is %window_width%x%window_height% with a buffer of %window_buffer%

If Lines shows the incorrect value for the window height, you might be able to use the WindowSize registry value of HKCU\Console:

for /f "tokens=3" %%A in ('reg query HKCU\Console /v WindowSize') do set /a window_height=%%A/65535

It is important to note that this is just the default height of the console and not the current height, but if the height was changed with mode con, then the buffer size will be overwritten and the first way will work.

edited Sep 29 '20 at 23:49

answered Sep 29 '20 at 22:32

SomethingDark

13,229
5
50
55

looks surprising ... the output i get is "Window is x with a buffer of 300" ... 300 is in fact the buffer size ... but before and after "x" some thing is missing ... maybe because of windows 7? .. "more con" does say "buffer 300, cols 80, refresh 31, delay 1, codepage 850" .. nothing about lines ... but the registry trick looks interesting ... there is a value "CursorSize" and it is "25" this may could be the lines because i actuali count 25 lines... thanks so far.. – Mugolumbu Sep 29 '20 at 23:19
@Mugolumbu - I can't replicate your problem in my Windows 7 VM. The only thing I can think is that your `mode con` isn't in English and so you need to change "Lines" and "Columns" to whatever the first and second lines of `mode con` report as on your machine. – SomethingDark Sep 29 '20 at 23:25
Absolutely right .. it was not english ... this is a important hint... now i get "Window is 80x300 with a buffer of 300" .... and what i would need is "Window is 80x25 with a buffer of 300" ... so far its all very interesting... just some thing with the windows height ist not correct ... i count manually 25 lines which i see in the window ... and if i scroll up and down 300 lines seem to be what i see ... but the window it self is 25 lines ... any idea how to get this number? – Mugolumbu Sep 29 '20 at 23:37
@Mugolumbu - I've added an alternate way to get the window height in my answer. Please see if it works for you. – SomethingDark Sep 29 '20 at 23:50
Perfect ... the magic number 25 is popping up ... it works ... thanks a lot :D now i get some how every thing from window width to height to buffer length ... and we have all info in the comments... even the very good hint with cmd outputs in different languages ... great i decide your answer to be the best ;) .. ohh sadly i have not enough points to vote you up ... but i did click you up – Mugolumbu Sep 30 '20 at 00:09

score 1 · Answer 2 · answered Sep 30 '20 at 12:57

You can use mode con to get the buffer size in terms of characters:

for /F "tokens=1* delims=: " %%I in ('
    mode con ^| findstr "Lines Columns"
') do set "%%I=%%J"
echo Lines=%Lines%
echo Columns=%Columns%

Note that such mode con approaches are locale-dependent!

To avoid that, you could use this:

rem // Ensure variables are empty:
set "Lines=" & set "Columns="
rem /* Skip over header lines and use `:` as the only delimiter, because
rem    keywords may contain spaces on their own in other languages: */
for /F "skip=2 tokens=1* delims=:" %%I in ('mode con') do (
    rem // Remove surrounding spaces from extracted value:
    for /F %%K in ("%%J") do (
        if not defined Lines (
            rem // First value after header line is supposed to be lines:
            set "Lines=%%K"
        ) else if not defined Columns (
            rem // Second value after header line is supposed to be columns:
            set "Columns=%%K"
        )
    )
)
echo Lines=%Lines%
echo Columns=%Columns%

For the actual window size refer to SomethingDark's answer (for how to use reg query).

Compo · Answer 3 · 2020-09-30T13:37:09.997

Just for the sake of it, a batch-file or cmd could leverage powershell for this:

"%__AppDir__%WindowsPowerShell\v1.0\powershell.exe" -NoP "$HW=(Get-Host).UI.RawUI;'Window size = '+$HW.WindowSize;'Buffer size = '+$HW.BufferSize"

This should provide an output similar to the following, (where the first number is the Width and the second the Height):

Window size = 80,30
Buffer size = 80,120

Obviously you could adjust the output to your specific requirements, e.g.

"%__AppDir__%WindowsPowerShell\v1.0\powershell.exe" -NoP "$HW=(Get-Host).UI.RawUI;'WinWxH='+$HW.WindowSize -Replace ',','x';'BufWxH='+$HW.BufferSize -Replace ',','x'"

Example output:

WinWxH=80x30
BufWxH=80x120

That would mean if you wanted those values as variables, in your batch-file, you could run the command within a for-loop and save the output with Set:

@For /F Delims^= %%G In ('PowerShell -NoP "$HW=(Get-Host).UI.RawUI;'WinWxH='+$HW.WindowSize -Replace ',','x';'BufWxH='+$HW.BufferSize -Replace ',','x'"')Do @Set "%%G"

Your variables in this case would be %WinWxH% with a defined value of 80x30, and %BufWxH% with a defined value of 80x120.

Way to find CMD window size from batch (*.bat) and maybe buffer size?

3 Answers3

Linked