Unable to close file handle in Perl

Question

I am new to Perl as I was trying to create a text file in a sub-directory named as data inside a directory named as a test, I have tried to write the following code, the code is as follows:-

#!/usr/bin/perl
use strict;
use warnings;
use Cwd qw(abs_path);
use File::Path qw(make_path remove_tree);
my $path = abs_path();
my @file = open(my $fh, '>>', '$path/test/data') or die "unable to create text file $!";
print $fh;
close $fh or die "unable to close file $fh $!\n";

It gave me the following error:-

unable to close file GLOB(0x1d5ea68) Bad file descriptor

Please it would be really helpful and appreciated if you can explain what is happening here? and how can it be solved? Thanks in advance.

Answer 1

open failed, so $fh doesn't contain a valid file handle, and this is causing close to fail.

---

open is returning an error, but you aren't being notified about it because your check is incorrect. Because open always returns a value, the list assignment always returns 1, so the die could never be evaluated. (See Scalar vs List Assignment Operator if you want more details.)

Replace

my @file = open(...)
    or die "unable to create text file $!";

with

open(...)
    or die "unable to create text file $!";

---

As for why open is failing, the reason is surely that the path $path/test/data doesn't exist. You are literally looking for a directory named $path because single-quoted string literals don't interpolate.

Replace

'$path/test/data'

with

"$path/test/data"

or simply

'test/data'

since $path just contains the current directory.

Answer 2

Not really an answer to your question, but I like to use the Path::Tiny module for file I/O. It's much easier to use than raw open calls, and you don't have to hunt for separate modules for most tasks.

#!/usr/bin/perl
use strict;
use warnings;
use Path::Tiny qw(path cwd);    # methods mkpath and remove_tree are available

my $file = cwd->child('test', 'data');
my $fh = $file->opena;  # dies on failure
print $fh;
close $fh or die "unable to close file $fh $!\n";

# But even easier to not bother with open/close and just do something like:
$file->append('...');

Answer 3

What that error is saying is that $fh is not an open file handle. The GLOB... part of the error message is the stringification of the file handle. Most likely $path/test/ doesn't exist so $fh is never opened. Open will not create directory components, only files. Check for it with -e first and create it with mkdir or make_path if necessary.

Your open or die clause doesn't work because you are capturing the open output into an array and that is what is evaluated by or.

I commend you for learning Perl to accomplish your task. Here is what you should be reading to solve these problems and continue on your path.

https://perldoc.pl/perl https://perldoc.pl/functions/open https://perldoc.pl/functions

HTH