Batch countdown but WITH showing countdown

Question

I do know it can Batch timeout 30 etc but how to do showing countdown for

I saw here: http://www.trytoprogram.com/batch-file/shutdown-commands/ BOTTOM Page "Batch file program to shutdown, reboot, hibernate, and logoff the computer"

/t 0 is no good ever i did do /t 30 it not showing countdown

Any idea how to show the countdown like the: timeout 30 29 28 27 etc

Answer 1

A timer can be effected by using a for /L loop for the number of seconds, and a for /F loop executing a choice command with a /T 1 Delay with a /D default that performs no action.

Other options can be built into the For /F Choice loop to allow Cancellation of the shutdown, resetting of the countdown, or immediate shutdown:

 @Echo off
:Reset
 For /L %%i in (30 -1 1)Do (
  Cls
  Echo Shutting down in : %%i Seconds [C]ancel [S]hutdown Now [R]eset Timer
  For /F "Delims=" %%G in ('Choice /T 1 /N /C:CSRW /D W')Do (
   If %%G==R Goto :Reset
   If %%G==C Goto :Eof
   If %%G==S Shutdown /SG /T 0
  )
 )
 Shutdown /SG /T 1

EDIT:

Example of modifying the above for use as a function called from a menu.

@Echo off
:Menu
 Echo [E]xit [L]ogoff [R]estart [S]hutdown
 For /F "Delims=" %%G in ('Choice /N /C:SRLE')Do (
  If %%G==S Call :Timer "Shutdown /SG /T 1" "Shutting Down"
  If %%G==R Call :Timer "Shutdown /R /T 1" "Restarting"
  If %%G==L Call :Timer "Shutdown /L" "Logging Off"
  If %%G==E Exit /B
 )
:# On Cancel Command Selection:
Goto :Menu
:# Function With timer
:Timer [Command] [Prompt]
 For /L %%i in (30 -1 1)Do (
  Cls
  Echo %~2 in : %%i Seconds [C]ancel [R]estart Timer [N]o wait
  For /F "Delims=" %%G in ('Choice /T 1 /N /C:CRNW /D W')Do (
   If %%G==R Goto :Timer
   If %%G==C Goto :Eof
   If %%G==N %~1
  )
 )
 %~1

Answer 2

PsShutdown

You could use Mark Rusinovich's psshutdown which does exactly what you want:

• initiates shutdown after specified amount of time
• displays countdown
• allows user to cancel with a cancel button

It is free to use.

Commandline: psshutdown -k -f -t 30 -c

• -k shuts down the computer (ACPI power off)
• -f forces programs to terminate if necessary
• -t 30 introduces a delay of 30 seconds before shutdown
• -c allows user to cancel shutdown with Cancel button

( Screenshot from superuser.com )

Choice

Another option would be to call choice /t 1 multiple times:

@echo off

set /a "t=30"
:loop
set /a "t-=1"
if "%t%" == "0" goto timedout
cls
choice /T 1 /C sc /N /D s /M "Shutdown in %t% seconds, press c to cancel: "
if not "%errorlevel%" == "1" goto cancelled 
goto loop

:cancelled
echo You cancelled shutdown
pause
goto :eof

:timedout
echo Shutting down
shutdown /s /f /t 1
pause
goto :eof

• set /a "t=30" sets variable t to 30
• set /a "t-=1" substracts 1 from t
• if "%t%" == "0" goto timedout initiates shutdown when t reaches zero
• cls clears previous text from screen
• choice is timeout that knows if it was cancelled but without printing time
  • /T 1 - timeout in 1 second (to update the message)
  • /C sc - choice 1 is s, choice 2 is c
  • /N - don't display [s,c] in the end
  • /D s - default option on 1-second-timeout is s
  • /M "Shutdown in %t% ..." - display message with current value of variable t

Please note that shutdown /s /f /t NNN may not behave the same as shutdown /s /f without time, so I included /t 1 just in case.

Shutdown /a

It may be advantageous to actually initiate shutdown before the countdown, but allow the user to abort it:

• Do the countdown as described in previous section ("Choice").

  • You could get away with just plain timeout command with a few more seconds in hopes that the batch script is aborted by shutdown before the time runs out but it would be very confusing and unreliable, so this is not recommended

• Before beginning the countdown (:loop) start the shutdown like this: shutdown /s /f /t 30

• If timed out, do nothing (remove shutdown /s /f /t 1 after timedout:)

• If user cancelled (right after :cancelled), abort it with: shutdown /a