How can I use Excel to interact with MySQL and show result of an SQL query in a cell, after I enter SQL table id in another cell?

Question

I am trying to figure out how to use Excel as an interactive front end to MySQL. It will be my first VBA experience with a database.

My scenario is I want to enter an order number into one cell, and upon completing the input, I want an SQL query to be ran, like SELECT field1, field2 FROM table WHERE order_number = ?, and then display the return result of field1 in a cell. I may use field2 in other cells.

I see there is some code here that may be useful, but I don't know where to enter that code, and how to make that code work after I enter an order number into the cell. I have already made an ODBC Driver connection to where I am able to connect to a database using Excel Database functions. I don't yet know how to use VBA do make a database connection or run interactive queries.

Can you help get me to the point where I can enter an order number in one cell, and see field1 show up in another cell, where field1 will be a value from an SQL query, like the above?

I have never done that myself. But maybe the following link will help you as a first approach: https://www.connectionstrings.com/ — Zwenn, Mar 19 '21 at 14:55
https://stackoverflow.com/questions/4305436/excel-vba-query-a-mysql-database/33532376 — Tim Williams, Mar 19 '21 at 16:32

score 1 · Accepted Answer · answered Mar 19 '21 at 17:40

Put code on worksheet where you enter the order number. This uses a DSN created using ODBC Data Source Administrator.

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    
    Dim ar As Variant
    If Target.Address = "$B$2" Then
        ar = GetOrder(Target.Value)
        Range("B4") = ar(0)
        Range("B5") = ar(1)
    End If

End Sub

Function GetOrder(OrderNo As Long) As Variant

    Const CONN = "DSN=***;UID=***;PWD=***;"
 
    Const SQL = " SELECT Field1,Field2" & _
                " FROM table1 " & _
                " WHERE OrderNo = ?"
  
    Dim dbConn As ADODB.Connection, dbCmd As ADODB.Command
    Dim rs As ADODB.Recordset
    Dim param As ADODB.Parameter, n As Long

    Set dbConn = New ADODB.Connection
    dbConn.Open CONN

    Set dbCmd = New ADODB.Command
    With dbCmd
        .ActiveConnection = dbConn
        .CommandType = adCmdText
        .CommandText = SQL
        Set param = .CreateParameter("P1", adInteger, adParamInput, 0)
        .Parameters.Append param
    End With
    
    Set rs = dbCmd.Execute(n, OrderNo)
    If Not rs.EOF Then
       GetOrder = Array(rs(0).Value, rs(1).Value)
    Else
       GetOrder = Array("#N/A", "#N/A")
       MsgBox "Could not find " & OrderNo, vbExclamation, "Error"
    End If
   
    dbConn.Close

End Function

Thanks! How would I add multiple items to the list? I'm having trouble figuring that out. I was able to populate `GetOrder` by using `GetOrder = rs.GetRows`, but having trouble figuring out how to populate the list. Do I use a For loop or is there a better way? — Dennis, Mar 22 '21 at 22:27
@dennis What do you mean, which list ? If you want the results on a sheet there is the [copyfromrecordset method](https://learn.microsoft.com/en-us/office/vba/api/excel.range.copyfromrecordset) — CDP1802, Mar 22 '21 at 23:06
oh I apologize! I mixed your answer up with another answer. I am trying to populate a `ComboBox` (a drop-down list) with results received from `rs` — Dennis, Mar 23 '21 at 00:22
@dennis If it's a single field then `Me.ComboBox1.List = Application.Transpose(rs.GetRows)` — CDP1802, Mar 23 '21 at 12:06

How can I use Excel to interact with MySQL and show result of an SQL query in a cell, after I enter SQL table id in another cell?

1 Answers1