3

Does anyone know how I can plot each occurrence of a defined variable after a certain date? So, before a certain timeframe input ignore all occurrances. I was able to find this:How to plot only the last x periods But, this appears to only plot a single occurrance of the variable on the input date.

For example and simplicity how can I plot every doji after the user input date:

//@version=5
indicator('Plot all Doji after input date and ignore before input date', overlay=true)
monthsBack = input.int(3, minval=0)

doji = close == open

targetDate = time >= timestamp(year(timenow), month(timenow) - monthsBack, 1, 0, 0, 0)
beginMonth = not targetDate[1] and targetDate

var float valueToPlot = doji
if beginMonth
    valueToPlot := high
    valueToPlot
plot(valueToPlot)
bgcolor(beginMonth ? color.green : na, transp=90)

Update:

Wow, thank you shanem I was not expecting such a thorough answer. After reading your response it makes sense to me now.

I'm primarily a trader, not much of a programmer, so I'm excited to see my trading strategies starting to come together in a more automated way. This script is just part of my most profitable trading strategy and will help save me tons of time spent identifying levels. It will also help me move to a new symbol with levels ready to go much faster as I have been hand drawing my levels for the last two years which is time-consuming.

I should have said "test candle" in my original post rather than "doji." I just meant to use a placeholder for the candle type since writing the code for the actual condition I'm looking for is going to be somewhat complicated. But, I wanted to make sure I would be able to plot what I needed to see before embarking on that.

Screenshot

Here's a screenshot of how I would normally hand draw a price level. Now done with a script automatically!

link to image

Here's the script I have with the help if shanem, still a work in progress, but getting there:

//@version=5
// with help from shanem it works!
indicator("Identify [a specific kind of candle] in past N months", shorttitle = "Auto Price Levels", overlay = true)

// 1) Define inputs used in the script
monthsBack = input.int(8, minval=0, title="How many months back should we scan for [candle type]?")

// 2) Declare variables used in the script, and set defaults (once per chart)
var tn = timenow
var firstDate = timestamp(year(tn), month(tn) - monthsBack, 1, 0, 0, 0)
var testCandle = false
var okayToPlot = false

// 3) Calculations. 
okayToPlot := time > firstDate

// A note about the candle type. For the purpose of this script I plugged in a quick candle description to limit the number of 
    // candles that would appear on the chart, and to reduce the amount of code to deal with to focus on the 'plot' code. I first
    // wanted to see if it was possible to plot what I needed to see before I set out to create code for the specifi candle I'm 
    // looking for. I will either fully describe the candle in the future script, or import from a Pine Library since it is somewhat complex.  
testCandle := if close == open and barstate.isconfirmed and session.ismarket

    close

// 4) Output / Plotting
        // Plot a price line on the close of each occurance of the [candle type].
        // Also, highlight the high and low of the [candle type] and extend right. 
plot(okayToPlot and testCandle ? close : na, style = plot.style_circles, linewidth = 3, color = color.rgb(245, 66, 221))

if testCandle and okayToPlot
    line.new(bar_index - 1, close, bar_index, close, color = color.rgb(255, 164, 23), extend = extend.right, width = 1)
    box.new(bar_index - 1, high, bar_index, low, border_color = na, bgcolor = color.rgb(135, 135, 135, 80), extend = extend.right)

// To do next, working on now:
    // 1.   Define the candle and limit the timeframe (or resolution) the price level is calculated on. 
    //      Perhaps 30 minute. But, allow the price levels to be seen on all other timeframes.
    //      Seen on 1m, 5m, 4hr, daily, etc., but derived from 30m (just example).
    // 2.   Alerts. Send JSON payload via webhook if current price in range. Found this and modified version works good: 
    //      User "wlhm" - https://www.tradingview.com/script/FPq2xKyZ-DiscordWebhookFunction/
Josiah
  • 53
  • 1
  • 2
  • 6

1 Answers1

3

Great question Josiah, there is a lot going on here:

  • You probably already discovered this, but the beginMonth test in the code sample above, as written, will only flag the first day of the first full month that is in your allowed date range. We'll fix that below.
  • There are some related changes in Pine v5 to how colors are set, and from v4 as to how variables are declared and updated, so I have leveraged those below as well.
  • You have two tests going on: timeframe and doji-ness, so I've split them up below for clarity.

This was a great example to work with because it highlights a problem I often have in my own Pine scripting, looking for opportunities or conditions:

Why don't I see any opportunities flagged by my rules? Is there something wrong with my code? Did it even run? Or is it the data I'm looking at, in there just aren't any matching candles, but the code is fine? (Oh, and am I reading the wrong version of the documentation, using the correct version of the function, updating the values on each bar or not...)

Even when we succeed in crafting the correct tests and succeed in combining them properly, it's still very hard to effectively plot dojis. Partly because they're rare, and partly because of what they look like on a chart. That also makes it hard to tell if our code is working, even when it is.

So I try to make sure my code helps me see just what's going wrong and what isn't. And hopefully this example is useful to others on that level as well.

The code below should do what you want. To answer your headline question, it uses a variable called okayToPlot to limit rendering of your indicator to just days in the past N months.

It also shows how find and effectively highlight doji's, so you don't go insane trying to see a thin black line that was rendered on top of another thin black line.

I used overlay=false to help you (okay, me) get a better look at what was going on. Once you're satisfied with your working script, just change it back to overlay=true and you're good to go.

If you copy/paste this into your Pine Editor as a new Indicator and try it out on a daily chart for some slow-moving large cap stock, you should spot a doji if you scan a long enough period.

I used 8 months on BCE on the TSX in late 2021 and it finds 2 days with a doji formation, which it highlights with a yellow background and a bright green + sign.

//@version=5
indicator("Highlight Any Doji In Past N Months", overlay=false)

// 1) Define inputs used in the script
monthsBack = input.int(8, minval=0, title="How many months back should we scan for dojis?")

// 2) Declare variables used in the script, and set defaults (once per chart)
var tn = timenow
var firstDate = timestamp(year(tn), month(tn) - monthsBack, 1, 0, 0, 0)
var doji = false
var okayToPlot = false

// 3) Calculations. The := notation below updates the variable on each bar of the chart.
okayToPlot := time > firstDate

doji := close == open

// 4) Output / Plotting

plot(okayToPlot and doji ? close : na, style = plot.style_cross, linewidth = 3, color = color.new(color.green, 40))

bgcolor(okayToPlot ? doji ? color.new(color.yellow, 60) : color.new(color.green, 80) : na)

Screenshot

I use a dark theme in my charts. Hopefully you can still make out the difference between the black background on dates more than 8 months ago, which will not highlight a doji in yellow, and dates in the past 8 months, which will highlight any doji day in yellow -- if any are found.

Pine Script Highlighting Scanned Dates In Dark Green and Dates With Dojis In Yellow

Relevant: What's a Doji?

At first I thought this line in the question was a bug:

doji = close == open

But it turns out that I actually didn't know what a doji was until today. I had to look it up, and just so future readers in the same boat aren't confused by this particular example, this quick side note:

A doji is formed when the opening price and the closing price are equal.

(via https://commodity.com/technical-analysis/doji/ )

So on a candlestick chart, it can look like a + or a taller cross.

From skimming the link above, I'm not sure whether a day where the high and the low are also equal technically counts as a doji. On a candlestick chart it would look like a minus sign, a dash. If you want to exclude those from your filter, change the doji test line above to:

doji := close == open and high > low

Bonus Round: plotchar()

Here's another screenshot with brighter colours and a slightly different plotting technique that is even better suited to situations like this.

We probably don't really want to plot the closing price, just draw a viewer's eye to it. I also zoomed this screenshot into the most relevant couple of months of my previous image (after changing the months input to 5 so it only searches back to July 1st).

Doji!

// Since plotting anything (a line, a cross, whatever) directly at the close
// price of a doji will hide it, here's a version that uses plotchar() to
// place a question mark directly above the doji.
plotchar(okayToPlot and doji, char='?', location = location.abovebar, color = color.new(color.black, 0))
bgcolor(okayToPlot ? doji ? color.new(color.yellow, 40) : color.new(color.green, 20) : na)

Green and yellow colours inspired by Iron Fist, since doji reminds me of dojo and some part of me is still seven years old. The question mark is because a doji represents uncertainty, an indecisive market... and is in no way a reference to The Riddler, who also wears green. That's just a coincidence, surely?

shanem
  • 136
  • 1
  • 2