How to create a radial plot using gnuplot?

Question

Possible Duplicate:
How to get a radial(polar) plot using gnu plot?

I want a radial(polar) plot using gnuplot(i.e in circular co-ordinate system(r,theta):!

Here I have used the values:

How to get such a plot using gnu-plot? If I take positive values say 3400,5300,4700 etc....I must be able to plot them in the same plot in such a way that it is not confusing. Is there a gnu-plot command to directly mention radius and theta instead of x and y co-ordinates to get such a radial plot?

Thanks in advance

Answer 1

Possible duplicate: here

The only way I can think of is to use

set ytics ("-1000" 1000, "-2000" 2000, "-3000" 3000, "-4000" 4000, "-5000" 5000, "-6000" 6000)

So instead of the answer of this question use this script (only this time without the comments):

unset border
set polar
set angles degrees

set style line 10 lt 1 lc 0 lw 0.3

set grid polar 60
set grid ls 10

set xrange [-6000:6000]
set yrange [-6000:6000]

set xtics axis
set ytics axis

set xtics scale 0
set xtics ("" 1000, "" 2000, "" 3000, "" 4000, "" 5000, "" 6000)
set ytics ("-1000" 1000, "-2000" 2000, "-3000" 3000, "-4000" 4000, "-5000" 5000,     "-6000" 6000)

set size square

set key lmargin

set_label(x, text) = sprintf("set label '%s' at (6500*cos(%f)), (6500*sin(%f))             center", text, x, x)

eval set_label(0, "0")
eval set_label(60, "60")
eval set_label(120, "120")
eval set_label(180, "180")
eval set_label(240, "240")
eval set_label(300, "300")

set style line 11 lt 1 lw 2 pt 2 ps 2

plot "-" u 1:(-1*$2) t "Max strain" w lp ls 11
0 -3400
60 -5300
120 -4700
180 -3800
240 -4100
300 -3100
360 -3400
e