Combinations with pairs

Question

I am trying to combine a list of pairs in scheme to get all possible combinations. For example:

((1 2) (3 4) (5 6)) --> ((1 3 5) (1 3 6) (1 4 5) (1 4 6) (2 3 5) (2 3 6) (2 4 5) (2 4 6))

I've been able to solve it (I think) using a "take the first and prepend it to the cdr of the procedure" with the following:

(define (combine-pair-with-list-of-pairs P Lp)
  (apply append
         (map (lambda (num)
                (map (lambda (pair)
                       (cons num pair)) Lp)) P)))

(define (comb-N Lp)
  (if (null? Lp)
      '(())
      (combine-pair-with-list-of-pairs (car Lp) (comb-N (cdr Lp)))))

(comb-N '((1 2)(3 4)(5 6)))
; ((1 3 5) (1 3 6) (1 4 5) (1 4 6) (2 3 5) (2 3 6) (2 4 5) (2 4 6))

However, I've been having trouble figuring out how I can use a procedure that only takes two and having a wrapper around it to be able to define comb-N by calling that function. Here it is:

(define (combinations L1 L2)
  (apply append
         (map (lambda (L1_item)
                (map (lambda (L2_item)
                       (list L1_item L2_item))
                     L2))
              L1)))
(combinations '(1) '(1 2 3))
; ((1 1) (1 2) (1 3))

I suppose the difficulty with calling this function is it expects two lists, and the recursive call is expecting a list of lists as the second argument. How could I call this combinations function to define comb-N?

Answer 1

difficulty? recursion? where?

You can write combinations using delimited continuations. Here we represent an ambiguous computation by writing amb. The expression bounded by reset will run once for each argument supplied to amb -

(define (amb . lst)
  (shift k (append-map k lst)))

(reset
  (list (list (amb 'a 'b) (amb 1 2 3))))

((a 1) (a 2) (a 3) (b 1) (b 2) (b 3))

how it works

The expression is evaluated through the first amb where the continuation is captured to k -

k := (list (list ... (amb 1 2 3)))

Where applying k will supply its argument to the "hole" left by amb's call to shift, represented by ... above. We can effectively think of k in terms of a lambda -

k := (lambda (x) (list (list x (amb 1 2 3)))

amb returns an append-map expression -

(append-map k '(a b))

Where append-map will apply k to each element of the input list, '(a b), and append the results. This effectively translates to -

(append
 (k 'a)
 (k 'b))

Next expand the continuation, k, in place -

(append
 (list (list 'a (amb 1 2 3)))  ; <-
 (list (list 'b (amb 1 2 3)))) ; <-

Continuing with the evaluation, we evaluate the next amb. The pattern is continued. amb's call to shift captures the current continuation to k, but this time the continuation has evolved a bit -

k := (list (list 'a ...))

Again, we can think of k in terms of lambda -

k := (lambda (x) (list (list 'a x)))

And amb returns an append-map expression -

(append
 (append-map k '(1 2 3)) ; <-
 (list (list 'b ...)))

We can continue working like this to resolve the entire computation. append-map applies k to each element of the input and appends the results, effectively translating to -

(append
 (append (k 1) (k 2) (k 3)) ; <-
 (list (list 'b ...)))

Expand the k in place -

(append
  (append
     (list (list 'a 1))  ; <-
     (list (list 'a 2))  ; <-
     (list (list 'a 3))) ; <-
  (list (list 'b (amb 1 2 3))))

We can really start to see where this is going now. We can simplify the above expression to -

(append
 '((a 1) (a 2) (a 3)) ; <-
 (list (list 'b (amb 1 2 3))))

Evaluation now continues to the final amb expression. We will follow the pattern one more time. Here amb's call to shift captures the current continuation as k -

k := (list (list 'b ...))

In lambda terms, we think of k as -

k := (lambda (x) (list (list 'b x)))

amb returns an append-map expression -

(append
 '((a 1) (a 2) (a 3))
 (append-map k '(1 2 3))) ; <-

append-map applies k to each element and appends the results. This translates to -

(append
 '((a 1) (a 2) (a 3))
 (append (k 1) (k 2) (k 3))) ; <-

Expand k in place -

(append
 '((a 1) (a 2) (a 3))
 (append
  (list (list 'b 1))   ; <-
  (list (list 'b 2))   ; <-
  (list (list 'b 3)))) ; <-

This simplifies to -

(append
 '((a 1) (a 2) (a 3))
 '((b 1) (b 2) (b 3))) ; <-

And finally we can compute the outermost append, producing the output -

((a 1) (a 2) (a 3) (b 1) (b 2) (b 3))

generalizing a procedure

Above we used fixed inputs, '(a b) and '(1 2 3). We could make a generic combinations procedure which applies amb to its input arguments -

(define (combinations a b)
  (reset
   (list (list (apply amb a) (apply amb b)))))

(combinations '(a b) '(1 2 3))

((a 1) (a 2) (a 3) (b 1) (b 2) (b 3))

Now we can easily expand this idea to accept any number of input lists. We write a variadic combinations procedure by taking a list of lists and map over it, applying amb to each -

(define (combinations . lsts)
  (reset
     (list (map (lambda (each) (apply amb each)) lsts))))

(combinations '(1 2) '(3 4) '(5 6))

((1 3 5) (1 3 6) (1 4 5) (1 4 6) (2 3 5) (2 3 6) (2 4 5) (2 4 6))

Any number of lists of any length can be used -

(combinations
  '(common rare)
  '(air ground)
  '(electric ice bug)
  '(monster))

((common air electric monster)
 (common air ice monster)
 (common air bug monster)
 (common ground electric monster)
 (common ground ice monster)
 (common ground bug monster)
 (rare air electric monster)
 (rare air ice monster)
 (rare air bug monster)
 (rare ground electric monster)
 (rare ground ice monster)
 (rare ground bug monster))

related reading

In Scheme, we can use Olivier Danvy's original implementation of shift/reset. In Racket, they are supplied via racket/control

(define-syntax reset
  (syntax-rules ()
    ((_ ?e) (reset-thunk (lambda () ?e)))))

(define-syntax shift
  (syntax-rules ()
    ((_ ?k ?e) (call/ct (lambda (?k) ?e)))))

(define *meta-continuation*
  (lambda (v)
    (error "You forgot the top-level reset...")))

(define abort
  (lambda (v)
    (*meta-continuation* v)))

(define reset-thunk
  (lambda (t)
    (let ((mc *meta-continuation*))
      (call-with-current-continuation
        (lambda (k)
      (begin
        (set! *meta-continuation* (lambda (v)
                    (begin
                      (set! *meta-continuation* mc)
                      (k v))))
        (abort (t))))))))

(define call/ct
  (lambda (f)
    (call-with-current-continuation
      (lambda (k)
    (abort (f (lambda (v)
            (reset (k v)))))))))

For more insight on the use of append-map and amb, see this answer to your another one of your questions.

See also the Compoasable Continuations Tutorial on the Scheme Wiki.

remarks

I really struggled with functional style at first. I cut my teeth on imperative style and it took me some time to see recursion as the "natural" way of thinking to solve problems in a functional way. However I offer this post in hopes to provoke you to reach for even higher orders of thinking and reasoning. Recursion is the topic I write about most on this site but I'm here saying that sometimes even more creative, imaginative, declarative ways exist to express your programs.

First-class continuations can turn your program inside-out, allowing you to write a program which manipulates, consumes, and multiplies itself. It's a sophisticated level of control that's part of the Scheme spec but only fully supported in a few other languages. Like recursion, continuations are a tough nut to crack, but once you "see", you wish you would've learned them earlier.

Answer 2

As suggested in the comments you can use recursion, specifically, right fold:

(define (flatmap foo xs)
  (apply append
    (map foo xs)))

(define (flatmapOn xs foo)
  (flatmap foo xs))

(define (mapOn xs foo)
  (map foo xs))

(define (combs L1 L2)  ; your "combinations", shorter name
  (flatmapOn L1 (lambda (L1_item)
     (mapOn L2   (lambda (L2_item)        ; changed this:
             (cons L1_item L2_item))))))  ;   cons     NB!

(display
 (combs '(1 2)
   (combs '(3 4)
     (combs '(5 6) '( () )))))

; returns:
; ((1 3 5) (1 3 6) (1 4 5) (1 4 6) (2 3 5) (2 3 6) (2 4 5) (2 4 6))

So you see, the list that you used there wasn't quite right, I changed it back to cons (and thus it becomes fully the same as combine-pair-with-list-of-pairs). That way it becomes extensible: (list 3 (list 2 1)) isn't nice but (cons 3 (cons 2 (cons 1 '()))) is nicer.

With list it can't be used as you wished: such function receives lists of elements, and produces lists of lists of elements. This kind of output can't be used as the expected kind of input in another invocation of that function -- it would produce different kind of results. To build many by combining only two each time, that combination must produce the same kind of output as the two inputs. It's like +, with numbers. So either stay with the cons, or change the combination function completely.

As to my remark about right fold: that's the structure of the nested calls to combs in my example above. It can be used to define this function as

(define (sequence lists)
  (foldr
     (lambda (list r)   ; r is the recursive result
        (combs list r))
     '(())              ; using `()` as the base
     lists))

Yes, the proper name of this function is sequence (well, it's the one used in Haskell).