Delphi dbgrid continuous scrolling

Question

I'm making an application that holds orders and prints invoices. I have some labels, tedits, tmemos, buttons, a datasource, an adotable, a popupmenu, and a dbgrid on my form.

When I build the program and scroll down the dbgrid scrollbar, it scrolls after I release mouse button. But i want continuous scrolling.

Greetings

Isn't that the nature of data aware controls? – David Heffernan Aug 02 '11 at 21:35 — David Heffernan, Aug 02 '11 at 21:35

score 12 · Accepted Answer · edited May 23 '17 at 12:01

12

That's called thumb tracking. Derive a new class to override scrolling behavior. Example of using an interposer class:

type
  TDBGrid = class(DBGrids.TDBGrid)
  private
    procedure WmVScroll(var Message: TWMVScroll); message WM_VSCROLL;
  end;

  TForm1 = class(TForm)
    DBGrid1: TDBGrid;
    ..

implementation

procedure TDBGrid.WmVScroll(var Message: TWMVScroll);
begin
  if Message.ScrollCode = SB_THUMBTRACK then
    Message.ScrollCode := SB_THUMBPOSITION;
  inherited;
end;

You can also replace the WindowProc of the control if you don't want to derive a new class. All you need to do is to handle WM_VSCROLL message. Here is an example how to do that.

edited May 23 '17 at 12:01

Community

1
1

answered Aug 02 '11 at 21:48

Sertac Akyuz

54,131
4
102
169

Is the non-tracking of `TDBGrid` a design choice to avoid hammering the database whilst scrolling? This is an honest question asked in ignorance by someone who knows absolutely nothing about databases. – David Heffernan Aug 02 '11 at 21:50
6

@David - Very likely.. But the option should have been given to the developer anyway. Sometimes all field data is cached anyway, there's no point then to not to have thumb tracking. – Sertac Akyuz Aug 02 '11 at 21:58
2

Thank you – David Heffernan Aug 02 '11 at 22:01
I've got an error "Undeclared identifier DBGrids".. how to fix this? thnx. – user2200585 Jan 04 '15 at 12:30
1

@user - Ask a new question when you have a question.. unless it has been answered before. This has been probably answered many times. Anyway, replace 'DBGrids' with 'Vcl.DBGrids'. – Sertac Akyuz Jan 04 '15 at 15:29
thnx a lot bro! HAPPY NEW YEAR! – user2200585 Jan 04 '15 at 17:22

score 3 · Answer 2 · answered Aug 26 '15 at 10:16

Here is the other solution Sertac Akyuz mentioned without having to derive a new class from TDBGrid:

  private
    FOrgDBGridWndProc: TWndMethod;
    procedure DBGridWndProc(var Msg: TMessage);
  // ...
  end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  FOrgDBGridWndProc:= DBGrid1.WindowProc;
  DBGrid1.WindowProc := DBGridWndProc;
end;

procedure TForm1.DBGridWndProc(var Msg: TMessage);
begin
  if (Msg.Msg = WM_VSCROLL) and
    (LongRec(Msg.wParam).Lo = SB_THUMBTRACK) then
  begin
      LongRec(Msg.wParam).Lo := SB_THUMBPOSITION;
  end;
  if Assigned(FOrgDBGridWndProc) then
    FOrgDBGridWndProc(Msg);
end;

Delphi dbgrid continuous scrolling

2 Answers2

Linked