Do a cmd command in a msgbox

Question

So, my goal is that I want to get a msgbox that tells me what power plan I'm on without using the command prompt.

I've tried making a batch file but that only does the command.

start cmd /k powercfg/getactivescheme

When I try doing it from the command prompt it just outputs the text of the command in the msg box not the actual output.

msg %username% powerconfg/getactivescheme

Thanks in advance

[get the output of your command into a variable](https://stackoverflow.com/a/44880852/2152082). The rest should be trivial. — Stephan, Oct 18 '20 at 07:44

score 1 · Accepted Answer · answered Oct 18 '20 at 07:44

Try like this (Use for to get your command output in a variable):

@echo off
for /f "tokens=* delims= " %%a in ('powercfg /getactivescheme') do msg * %%a

A better example using VBScript MsgBox, which can have custom title and icons:

@echo off
for /f "tokens=* delims= " %%a in ('powercfg /getactivescheme') do set "body=%%a"
echo MsgBox "%body%",64,"YOUR TITLE" >temp.vbs
cscript //nologo temp.vbs
del temp.vbs

Learn more on VBScript MsgBox

Hackoo · Answer 2 · 2020-10-18T08:59:29.737

You can give a try for this batch file too :

@echo off
Set Title="command in a msgbox"
Title %Title%
@for /f "delims=" %%a in ('powercfg /getactivescheme') do (Set "MSG=%%a")
>"%temp%\%~n0.vbs" ( echo MsgBox "%MSG%",vbInformation,%Title% )
 wscript "%temp%\%~n0.vbs" & Del "%temp%\%~n0.vbs"

EDIT : If You want to extract Data between two parenthesis ( Data Info....) You can use a vbscript dealing with Regex like this one :

For example in my test with french machine ( Utilisation Normale )

@echo off
Set Title="command in a msgbox"
Title %Title%
@for /f "delims=" %%a in ('powercfg /getactivescheme') do (Set "MSG=%%a")
Call :ExtractData "%MSG%" MSG
>"%temp%\%~n0.vbs" ( echo MsgBox "%MSG%",vbInformation,%Title% )
Wscript.exe "%temp%\%~n0.vbs" & Del "%temp%\%~n0.vbs"
Exit
REM------------------------------------------------------------------------
:ExtractData
(
    echo wscript.echo Extract("%~1"^)
    echo Function Extract(Data^)
    echo Dim strPattern,oRegExp,Matches
    echo strPattern = "(?:\()(.*)(?:\))"
    echo Set oRegExp = New RegExp
    echo oRegExp.IgnoreCase = True 
    echo oRegExp.Pattern = strPattern
    echo set Matches = oRegExp.Execute(Data^) 
    echo If Matches.Count ^> 0 Then Extract = Matches(0^).SubMatches(0^)
    echo End Function
)>"%tmp%\%~n0.vbs"
@for /f "delims=" %%a in ('cscript //nologo "%tmp%\%~n0.vbs"') do ( set "%2=%%a")
If Exist "%tmp%\%~n0.vbs" Del "%tmp%\%~n0.vbs"
Exit /B
REM------------------------------------------------------------------------

Do a cmd command in a msgbox

2 Answers2